Creating a background job with out Variant.

Question

Hi Experts,
I'm developed one ALV report which is not having any selection-screen and Variant.
We can execute the program in fore ground but the user wants to be run in back ground and he wants to be created a spool requet for that report.
My Question is ...the above requirement is possible or not.
if your answer is yes then
How to create a variant for a report which is not having any selection-screen?
Can we creat a spool request manually ..means with in the report only through coding?
Thank you ,
Venky.

Answer 1

try this one...
you can submit your report in background and create spool...
An ALV report can be executed in background.. but if its an ALV Grid then spool will contain ALV list output. You can directly select execute in background even if you dont have any parameter on selection screen. or try below code...... if you want to create a spool from the report itself.....
I hope its useful
DATA: number           TYPE tbtcjob-jobcount,
      name             TYPE tbtcjob-jobname VALUE 'JOB_TEST',
      print_parameters TYPE pri_params.
CALL FUNCTION 'JOB_OPEN'
  EXPORTING
    jobname          = name
  IMPORTING
    jobcount         = number
  EXCEPTIONS
    cant_create_job  = 1
    invalid_job_data = 2
    jobname_missing  = 3
    OTHERS           = 4.
IF sy-subrc = 0.
  SUBMIT report TO SAP-SPOOL
                    SPOOL PARAMETERS print_parameters
                    WITHOUT SPOOL DYNPRO
                    VIA JOB name NUMBER number
                    AND RETURN.
  IF sy-subrc = 0.
    CALL FUNCTION 'JOB_CLOSE'
      EXPORTING
        jobcount             = number
        jobname              = name
        strtimmed            = 'X'
      EXCEPTIONS
        cant_start_immediate = 1
        invalid_startdate    = 2
        jobname_missing      = 3
        job_close_failed     = 4
        job_nosteps          = 5
        job_notex            = 6
        lock_failed          = 7
        OTHERS               = 8.
    IF sy-subrc <> 0.
    ENDIF.
  ENDIF.
ENDIF.