DBMS_TYPES with timestamp and interval does not seem to work.

Question

I have a PL/SQL script that seems to work for char,varchar,numerics, dates, but not for intervals. I basically took example code out of the Oracle manuals and stitched it together.
The code in question is the function colTypeString. Apparently, interval is not being recognized as a type, so the function is returning back unknown. The documentation seems a bit spartan, so I thought perhaps you can help me out.
Thanks.
Here's the code:
create table interval_test( intym interval year(4) to month, intdm interval day(3) to second(4) );
execute oraforum_pkg.desc_query( 'select * from interval_test' );
col_type     =     182, UNKNOWN_TYPE
col_maxlen     =     5
col_name     =     INTYM
col_name_len     =     5
col_schema_name =
col_schema_name_len =     0
col_precision     =     4
col_scale     =     0
col_null_ok     =     true
col_type     =     183, UNKNOWN_TYPE
col_maxlen     =     11
col_name     =     INTDM
col_name_len     =     5
col_schema_name =
col_schema_name_len =     0
col_precision     =     3
col_scale     =     4
col_null_ok     =     true
PL/SQL procedure successfully completed.
Here's the package:
-- Define the ref cursor types and function
CREATE OR REPLACE PACKAGE oraforum_pkg IS
FUNCTION colTypeString( typeId in integer) return varchar2; -- typeId from dbms_types
PROCEDURE print_rec(rec in DBMS_SQL.DESC_REC);
PROCEDURE desc_query( selectSql in varchar2 );
END oraforum_pkg;
CREATE OR REPLACE PACKAGE BODY oraforum_pkg IS
FUNCTION colTypeString( typeId in integer)
return varchar2 -- typeId from dbms_types
is
rval varchar2(40) := 'Unknown';
BEGIN
case typeId
when DBMS_TYPES.NO_DATA then rval := 'NO_DATA' ;
when DBMS_TYPES.SUCCESS          then rval := 'SUCCESS' ;
when DBMS_TYPES.TYPECODE_BDOUBLE     then rval := 'BDOUBLE' ;
when DBMS_TYPES.TYPECODE_BFILE     then rval := 'BFILE' ;
when DBMS_TYPES.TYPECODE_BFLOAT     then rval := 'BFLOAT' ;
when DBMS_TYPES.TYPECODE_BLOB     then rval := 'BLOB' ;
when DBMS_TYPES.TYPECODE_CFILE     then rval := 'CFILE' ;
when DBMS_TYPES.TYPECODE_CHAR     then rval := 'CHAR' ;
when DBMS_TYPES.TYPECODE_CLOB     then rval := 'CLOB' ;
when DBMS_TYPES.TYPECODE_DATE     then rval := 'DATE' ;
when DBMS_TYPES.TYPECODE_INTERVAL_DS     then rval := 'INTERVAL_DS' ;
when DBMS_TYPES.TYPECODE_INTERVAL_YM     then rval := 'INTERVAL_YM' ;
when DBMS_TYPES.TYPECODE_MLSLABEL     then rval := 'MLSLABEL' ;
when DBMS_TYPES.TYPECODE_NAMEDCOLLECTION then rval := 'NAMEDCOLLECTION' ;
when DBMS_TYPES.TYPECODE_NUMBER     then rval := 'NUMBER' ;
when DBMS_TYPES.TYPECODE_OBJECT     then rval := 'OBJECT' ;
when DBMS_TYPES.TYPECODE_OPAQUE     then rval := 'OPAQUE' ;
when DBMS_TYPES.TYPECODE_RAW          then rval := 'RAW' ;
when DBMS_TYPES.TYPECODE_REF          then rval := 'REF' ;
when DBMS_TYPES.TYPECODE_TABLE     then rval := 'TABLE' ;
when DBMS_TYPES.TYPECODE_TIMESTAMP     then rval := 'TIMESTAMP' ;
when DBMS_TYPES.TYPECODE_TIMESTAMP_LTZ then rval := 'TIMESTAMP_LTZ' ;
when DBMS_TYPES.TYPECODE_TIMESTAMP_TZ then rval := 'TIMESTAMP_TZ' ;
when DBMS_TYPES.TYPECODE_VARCHAR2     then rval := 'VARCHAR2' ;
when DBMS_TYPES.TYPECODE_VARCHAR     then rval := 'VARCHAR' ;
when DBMS_TYPES.TYPECODE_VARRAY then rval := 'VARRAY' ;
else rval := 'UNKNOWN_TYPE';
end case;
return rval;
END;
PROCEDURE print_rec(rec in DBMS_SQL.DESC_REC) IS
BEGIN
DBMS_OUTPUT.PUT_LINE('col_type = '
|| rec.col_type || ', ' || colTypeString(rec.col_type) );
DBMS_OUTPUT.PUT_LINE('col_maxlen = '
|| rec.col_max_len);
DBMS_OUTPUT.PUT_LINE('col_name = '
|| rec.col_name);
DBMS_OUTPUT.PUT_LINE('col_name_len = '
|| rec.col_name_len);
DBMS_OUTPUT.PUT_LINE('col_schema_name = '
|| rec.col_schema_name);
DBMS_OUTPUT.PUT_LINE('col_schema_name_len = '
|| rec.col_schema_name_len);
DBMS_OUTPUT.PUT_LINE('col_precision = '
|| rec.col_precision);
DBMS_OUTPUT.PUT_LINE('col_scale = '
|| rec.col_scale);
DBMS_OUTPUT.PUT('col_null_ok = ');
IF (rec.col_null_ok) THEN
DBMS_OUTPUT.PUT_LINE('true');
ELSE
DBMS_OUTPUT.PUT_LINE('false');
END IF;
DBMS_OUTPUT.PUT_LINE('');
END;
PROCEDURE desc_query( selectSql in varchar2 ) IS
c NUMBER;
d NUMBER;
col_cnt INTEGER;
f BOOLEAN;
rec_tab DBMS_SQL.DESC_TAB;
col_num NUMBER;
BEGIN
c := DBMS_SQL.OPEN_CURSOR; -- Is this needed for parsing? Yes, as argument to PARSE
DBMS_SQL.PARSE(c, selectSql, DBMS_SQL.NATIVE);
-- d := DBMS_SQL.EXECUTE(c); -- Doesn't look necessary.
DBMS_SQL.DESCRIBE_COLUMNS(c, col_cnt, rec_tab);
* Following loop could simply be for j in 1..col_cnt loop.
* Here we are simply illustrating some of the PL/SQL table
* features.
col_num := rec_tab.first;
IF (col_num IS NOT NULL) THEN
LOOP
print_rec(rec_tab(col_num));
col_num := rec_tab.next(col_num);
EXIT WHEN (col_num IS NULL);
END LOOP;
END IF;
DBMS_SQL.CLOSE_CURSOR(c);
END;
END oraforum_pkg;
Message was edited by:
user554561

Answer 1

The issue is that DBMS_SQL and DBMS_TYPES have different typecodes. Which means you can't interrogate the DBMS_SQL.DESC_REC using DBMS_TYPES constants. You could create yourself a package of DBMS_SQL_TYPES.
SQL> create table t ( ts timestamp, iv interval day to second );
Table created.
SQL>
SQL> insert into t values ( systimestamp, interval '1' second );
1 row created.
SQL>
SQL> declare
  2     c         integer           := dbms_sql.open_cursor ();
  3     rec_tab   dbms_sql.desc_tab;
  4     col_cnt   integer;
  5  begin
  6     dbms_sql.parse (c, 'select * from t', dbms_sql.native);
  7     dbms_sql.describe_columns (c, col_cnt, rec_tab);
  8
  9     for i in 1 .. col_cnt
10     loop
11        dbms_output.put_line ('Name: ' || rec_tab (i).col_name || '; Type: ' || rec_tab (i).col_type);
12     end loop;
13
14     dbms_sql.close_cursor (c);
15
16     dbms_output.put_line ('DBMS_TYPES.TYPECODE_TIMESTAMP; Type: ' || DBMS_TYPES.TYPECODE_TIMESTAMP);
17     dbms_output.put_line ('DBMS_TYPES.TYPECODE_INTERVAL_DS; Type: ' || DBMS_TYPES.TYPECODE_INTERVAL_DS);
18
19  end;
20  /
Name: TS; Type: 180
Name: IV; Type: 183
DBMS_TYPES.TYPECODE_TIMESTAMP; Type: 187
DBMS_TYPES.TYPECODE_INTERVAL_DS; Type: 190
PL/SQL procedure successfully completed.Regards