Delete after trigger returns a NULL value for the old primary key??

Question

I am creat an After trigger that I was using to delete a row from another table. However, the OLD value returned for my primary key is a NULL value. I have an UPDATE and an INSERT portion to this same trigger that work fine with just grabbing NEW values, but this OLD value cannot be grabbed for some reason, although it seems to work on other tables when the owner is me, the problem table is not owned by me though. Has anyone run into this before? Is there a view that I need access to from this table or perhaps a setting I need to turn on? I am at a loss. Thanks.

Answer 1

Cannot reproduce with this modified trigger code … right now I believe the problem is in this part:
BEGIN
  col_ret := vpack.vOPCollectIO(tpid, User, 'SCOTT.OINFTABL', dmltype, vdata);
EXCEPTION
  WHEN lost_connection OR lost_connection2 THEN
    col_ret := vpack.vOPCollectIO(tpid, User, 'SCOTT.OINFTABL', dmltype, vdata);
END;
In schema CORE:
SQL> create table oinftabl
  2  ( akey     number(9) primary key
  3   ,astring  varchar2(10)
  4   ,astring2 varchar2(10)
  5  );
Table created.
SQL>
SQL> grant all on oinftabl to flip;
In schema FLIP (which has “CREATE ANY TRIGGER”):
flip@FLOP> CREATE OR REPLACE TYPE VDAT AS VARRAY(100000) OF VARCHAR2(50);
2     /
create or replace trigger sbt3_system_oinftabl_x
after insert or update or delete on core.oinftabl
REFERENCING NEW as n OLD as o
FOR EACH ROW
DECLARE
  col_ret INT;
  dmltype CHAR(1);
  tpid VARCHAR2(30);
  vdata VDAT; --varray datatype I created;
  lost_connection EXCEPTION;
  lost_connection2 EXCEPTION;
  already_there EXCEPTION;
  PRAGMA EXCEPTION_INIT(lost_connection, -28576);
  PRAGMA EXCEPTION_INIT(lost_connection2, -28579);
  PRAGMA EXCEPTION_INIT(already_there,-1);
BEGIN
  tpid := SYS.DBMS_TRANSACTION.LOCAL_TRANSACTION_ID();
  IF INSERTING THEN dmltype := 'I';
  ELSIF UPDATING THEN dmltype := 'U';
  ELSE dmltype := 'D';
  END IF;
  IF INSERTING OR UPDATING THEN
    dbms_output.put_line('new akey='||nvl(to_char(:n.akey),'null'));
    dbms_output.put_line('new astring='||:n.astring);
    vdata := VDAT(
    to_char(:n.AKEY),
    :n.ASTRING,
    :n.ASTRING2,
    NULL);
  ELSIF DELETING THEN
    dbms_output.put_line('old akey='||nvl(to_char(:o.akey),'null'));
    vdata := VDAT(
      to_char(:o.AKEY),
      NULL);
  END IF;
  for i in 1..vdata.count
  loop
    dbms_output.put_line('vdata('||i||')='||nvl(vdata(i),'null'));
  end loop;
--BEGIN
--  col_ret := vpack.vOPCollectIO(tpid, User, 'SCOTT.OINFTABL', dmltype, vdata);
--EXCEPTION
--  WHEN lost_connection OR lost_connection2 THEN
--    col_ret := vpack.vOPCollectIO(tpid, User, 'SCOTT.OINFTABL', dmltype, vdata);
--END;
END;
Trigger created.
flip@FLOP> show errors
No errors.
flip@FLOP> insert into core.oinftabl values (1,'abc',null);
new akey=1
new astring=abc
vdata(1)=1
vdata(2)=abc
vdata(3)=null
vdata(4)=null
1 row created.
flip@FLOP>  update core.oinftabl set akey=2, astring='cba' where akey=1;
new akey=2
new astring=cba
vdata(1)=2
vdata(2)=cba
vdata(3)=null
vdata(4)=null
1 row updated.
flip@FLOP> delete from core.oinftabl where akey=2;
old akey=2
vdata(1)=2
vdata(2)=null
1 row deleted.
So the trigger has the OLD AKEY value when DELETING and it does successfully store it in the VARRAY.
Hence the problem is in that pl/sql block at the end.
What are you doing in there?