Downloading BLOB to a file using pl/sql toolkit

Question

Created an Oracle Reports RDF file using the reports builder (9.0.2.x).
Uploaded the file into the database in a BLOB column using the following code:
>>>>
SET VERIFY OFF
DECLARE
p_bfile BFILE ;
p_blob BLOB ;
BEGIN
p_bfile := BFILENAME('CDR_REPORTS', '&1') ;
INSERT INTO RPTIDE (RPTID, RPTMODULE) VALUES ('&1', EMPTY_BLOB()) RETURNING
RPTMODULE INTO p_blob ;
DBMS_LOB.FILEOPEN(p_bfile, DBMS_LOB.FILE_READONLY);
DBMS_LOB.LOADFROMFILE(p_blob, p_bfile, DBMS_LOB.GETLENGTH(p_bfile));
DBMS_LOB.FILECLOSE(p_bfile);
COMMIT ;
END ;
<<<<<
Now when we try to download the same file using pl/sql web toolkit (code pasted
below), the file downloads fine (with exact same file size as before), but no
longer can open the file in Reports Builder anymore. Get "Cannot open file"
error in reports builder. Is it getting corrupt or am I doing something wrong?
>>>>
CREATE OR REPLACE PROCEDURE filedownload(p_rpt IN VARCHAR2) AS
p_file blob;
p_mime_type varchar2(50);
p_offset integer := 1;
p_len number;
p_buf RAW(32000);
p_buf_size integer:= 32000;
BEGIN
SELECT rptmodule, 'application/x-zip'
INTO p_file, p_mime_type
FROM rptide
WHERE rptid = p_rpt ;
OWA_UTIL.MIME_HEADER(p_mime_type);
p_len := DBMS_LOB.GETLENGTH(p_file);
WHILE p_offset < p_len LOOP
DBMS_LOB.READ(p_file, p_buf_size, p_offset, p_buf);
HTP.PRN(UTL_RAW.CAST_TO_VARCHAR2(p_buf));
p_offset := p_offset + p_buf_size;
END LOOP;
EXCEPTION
WHEN NO_DATA_FOUND THEN HTP.PRN('No document specified') ;
WHEN OTHERS THEN HTP.P('filedownload: '||SQLERRM);
END filedownload ;
<<<<<

Answer 1

The answer to this problem was to set the NLS_LANGUAGE for the DAD to an 8-bit character set since the database charset was 8-bit. It seems, by default, the web toolkit assumes a 7-bit character set.