Dynamic Table - Deep Structure

Question

Hi Gurus,
this is my first posting, so be patient!
I want to create a deep structure dynamic table via method
cl_alv_table_create=>create_dynamic_table, is this possible? Are there tricks to make it happen?
Background: i wanna create an alv with dynamic fieldcatalalog, in this case i want to colour special fields, which is done by lvc_s_layo-?csp_fieldname? in combination with a field in my internal table which is typed ?lvc_t_scol?. Is this possible under 6.2.43
thanxs for your replies
juergen
- ?i dont actually know by rote the correct fieldnames of lvc_xxxxx?

Answer 1

Hi Jurgen, I took on the challenge.  This program provides a dynamic table with the ability to set the colors of the cells.
Create the structure ZCDF_CELL_COLOR in the dictionary as described in the program.
Create screen 100 as empty, with next screen set to 0, and the following flow logic:
PROCESS BEFORE OUTPUT.
  MODULE initialization.
PROCESS AFTER INPUT.
REPORT  zcdf_dynamic_table.
* Dynamic ALV Grid with Cell Coloring
DATA:
  r_dyn_table      TYPE REF TO data,
  r_wa_dyn_table   TYPE REF TO data,
  r_dock_ctnr      TYPE REF TO cl_gui_docking_container,
  r_alv_grid       TYPE REF TO cl_gui_alv_grid,
  t_fieldcat1      TYPE lvc_t_fcat, "with cell color
  t_fieldcat2      TYPE lvc_t_fcat, "without cell color
  wa_fieldcat      LIKE LINE OF t_fieldcat1,
  wa_cellcolors    TYPE LINE OF lvc_t_scol,
  wa_is_layout     TYPE lvc_s_layo.
FIELD-SYMBOLS:
  <t_dyn_table>    TYPE STANDARD TABLE,
  <wa_dyn_table>   TYPE ANY,
  <t_cellcolors>   TYPE lvc_t_scol,
  <w_field>        TYPE ANY.
START-OF-SELECTION.
* Build field catalog based on your criteria.
  wa_fieldcat-fieldname = 'FIELD1'.
  wa_fieldcat-inttype   = 'C'.
  wa_fieldcat-outputlen = '10'.
  wa_fieldcat-coltext   = 'My Field 1'.
  wa_fieldcat-seltext   = wa_fieldcat-coltext.
  APPEND wa_fieldcat TO t_fieldcat1.
  wa_fieldcat-fieldname = 'FIELD2'.
  wa_fieldcat-inttype   = 'C'.
  wa_fieldcat-outputlen = '10'.
  wa_fieldcat-coltext   = 'My Field 2'.
  wa_fieldcat-seltext   = wa_fieldcat-coltext.
  APPEND wa_fieldcat TO t_fieldcat1.
* Before adding cell color table,
*  save fieldcatalog to pass
*  to ALV call.
  t_fieldcat2[] = t_fieldcat1[].
* Add cell color table.
*  ZCDF_CELL_COLOR is a structure in the
*   dictionary with one
*   field called T_CELL_COLOR of type LVC_T_SCOL.
  wa_fieldcat-fieldname = 'T_CELLCOLORS'.
  wa_fieldcat-ref_field = 'T_CELL_COLOR'.
  wa_fieldcat-ref_table = 'ZCDF_CELL_COLOR'.
  APPEND wa_fieldcat TO t_fieldcat1.
* Create dynamic table.
  CALL METHOD cl_alv_table_create=>create_dynamic_table
    EXPORTING
      it_fieldcatalog           = t_fieldcat1
    IMPORTING
      ep_table                  = r_dyn_table
    EXCEPTIONS
      generate_subpool_dir_full = 1
      OTHERS                    = 2.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
               WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
* Get access to new table using field symbol.
  ASSIGN r_dyn_table->* TO <t_dyn_table>.
* Create work area for new table.
  CREATE DATA r_wa_dyn_table LIKE LINE OF <t_dyn_table>.
* Get access to new work area using field symbol.
  ASSIGN r_wa_dyn_table->* TO <wa_dyn_table>.
* Get data into table from somewhere.  Field names are
*  known at this point because field catalog is already
*  built.  Read field names from the field catalog or use
*  COMPONENT <number> in a DO loop to access the fields. 
*  A simpler hard coded approach is used here.
  ASSIGN COMPONENT 'FIELD1' OF STRUCTURE <wa_dyn_table>
    TO <w_field>.
  <w_field> = 'ABC'.
  ASSIGN COMPONENT 'FIELD2' OF STRUCTURE <wa_dyn_table>
    TO <w_field>.
  <w_field> = 'XYZ'.
  APPEND <wa_dyn_table> TO <t_dyn_table>.
  ASSIGN COMPONENT 'FIELD1' OF STRUCTURE <wa_dyn_table>
    TO <w_field>.
  <w_field> = 'TUV'.
  ASSIGN COMPONENT 'FIELD2' OF STRUCTURE <wa_dyn_table>
    TO <w_field>.
  <w_field> = 'DEF'.
  APPEND <wa_dyn_table> TO <t_dyn_table>.
* Color cells based on your criteria. 
*  In this example, a test on
*  FIELD2 is used to decide on color.
  LOOP AT <t_dyn_table> INTO <wa_dyn_table>.
    ASSIGN COMPONENT 'FIELD2' OF STRUCTURE <wa_dyn_table>
      TO <w_field>.
    ASSIGN COMPONENT 'T_CELLCOLORS'
      OF STRUCTURE <wa_dyn_table> TO <t_cellcolors>.
    CLEAR wa_cellcolors.
    wa_cellcolors-fname     = 'FIELD2'.
    IF <w_field> = 'DEF'.
      wa_cellcolors-color-col = '7'.
    ELSE.
      wa_cellcolors-color-col = '5'.
    ENDIF.
    APPEND wa_cellcolors TO <t_cellcolors>.
    MODIFY <t_dyn_table> FROM <wa_dyn_table>.
  ENDLOOP.
  CALL SCREEN 100.
*  MODULE initialization OUTPUT
MODULE initialization OUTPUT.
* Set up for ALV display.
  IF r_dock_ctnr IS INITIAL.
    CREATE OBJECT r_dock_ctnr
           EXPORTING
              side  =  
                cl_gui_docking_container=>dock_at_left
              ratio = '90'.
    CREATE OBJECT r_alv_grid
           EXPORTING i_parent = r_dock_ctnr.
*   Set ALV controls.
    wa_is_layout-ctab_fname = 'T_CELLCOLORS'.
*   Display.
    CALL METHOD r_alv_grid->set_table_for_first_display
      EXPORTING
        is_layout       = wa_is_layout
      CHANGING
        it_outtab       = <t_dyn_table>
        it_fieldcatalog = t_fieldcat2.
  ELSE.     "grids already prepared
*   Refresh display.
    CALL METHOD r_alv_grid->refresh_table_display
      EXPORTING
        i_soft_refresh = ' '
      EXCEPTIONS
        finished       = 1
        OTHERS         = 2.
  ENDIF.
ENDMODULE.                 " initialization  OUTPUT