Email with attachments not delivered how to resend
I Sent an email with attachments but it wasn't delivered. How can I resend it with amended information?
I Also can't open the attachments to see which photos they were.
MAny thanks
Find it in your sent folder, then forward with any changes. If it isn't in your sent folder, check your outbox.
Similar Messages
-
Sending email with attachments not working on Lumi...
It is not possible to attach a file to an email, either via WiFi or my 4G connection. I have two different Office365 email accounts (work and private) that work perfectly when sending/receiving emails with/without attachments. However when I try and share a photo (from any folder in Photos) I can select a photo, choose Share-->Email account, but when it brings up the email message screen there is nothing attached. The same thing happens if I create an ordinary email and try to attach any file, it won't attach and the email sends OK without the attachment.
It is not an issue with the email accounts as I can send/receive attachments OK from my laptop and iPad. It is only when I try and send from my 1520.
This has got me baffled!try to delete the account and re-add the account.
then, try to take a picture and immediately go to that image by tapping it on the screen and sharing as you stated.
if that doesn't work, then I wonder if the device is corrupted and the images are not "really there"
can you see the images on your skydrive account?
have you tried to do a soft reset?
Soft Reset-
Hold Vol- & Pwr until the device shuts down
When the device vibrates and starts to reboot, release ONLY Pwr button, still holding the Vol-
When you see the (!) on your screen, then release the Vol- button and wait until the device boots.
Your device is now soft reset -
Email with attachments not being sent
When I send an email with an attachment it is not being recieved. It shows up in the 'sent' box but never gets to the person I send it to.
It could be that the size o fthe attachment is too large and the server used by the reciever rejects it. It could be you have the wrong address (not as likely). I'd try the following:
1) send a short email with no attachment to xxx.
2) send a short email with a small file attached to xxx.
3) send an email with the file you tried to send previously to xxx.
Which of these works, which don't? -
Forwarded emails with attachments not showing email thread history
Hi,
My boss has a Mac laptop and forwards me emails for me to action. When the emails have attachments the email thread history doesn't come along with the email, so all the conversation leading up to the email being forwarded. It just shows what he has written and stops at the signature.
When an email is forwarded without attachments the thread history is included. We've done some testing and it's specific to him and his Mac.
Sorry I don't have a mac laptop myself so don't know a lot of details about what he uses but can find out information that is important to solving the issue.
I've had a good look but can't find any setting on his Mac to change this, any help would be greatly appreciated.
Thanks, SimonStill love any advice on this issue if anyone can help????
Thanks -
I often get emails with attachments that will not open with my mac often a small ? will show. How do I open these
What kind of attachment? Post an example file name.
-
How to send Email with attachments
Hi im Trying to send a file as attachment using EMail Activity operator.
Can we do it using Email activity? If yes, then how can we do it? If no, then please tell me about any other method using which i can send a email with attachments.
Regards
VibhutiBetter late than never, a comprehensive demo on the topic:
REM
REM maildemo.sql - A PL/SQL package to demonstrate how to use the UTL_SMTP
REM package to send emails in ASCII and non-ASCII character sets, emails
REM with text or binary attachments.
REM
REM Note: this package relies on the UTL_ENCODE PL/SQL package in Oracle 9i.
CREATE OR REPLACE PACKAGE demo_mail IS
----------------------- Customizable Section -----------------------
-- Customize the SMTP host, port and your domain name below.
smtp_host VARCHAR2(256) := 'smtp-server.some-company.com';
smtp_port PLS_INTEGER := 25;
smtp_domain VARCHAR2(256) := 'some-company.com';
-- Customize the signature that will appear in the email's MIME header.
-- Useful for versioning.
MAILER_ID CONSTANT VARCHAR2(256) := 'Mailer by Oracle UTL_SMTP';
--------------------- End Customizable Section ---------------------
-- A unique string that demarcates boundaries of parts in a multi-part email
-- The string should not appear inside the body of any part of the email.
-- Customize this if needed or generate this randomly dynamically.
BOUNDARY CONSTANT VARCHAR2(256) := '-----7D81B75CCC90D2974F7A1CBD';
FIRST_BOUNDARY CONSTANT VARCHAR2(256) := '--' || BOUNDARY || utl_tcp.CRLF;
LAST_BOUNDARY CONSTANT VARCHAR2(256) := '--' || BOUNDARY || '--' ||
utl_tcp.CRLF;
-- A MIME type that denotes multi-part email (MIME) messages.
MULTIPART_MIME_TYPE CONSTANT VARCHAR2(256) := 'multipart/mixed; boundary="'||
BOUNDARY || '"';
MAX_BASE64_LINE_WIDTH CONSTANT PLS_INTEGER := 76 / 4 * 3;
-- A simple email API for sending email in plain text in a single call.
-- The format of an email address is one of these:
-- someone@some-domain
-- "Someone at some domain" <someone@some-domain>
-- Someone at some domain <someone@some-domain>
-- The recipients is a list of email addresses separated by
-- either a "," or a ";"
PROCEDURE mail(sender IN VARCHAR2,
recipients IN VARCHAR2,
subject IN VARCHAR2,
message IN VARCHAR2);
-- Extended email API to send email in HTML or plain text with no size limit.
-- First, begin the email by begin_mail(). Then, call write_text() repeatedly
-- to send email in ASCII piece-by-piece. Or, call write_mb_text() to send
-- email in non-ASCII or multi-byte character set. End the email with
-- end_mail().
FUNCTION begin_mail(sender IN VARCHAR2,
recipients IN VARCHAR2,
subject IN VARCHAR2,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
priority IN PLS_INTEGER DEFAULT NULL)
RETURN utl_smtp.connection;
-- Write email body in ASCII
PROCEDURE write_text(conn IN OUT NOCOPY utl_smtp.connection,
message IN VARCHAR2);
-- Write email body in non-ASCII (including multi-byte). The email body
-- will be sent in the database character set.
PROCEDURE write_mb_text(conn IN OUT NOCOPY utl_smtp.connection,
message IN VARCHAR2);
-- Write email body in binary
PROCEDURE write_raw(conn IN OUT NOCOPY utl_smtp.connection,
message IN RAW);
-- APIs to send email with attachments. Attachments are sent by sending
-- emails in "multipart/mixed" MIME format. Specify that MIME format when
-- beginning an email with begin_mail().
-- Send a single text attachment.
PROCEDURE attach_text(conn IN OUT NOCOPY utl_smtp.connection,
data IN VARCHAR2,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
inline IN BOOLEAN DEFAULT TRUE,
filename IN VARCHAR2 DEFAULT NULL,
last IN BOOLEAN DEFAULT FALSE);
-- Send a binary attachment. The attachment will be encoded in Base-64
-- encoding format.
PROCEDURE attach_base64(conn IN OUT NOCOPY utl_smtp.connection,
data IN RAW,
mime_type IN VARCHAR2 DEFAULT 'application/octet',
inline IN BOOLEAN DEFAULT TRUE,
filename IN VARCHAR2 DEFAULT NULL,
last IN BOOLEAN DEFAULT FALSE);
-- Send an attachment with no size limit. First, begin the attachment
-- with begin_attachment(). Then, call write_text repeatedly to send
-- the attachment piece-by-piece. If the attachment is text-based but
-- in non-ASCII or multi-byte character set, use write_mb_text() instead.
-- To send binary attachment, the binary content should first be
-- encoded in Base-64 encoding format using the demo package for 8i,
-- or the native one in 9i. End the attachment with end_attachment.
PROCEDURE begin_attachment(conn IN OUT NOCOPY utl_smtp.connection,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
inline IN BOOLEAN DEFAULT TRUE,
filename IN VARCHAR2 DEFAULT NULL,
transfer_enc IN VARCHAR2 DEFAULT NULL);
-- End the attachment.
PROCEDURE end_attachment(conn IN OUT NOCOPY utl_smtp.connection,
last IN BOOLEAN DEFAULT FALSE);
-- End the email.
PROCEDURE end_mail(conn IN OUT NOCOPY utl_smtp.connection);
-- Extended email API to send multiple emails in a session for better
-- performance. First, begin an email session with begin_session.
-- Then, begin each email with a session by calling begin_mail_in_session
-- instead of begin_mail. End the email with end_mail_in_session instead
-- of end_mail. End the email session by end_session.
FUNCTION begin_session RETURN utl_smtp.connection;
-- Begin an email in a session.
PROCEDURE begin_mail_in_session(conn IN OUT NOCOPY utl_smtp.connection,
sender IN VARCHAR2,
recipients IN VARCHAR2,
subject IN VARCHAR2,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
priority IN PLS_INTEGER DEFAULT NULL);
-- End an email in a session.
PROCEDURE end_mail_in_session(conn IN OUT NOCOPY utl_smtp.connection);
-- End an email session.
PROCEDURE end_session(conn IN OUT NOCOPY utl_smtp.connection);
END;
CREATE OR REPLACE PACKAGE BODY demo_mail IS
-- Return the next email address in the list of email addresses, separated
-- by either a "," or a ";". The format of mailbox may be in one of these:
-- someone@some-domain
-- "Someone at some domain" <someone@some-domain>
-- Someone at some domain <someone@some-domain>
FUNCTION get_address(addr_list IN OUT VARCHAR2) RETURN VARCHAR2 IS
addr VARCHAR2(256);
i pls_integer;
FUNCTION lookup_unquoted_char(str IN VARCHAR2,
chrs IN VARCHAR2) RETURN pls_integer AS
c VARCHAR2(5);
i pls_integer;
len pls_integer;
inside_quote BOOLEAN;
BEGIN
inside_quote := false;
i := 1;
len := length(str);
WHILE (i <= len) LOOP
c := substr(str, i, 1);
IF (inside_quote) THEN
IF (c = '"') THEN
inside_quote := false;
ELSIF (c = '\') THEN
i := i + 1; -- Skip the quote character
END IF;
GOTO next_char;
END IF;
IF (c = '"') THEN
inside_quote := true;
GOTO next_char;
END IF;
IF (instr(chrs, c) >= 1) THEN
RETURN i;
END IF;
<<next_char>>
i := i + 1;
END LOOP;
RETURN 0;
END;
BEGIN
addr_list := ltrim(addr_list);
i := lookup_unquoted_char(addr_list, ',;');
IF (i >= 1) THEN
addr := substr(addr_list, 1, i - 1);
addr_list := substr(addr_list, i + 1);
ELSE
addr := addr_list;
addr_list := '';
END IF;
i := lookup_unquoted_char(addr, '<');
IF (i >= 1) THEN
addr := substr(addr, i + 1);
i := instr(addr, '>');
IF (i >= 1) THEN
addr := substr(addr, 1, i - 1);
END IF;
END IF;
RETURN addr;
END;
-- Write a MIME header
PROCEDURE write_mime_header(conn IN OUT NOCOPY utl_smtp.connection,
name IN VARCHAR2,
value IN VARCHAR2) IS
BEGIN
utl_smtp.write_data(conn, name || ': ' || value || utl_tcp.CRLF);
END;
-- Mark a message-part boundary. Set <last> to TRUE for the last boundary.
PROCEDURE write_boundary(conn IN OUT NOCOPY utl_smtp.connection,
last IN BOOLEAN DEFAULT FALSE) AS
BEGIN
IF (last) THEN
utl_smtp.write_data(conn, LAST_BOUNDARY);
ELSE
utl_smtp.write_data(conn, FIRST_BOUNDARY);
END IF;
END;
PROCEDURE mail(sender IN VARCHAR2,
recipients IN VARCHAR2,
subject IN VARCHAR2,
message IN VARCHAR2) IS
conn utl_smtp.connection;
BEGIN
conn := begin_mail(sender, recipients, subject);
write_text(conn, message);
end_mail(conn);
END;
FUNCTION begin_mail(sender IN VARCHAR2,
recipients IN VARCHAR2,
subject IN VARCHAR2,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
priority IN PLS_INTEGER DEFAULT NULL)
RETURN utl_smtp.connection IS
conn utl_smtp.connection;
BEGIN
conn := begin_session;
begin_mail_in_session(conn, sender, recipients, subject, mime_type,
priority);
RETURN conn;
END;
PROCEDURE write_text(conn IN OUT NOCOPY utl_smtp.connection,
message IN VARCHAR2) IS
BEGIN
utl_smtp.write_data(conn, message);
END;
PROCEDURE write_mb_text(conn IN OUT NOCOPY utl_smtp.connection,
message IN VARCHAR2) IS
BEGIN
utl_smtp.write_raw_data(conn, utl_raw.cast_to_raw(message));
END;
PROCEDURE write_raw(conn IN OUT NOCOPY utl_smtp.connection,
message IN RAW) IS
BEGIN
utl_smtp.write_raw_data(conn, message);
END;
PROCEDURE attach_text(conn IN OUT NOCOPY utl_smtp.connection,
data IN VARCHAR2,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
inline IN BOOLEAN DEFAULT TRUE,
filename IN VARCHAR2 DEFAULT NULL,
last IN BOOLEAN DEFAULT FALSE) IS
BEGIN
begin_attachment(conn, mime_type, inline, filename);
write_text(conn, data);
end_attachment(conn, last);
END;
PROCEDURE attach_base64(conn IN OUT NOCOPY utl_smtp.connection,
data IN RAW,
mime_type IN VARCHAR2 DEFAULT 'application/octet',
inline IN BOOLEAN DEFAULT TRUE,
filename IN VARCHAR2 DEFAULT NULL,
last IN BOOLEAN DEFAULT FALSE) IS
i PLS_INTEGER;
len PLS_INTEGER;
BEGIN
begin_attachment(conn, mime_type, inline, filename, 'base64');
-- Split the Base64-encoded attachment into multiple lines
i := 1;
len := utl_raw.length(data);
WHILE (i < len) LOOP
IF (i + MAX_BASE64_LINE_WIDTH < len) THEN
utl_smtp.write_raw_data(conn,
utl_encode.base64_encode(utl_raw.substr(data, i,
MAX_BASE64_LINE_WIDTH)));
ELSE
utl_smtp.write_raw_data(conn,
utl_encode.base64_encode(utl_raw.substr(data, i)));
END IF;
utl_smtp.write_data(conn, utl_tcp.CRLF);
i := i + MAX_BASE64_LINE_WIDTH;
END LOOP;
end_attachment(conn, last);
END;
PROCEDURE begin_attachment(conn IN OUT NOCOPY utl_smtp.connection,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
inline IN BOOLEAN DEFAULT TRUE,
filename IN VARCHAR2 DEFAULT NULL,
transfer_enc IN VARCHAR2 DEFAULT NULL) IS
BEGIN
write_boundary(conn);
write_mime_header(conn, 'Content-Type', mime_type);
IF (filename IS NOT NULL) THEN
IF (inline) THEN
write_mime_header(conn, 'Content-Disposition',
'inline; filename="'||filename||'"');
ELSE
write_mime_header(conn, 'Content-Disposition',
'attachment; filename="'||filename||'"');
END IF;
END IF;
IF (transfer_enc IS NOT NULL) THEN
write_mime_header(conn, 'Content-Transfer-Encoding', transfer_enc);
END IF;
utl_smtp.write_data(conn, utl_tcp.CRLF);
END;
PROCEDURE end_attachment(conn IN OUT NOCOPY utl_smtp.connection,
last IN BOOLEAN DEFAULT FALSE) IS
BEGIN
utl_smtp.write_data(conn, utl_tcp.CRLF);
IF (last) THEN
write_boundary(conn, last);
END IF;
END;
PROCEDURE end_mail(conn IN OUT NOCOPY utl_smtp.connection) IS
BEGIN
end_mail_in_session(conn);
end_session(conn);
END;
FUNCTION begin_session RETURN utl_smtp.connection IS
conn utl_smtp.connection;
BEGIN
-- open SMTP connection
conn := utl_smtp.open_connection(smtp_host, smtp_port);
utl_smtp.helo(conn, smtp_domain);
RETURN conn;
END;
PROCEDURE begin_mail_in_session(conn IN OUT NOCOPY utl_smtp.connection,
sender IN VARCHAR2,
recipients IN VARCHAR2,
subject IN VARCHAR2,
mime_type IN VARCHAR2 DEFAULT 'text/plain',
priority IN PLS_INTEGER DEFAULT NULL) IS
my_recipients VARCHAR2(32767) := recipients;
my_sender VARCHAR2(32767) := sender;
BEGIN
-- Specify sender's address (our server allows bogus address
-- as long as it is a full email address ([email protected]).
utl_smtp.mail(conn, get_address(my_sender));
-- Specify recipient(s) of the email.
WHILE (my_recipients IS NOT NULL) LOOP
utl_smtp.rcpt(conn, get_address(my_recipients));
END LOOP;
-- Start body of email
utl_smtp.open_data(conn);
-- Set "From" MIME header
write_mime_header(conn, 'From', sender);
-- Set "To" MIME header
write_mime_header(conn, 'To', recipients);
-- Set "Subject" MIME header
write_mime_header(conn, 'Subject', subject);
-- Set "Content-Type" MIME header
write_mime_header(conn, 'Content-Type', mime_type);
-- Set "X-Mailer" MIME header
write_mime_header(conn, 'X-Mailer', MAILER_ID);
-- Set priority:
-- High Normal Low
-- 1 2 3 4 5
IF (priority IS NOT NULL) THEN
write_mime_header(conn, 'X-Priority', priority);
END IF;
-- Send an empty line to denotes end of MIME headers and
-- beginning of message body.
utl_smtp.write_data(conn, utl_tcp.CRLF);
IF (mime_type LIKE 'multipart/mixed%') THEN
write_text(conn, 'This is a multi-part message in MIME format.' ||
utl_tcp.crlf);
END IF;
END;
PROCEDURE end_mail_in_session(conn IN OUT NOCOPY utl_smtp.connection) IS
BEGIN
utl_smtp.close_data(conn);
END;
PROCEDURE end_session(conn IN OUT NOCOPY utl_smtp.connection) IS
BEGIN
utl_smtp.quit(conn);
END;
END;
/ -
Can not view (some) emails with attachments
There has already been some discussion about individuals getting the "This message has not been downloaded from the server" error.
http://discussions.apple.com/message.jspa?messageID=4983643
Has anyone found a solution to this problem? I am using GMail and am having problems reading (some) emails with attachments. I can read the first several lines through the preview view, but can not open (some) emails without getting the "This message has not been downloaded from the server" error.
The problem appears to be completely random. The problem occurs sometimes after I open the email on my computer, and other times it occurs before I open the email on my computer. And sometimes opening the email on my computer does not cause any problem opening the email on my phone.
I have seen this problem on two different phones now and have re-created the email accounts on both phone several times. But the problems keeps (eventually) appearing--for some, but not all emails.
PowerBook G4, Macintosh 512K iPod nano (2nd Gen 8GB), iPhone (8GB)So, I think things are actually sending/downloading and it's just taking time and the iphone is defaulting to the error message.
I don't think that's the case. I have several week-old messages on my iPhone (each under 300k) that still say "The message has not been downloaded from the server."
I've been connected to wifi for over an hour now, so that's plenty of time to downloaded these few small emails. I can read the "preview" of the message from the Inbox screen, but when I click on the message itself, I get the error.
And, those messages with the attachments that I was able to open this morning? I can no longer open them now. Very, very frustrating. -
Hi,
I have an issue with some PDF documents & some MS Office documents, notably MS Word when received in eMail as attachments not displaying properly on iPhones, iPad 2s & new iPads?
PDF docs - areas of the doc only show as grey splotches regardles of viewer
MS Word Docs -
inserted graphics don't display at all,
tables & lists especially with borders are broken &
tables & lists missing the borders &
tables & lists missing the 1st 1-2 lines of the lists/tables.
This is replicated on iPhone 4s, iPhone 4Ss, iPad 2s, iPad new (x2)
It certainly happens in iOS 5.1.1 & iOS 5.1
We believe it all worked aok in iOS 5.0.1(?) & prior
There is no problems reading/seeing these PDF & Word docs on anything other than iDevices.
This is rather critical for us & if not quickly fixed/rectified will prevent us from further purchases of these devices
Rolling back to iOS 5.0.1 or prior I believe isn't possible because of the BaseBand update(?) & isn't much of an option because of the quite noticeable Battery/Charging/WiFi improvements in 5.1 & 5.1.1Hi,
I logged a call with AppleCare & have since had explained why this occurs (some time ago)
I'll try to explain what was indicated to me.
iOS has a limited Font Set & this affects what PDFs can display. You need to use iOS supported fonts in your PDFs to see/read them properly
These supported fonts are indicated here => http://support.apple.com/kb/HT4980
Regards MS office docs, iOS doesn't have much of an API to work with MS Office documents at all so is stuck with 3rd Party Apps to try to do it.
Unfortunately Mail in/on iOS uses the API to attempt to open/use MS Office attachments unless you tell it to use an App to open the attachment.
I have had success opening & reading MS office docs now with CloudOn, but find it slow & very awkward to use.
Not too sure if this helps others, but at least it explains why this is occurring -
Hey Guys,
The title says it all. Whenever I receive an email with attachments, I will try to forward the email to someone with the attachments. Mac Mail shows that the attachments are attached, but the receiver says the attachments are not there. Our mail host is Rackspace. We are setup with IMAP. It should be noted that we are experiencing similar issues with OS 10.5.8 with Mac Mail 3.6 (936).
We assumed Rackspace was the problem, so we logged into their webmail portal and tested it and the attachments were received as normal, which points everything back to Mac Mail. We even had an ISP change but the problem do not change.
I have researched the problem, and there seems to be evidence of this being a known bug with Mac Mail, but I am hoping there is a workaround. The company is unwilling to move to a different mail client since they use Daylite 4, which does not support Thunderbird.Back up all data.
1. Triple-click the line below to select it:
~/Library/Mail/Bundles
Right-click or control-click the highlighted line and select
Services ▹ Open
from the contextual menu. A folder may open, or you may get an error message that the item can't be found. Either result is normal. If the folder does open and has contents, move the contents to the Desktop. Relaunch Mail and test. If there's no change, put the contents of the folder back and quit Mail again.
2. Repeat with this line:
/Library/Mail/Bundles
This time you may be prompted for your login password when you remove the items. Make sure they're removed from the folder and not just copied to the Desktop. If necessary, copy them first and then move the originals to the Trash. -
Mail; emails with attachments are not shown in Sent folder
Since upgrading to Yosemite I have had lots of problems with Mail.
One is that it seems that some emails with attachments do not show in the Sent folder! Some of them can be found further down, On my Mac in a folder called Recreated letters, or something like that in English.
Anyone have the same problem?
NinaWhat is your version of TB? Have you changed anything since the last time it worked? Mail servers changes done by your provider are also possible.
* Does it occur when an e-mail is sent immediately (before a possible auto-save, see below)?
* Can you copy any mail from any folder to the Sent folder?
I've heard of the error "saving to Sent" with older versions of TB, but not related to attachments.
So, for the general saving to Sent error, some people report that this
https://kb.wisc.edu/wiscmail/page.php?id=3679
has helped them.
I've also heard that turning off "Auto save every .. minutes" in TB preferences > Composition > General has helped some in older versions and IMAP.
You may check this page: <br>http://kb.mozillazine.org/IMAP:_advanced_account_configuration
PS: You seem to use Firefox 16, an extremely outdated and insecure browser version. Same for Thunderbird? To be on the safe side (bugs, security), IMHO you should really upgrade regularly to the latest versions, of course backing up your profiles first, especially with TB ( http://kb.mozillazine.org/Profile_backup ). -
Mail not receiving emails with attachments
Hi
I'd appreciate any suggestions in relation to the following.
My wife and I both run computers from the one account, Mail on her PowerBook logging in through my name and password. Until recently, we have had no problems at all. However, it has come to light that my wife has not been receiving emails with attachments for some time. To test this, my wife sent an email with an attachment to her home email address from work, and copied it to me. I received the email and the attachment on my PC; my wife's Mac did not receive the email. I then forwarded the email with the attachment to her computer; this was successful. This would suggest some problem with her Mail account on the Mac. However, the configuration has not been changed. Is it possible for it just to stop working for some reason?I'm using a PC for my email at the moment. I'm not sure if all my wife's emails have been downloaded. However, Mail has made a Home/Mail/MessageUidsAlreadyDowloaded file. This was created when I sent an email to test what happened. I was unable to make Mail download all her emails, so I guess they must have gone from the server. She has a different email address to mine, but it's run from the same ISP account; as I said, she logs in, automatically, through Mail to her email. I have contacted the ISP about it, but they are unable to see any trace of emails that colleagues have sent my wife and which she sends home to herself. All of these files happen to have attachments, but I cannot see any setting of Mail which would account for them being rejected. Also, I can't be entiurely sure that only emails with attachments don't get through; there may be others, 'unattached'.
Thanks for your continued assistance. -
One sender sent me 3 emails, two with attachments and one without attachment. I could see all the emails on my Blackberry but I didn't see emails with attachments on my computer. thanks for the help.
I would think this is an issue with your email provider, not the BlackBerry. What email service do you use?
1. Please thank those who help you by clicking the "Like" button at the bottom of the post that helped you.
2. If your issue has been solved, please resolve it by marking the post "Solution?" which solved it for you! -
How can i secure email with attachments using coldfusion
Hi,
I need to send emails with attachments containg word, excel or PDF documents using cfmail. However this email needs to be really secure. How is the best way to secure the entire email with its attachments.
Any ideas appreciated
Thanks
ZubairHi ,
I hope the following will help you..., using the UTL_SMTP db package.
DECLARE
c UTL_SMTP.CONNECTION;
PROCEDURE send_header(name IN VARCHAR2, header IN VARCHAR2) AS
BEGIN
UTL_SMTP.WRITE_DATA(c, name || ': ' || header || UTL_TCP.CRLF);
END;
BEGIN
-- Open connection to SMTP gateway
c := UTL_SMTP.OPEN_CONNECTION('smtp.server.acme.com');
UTL_SMTP.HELO(c, 'acme.com');
UTL_SMTP.MAIL(c, '[email protected]');
UTL_SMTP.RCPT(c, '[email protected]');
UTL_SMTP.OPEN_DATA(c);
send_header('From', '"Oracle Admin" ');
send_header('To', '"Bob Smith" ');
send_header('Subject', 'Automated Database Email');
UTL_SMTP.WRITE_DATA(c, utl_tcp.CRLF || 'This is an automated email from the Oracle database.');
UTL_SMTP.WRITE_DATA(c, utl_tcp.CRLF || 'The database is working for you!');
UTL_SMTP.CLOSE_DATA(c);
UTL_SMTP.QUIT(c);
END;
Simon -
Email not in sent box when I send email with attachments in Word.
Several times, I've noticed that when I send an email with attachments in Word = .doc format, I don't find the emails in my Sent Box…Why?
Then this sounds like a problem at the receiving end. More information is needed.
-
When I send an email with attachments and open them on my ipad some of them open but others do not
When I send an email with attachments and open them on my ipad some of them open but others do not
What are the types that won't open?
Do you have an App that can open those types of files?
Maybe you are looking for
-
Privilege problem after installing 10.4.7 update
I started experiencing 1. not able to print to network printer from any applications - get error 2. Not able to mount fileshare disk on MacBook located on my local network - wheel just spins forever and need to stop process. 3. Adobe Illustrator and
-
How to know if a wire is connected to a control (in the case of subVI)?
Hello, I would know if it is possible to know if a wire (in the caller VI) is connected to the subVI control ,or not. - There is any function to test a control to know if it is wired in the caller VI, or not ? OR - Do I test control defaults values a
-
My kids have been playing on my iMac and I now have a black box on the screen that describes where the cursor is or what I am typing etc. Can anyone help me with removing this box I thought it might be subtitles but not sure?
-
Recording the total of a rolling sequence
I am recording times taken for a production sequence to complete. The time is recorded in seconds by the plc, which counts upward from zero until the production sequence has completed, after a short pause the plc resets itself to zero and repeats the
-
Error in Creating Custom Business Methods using ADF Business Comp. Tutorial
I've been working with Jdev 10g Preview for a while. Now that we have Jdev 10g, I have to unlearn some of the Preview methods and learn the "real" way of doing things. To that end, I went out to the "Creating Custom Business Methods using ADF Busines