Error in calling a subroutine in Fortan

Question

I am trying to get this program to work. It is designed to accept integer values and sort them into order. For some reason when the program is executed an error occurs. I'm not sure why, but I think it may be the way I am calling the subroutine? Does anyone know?
The program is:
program sorter
read*,value
call sort(value)
end program sorter
subroutine sort(value)
implicit none
integer,dimension(:),intent(inout) :: value
integer :: first,temp,number,index,i,j
number=size(value)
do i=1,number-1
first=value(i)
index=i
do j=i+1,number
if (value(j) < first) then
first = value(j)
index=j
end if
end do
if (index /= i) then
temp=value(i)
value(i)=value(index)
value(index)=temp
end if
end do
print*,value
end subroutine sort

Answer 1

A couple of comments:
* In the main program, the 'Value' variable isn't declared
* If you are compiling this as an F90/F95 code, the subroutine 'sort' needs to be declared with an interface
program sorter
interface sort
   subroutine sort(value)
      integer, dimension(:), intent(inout) :: value
   end subroutine
end interface
integer, dimension(10) :: value
read*,value
call sort(value)
end program sorter
subroutine sort(value)
implicit none
integer,dimension(:),intent(inout) :: value
integer :: first,temp,number,index,i,j
number=size(value)
do i=1,number-1
   first=value(i)
   index=i
   do j=i+1,number
      if (value(j) < first) then
         first = value(j)
         index=j
      end if
   end do
   if (index /= i) then
      temp=value(i)
      value(i)=value(index)
      value(index)=temp
   end if
end do
print*,value
end subroutine sort% f90 -o sorter sorter.f90
% sorter
3 4 5 1 2 9 0 8 7 6
0 1 2 3 4 5 6 7 8 9