Expand a Regular Expression

Question

How do I expand a regular expression?
I mean if I have '12[3-5]' as my starting point. I want to see:
result
12[3-5]
123
124
125
Any help will be appreciated.
Thanks

Answer 1

I'd say you need a procedure that "interprets" a regular expression for generating all available string - good luck on this one. For short strings you could also try a "brute force" string generator that generates all possible combinations and filters them through a regular expression:
DECLARE
  PROCEDURE check_regex(
    p_regex   IN VARCHAR2
  , p_max_len IN NUMBER
  IS
    c_chars CONSTANT VARCHAR2(10) := '0123456789';
    TYPE t_counter IS TABLE OF PLS_INTEGER INDEX BY PLS_INTEGER;
    v_counter t_counter;
    v_exit   BOOLEAN := FALSE;
    v_string VARCHAR2(255);
  BEGIN  
    -- init loop
    FOR i IN 1..p_max_len
    LOOP
      v_counter(i) := 1;
    END LOOP;
    -- show regular expression
    DBMS_OUTPUT.put_line(p_regex); 
    WHILE NOT v_exit
    LOOP
      -- start generation
      v_string := '';
      FOR i IN 1..p_max_len
      LOOP
        v_string := v_string || SUBSTR(c_chars, v_counter(i), 1);
      END LOOP;
      -- filter the generated string through the regular expression
      IF REGEXP_LIKE(v_string, p_regex) THEN
         DBMS_OUTPUT.put_line(v_string); 
      END IF;
      -- increment loop
      FOR i IN REVERSE 1..p_max_len
      LOOP
        v_counter(i) := v_counter(i) + 1;     
        IF v_counter(i) > LENGTH(c_chars) THEN
           IF i > 1 THEN
              v_counter(i) := 1;
           ELSE
              v_exit := TRUE;  
           END IF;
        ELSE
           -- no further processing required
           EXIT;  
        END IF;  
      END LOOP;        
    END LOOP; 
  END check_regex;
BEGIN
  check_regex(p_regex => '12[3-5]', p_max_len => 3);
END;  If you come up with a better solution, I'd be interested.
C.