Export of global class
Hi everybody.
I want export a global class (SE24, Object Builder) to a local class in a INCLUDE, but unfortunally the Object Builder has no export function.
Does anybody know a way to change a global class to a local class?
Thx.
There's no easy way. I'm at a bit of a loss why you'd want to replace a global class witha local class that you include in your programs. What do you gain?
But if you insist, you can always cut and paste the public/private/protected sections of your class (making suitable modifications and assuming you're not on an old SAP version), and then you'd have to cut and paste the method implementations in as well.
Printing a class to a the spool is a fairly good way of getting all its details. Another alternative is to search these forums for where the includes that actually make up the class are - it should be fairly simple to write a program that would take that source code and construct local classes from it. But I still don't see the point.
Similar Messages
-
How to give a value range in export parameter (global class)
hi all,
I have created a class-method called get_po_date. In this i had export parameter as qmfe-qmnum. If i give qmfe-qmnum in import parameter in class, i am able to give only one value at one time, but i need a range of values at a time. Instead of qmfe-qmnum in associated type, i have given 'LXHME_RANGE_C12' ( a range table for char 12 ). the thing is i wanted to select this range in select-options. but still iam getting <b>not type compatible syntax error</b>. can any body solve my problem,
feel free to ask if any confusion with my question.
Best Regards,
abhilash.Hello Abhilash
Instead of using a specific range (where field LOW and HIGH are of type QMNUM) you can use a <b>generic </b>select option (of type <b>RSDSSELOPT</b>). Have a look at the following sample report <b>ZUS_SDN_SELOPTIONS</b>.
*& Report ZUS_SDN_SELOPTIONS
REPORT zus_sdn_seloptions.
TABLES: qmfe.
DATA:
gt_data TYPE STANDARD TABLE OF qmfe,
gt_data_x TYPE STANDARD TABLE OF qmfe,
gt_selopt TYPE rseloption, " generic table type for selopts
gs_selopt TYPE rsdsselopt.
START-OF-SELECTION.
SELECT * FROM qmfe INTO TABLE gt_data
WHERE ( qmnum BETWEEN '000000000001' AND '000000000500' ).
gs_selopt-sign = 'I'.
gs_selopt-option = 'BT'.
gs_selopt-low = '000000000001'.
gs_selopt-high = '000000000500'.
APPEND gs_selopt TO gt_selopt.
SELECT * FROM qmfe INTO TABLE gt_data_x
WHERE ( qmnum IN gt_selopt ).
IF ( gt_data = gt_data_x ).
WRITE: 'Selected data are equal.'.
ELSE.
WRITE: 'Selected data are NOT equal.'.
ENDIF.
END-OF-SELECTION.
Since RSDSSELOPT and RSELOPTION are global DDIC objects they can be used in <i>public </i>methods.
Regards
Uwe -
Export global classes to a local file
Hi,
is it possible to export a global class with all of its attributes, types, methods and more to a local file for archiving purposes?
We are currently using ECC 6.0, btw.
MichaelSure, via [SAPlink|http://code.google.com/p/saplink/]
Regards
Marcin -
How to export local class to global class in abap ?
is there any report that can export local class to a global class ?
thanks !Hi,
you can go to SE24 and there you can create a new class with reference to the class already created and your new class will have the same properties as your local class. -
Export global classes into program
Hello,
it is possible to import local classes from program into
class builder.
I would like to export global classes into program. Is there such a thing (4.6C)?
Thank you, in advance for your responses.
Best regards
SergejSure, via [SAPlink|http://code.google.com/p/saplink/]
Regards
Marcin -
Event handling in global class (abap object)
Hello friends
I have 1 problem regarding events in abap object... how to handel an event in global class in se24 .
Regards
Reema jain.
Message was edited by:
Reema JainHello Reema
The following sample report shows how to handle event in principle (see the § marks)..
The following sample report show customer data ("Header"; KNB1) in the first ALV list and sales areas ("Detail"; KNVV) for the selected customer (event double-click) in the second ALV list.
*& Report ZUS_SDN_TWO_ALV_GRIDS
REPORT zus_sdn_two_alv_grids.
DATA:
gd_okcode TYPE ui_func,
go_docking TYPE REF TO cl_gui_docking_container,
go_splitter TYPE REF TO cl_gui_splitter_container,
go_cell_top TYPE REF TO cl_gui_container,
go_cell_bottom TYPE REF TO cl_gui_container,
go_grid1 TYPE REF TO cl_gui_alv_grid,
go_grid2 TYPE REF TO cl_gui_alv_grid,
gs_layout TYPE lvc_s_layo.
DATA:
gt_knb1 TYPE STANDARD TABLE OF knb1,
gt_knvv TYPE STANDARD TABLE OF knvv.
"§1. Define and implement event handler method
" (Here: implemented as static methods of a local class)
* CLASS lcl_eventhandler DEFINITION
CLASS lcl_eventhandler DEFINITION.
PUBLIC SECTION.
CLASS-METHODS:
handle_double_click FOR EVENT double_click OF cl_gui_alv_grid
IMPORTING
e_row
e_column
es_row_no
sender.
ENDCLASS. "lcl_eventhandler DEFINITION
* CLASS lcl_eventhandler IMPLEMENTATION
CLASS lcl_eventhandler IMPLEMENTATION.
METHOD handle_double_click.
* define local data
DATA:
ls_knb1 TYPE knb1.
CHECK ( sender = go_grid1 ).
READ TABLE gt_knb1 INTO ls_knb1 INDEX e_row-index.
CHECK ( ls_knb1-kunnr IS NOT INITIAL ).
CALL METHOD go_grid1->set_current_cell_via_id
EXPORTING
* IS_ROW_ID =
* IS_COLUMN_ID =
is_row_no = es_row_no.
* Triggers PAI of the dynpro with the specified ok-code
CALL METHOD cl_gui_cfw=>set_new_ok_code( 'DETAIL' ).
ENDMETHOD. "handle_double_click
ENDCLASS. "lcl_eventhandler IMPLEMENTATION
START-OF-SELECTION.
SELECT * FROM knb1 INTO TABLE gt_knb1
WHERE bukrs = '1000'.
* Create docking container
CREATE OBJECT go_docking
EXPORTING
parent = cl_gui_container=>screen0
ratio = 90
EXCEPTIONS
OTHERS = 6.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Create splitter container
CREATE OBJECT go_splitter
EXPORTING
parent = go_docking
rows = 2
columns = 1
* NO_AUTODEF_PROGID_DYNNR =
* NAME =
EXCEPTIONS
cntl_error = 1
cntl_system_error = 2
OTHERS = 3.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Get cell container
CALL METHOD go_splitter->get_container
EXPORTING
row = 1
column = 1
RECEIVING
container = go_cell_top.
CALL METHOD go_splitter->get_container
EXPORTING
row = 2
column = 1
RECEIVING
container = go_cell_bottom.
* Create ALV grids
CREATE OBJECT go_grid1
EXPORTING
i_parent = go_cell_top
EXCEPTIONS
OTHERS = 5.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
"§2. Set event handler (after creating the ALV instance)
SET HANDLER: lcl_eventhandler=>handle_double_click FOR go_grid1. " Or:
" SET HANDLER: lcl_eventhandler=>handle_double_click FOR all instances.
CREATE OBJECT go_grid2
EXPORTING
i_parent = go_cell_bottom
EXCEPTIONS
OTHERS = 5.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Display data
gs_layout-grid_title = 'Customers'.
CALL METHOD go_grid1->set_table_for_first_display
EXPORTING
i_structure_name = 'KNB1'
is_layout = gs_layout
CHANGING
it_outtab = gt_knb1
EXCEPTIONS
OTHERS = 4.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
gs_layout-grid_title = 'Customers Details (Sales Areas)'.
CALL METHOD go_grid2->set_table_for_first_display
EXPORTING
i_structure_name = 'KNVV'
is_layout = gs_layout
CHANGING
it_outtab = gt_knvv " empty !!!
EXCEPTIONS
OTHERS = 4.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* Link the docking container to the target dynpro
CALL METHOD go_docking->link
EXPORTING
repid = syst-repid
dynnr = '0100'
* CONTAINER =
EXCEPTIONS
OTHERS = 4.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
* NOTE: dynpro does not contain any elements
CALL SCREEN '0100'.
* Flow logic of dynpro (does not contain any dynpro elements):
*PROCESS BEFORE OUTPUT.
* MODULE STATUS_0100.
*PROCESS AFTER INPUT.
* MODULE USER_COMMAND_0100.
END-OF-SELECTION.
*& Module STATUS_0100 OUTPUT
* text
MODULE status_0100 OUTPUT.
SET PF-STATUS 'STATUS_0100'. " contains push button "DETAIL"
* SET TITLEBAR 'xxx'.
* Refresh display of detail ALV list
CALL METHOD go_grid2->refresh_table_display
* EXPORTING
* IS_STABLE =
* I_SOFT_REFRESH =
EXCEPTIONS
OTHERS = 2.
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
* WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.
ENDMODULE. " STATUS_0100 OUTPUT
*& Module USER_COMMAND_0100 INPUT
* text
MODULE user_command_0100 INPUT.
CASE gd_okcode.
WHEN 'BACK' OR
'END' OR
'CANC'.
SET SCREEN 0. LEAVE SCREEN.
* User has pushed button "Display Details"
WHEN 'DETAIL'.
PERFORM entry_show_details.
WHEN OTHERS.
ENDCASE.
CLEAR: gd_okcode.
ENDMODULE. " USER_COMMAND_0100 INPUT
*& Form ENTRY_SHOW_DETAILS
* text
* --> p1 text
* <-- p2 text
FORM entry_show_details .
* define local data
DATA:
ld_row TYPE i,
ls_knb1 TYPE knb1.
CALL METHOD go_grid1->get_current_cell
IMPORTING
e_row = ld_row.
READ TABLE gt_knb1 INTO ls_knb1 INDEX ld_row.
CHECK ( syst-subrc = 0 ).
SELECT * FROM knvv INTO TABLE gt_knvv
WHERE kunnr = ls_knb1-kunnr.
ENDFORM. " ENTRY_SHOW_DETAILS
Regards
Uwe -
How to use global classes and display returned data?
Hello experts,
I have the following code in a program which accesses a global class (found in the class library). It executes one it's static methods. What I would like to do is to get hold of some elements of the returned data. How do I do that please?
Your help is greatly appreciated.
***Use global class CL_ISU_CUSTOMER_CONTACT
DATA: o_ref TYPE REF TO CL_ISU_CUSTOMER_CONTACT.
DATA: dref_tab LIKE TABLE OF O_ref.
DATA: begin OF o_ref2,
CONTACTID TYPE CT_CONTACT,
P_INSTANCES TYPE string,
P_CONTEXT TYPE CT_BPCCONF,
P_CONTROL TYPE ISU_OBJECT_CONTROL_DATA,
P_DATA TYPE BCONTD, "<<<=== THIS IS A STRUCTURE CONTAINING OTHER DATA ELEMENTS
P_NOTICE TYPE EENOT_NOTICE_AUTO,
P_OBJECTS TYPE BAPIBCONTACT_OBJECT_TAB,
P_OBJECTS_WITH_ROLES TYPE BAPIBCONTACT_OBJROLE_TAB,
end of o_ref2.
TRY.
CALL METHOD CL_ISU_CUSTOMER_CONTACT=>SELECT "<<<=== STATIC METHODE & PUBLIC VISIBILITY
EXPORTING
X_CONTACTID = '000001114875' "Whatever value here
RECEIVING
Y_CONTACTLOG = o_ref
ENDTRY.
WHAT I WOULD LIKE TO DO IS TO MOVE o_ref TO o_ref2 and then display:
1) P_DATA-PARTNER
2) P_DATA-ALTPARTNER
How can I do this please?I now have the following code. But when I check for syntax I get different error. They are at the end of the list.
Here is the code the way it stands now:
================================================
***Use global class CL_ISU_CUSTOMER_CONTACT
DATA: oref TYPE REF TO CL_ISU_CUSTOMER_CONTACT.
DATA: dref_tab LIKE TABLE OF oref.
DATA: begin OF oref2,
CONTACTID TYPE CT_CONTACT,
P_INSTANCES TYPE string,
P_CONTEXT TYPE CT_BPCCONF,
P_CONTROL TYPE ISU_OBJECT_CONTROL_DATA,
P_DATA TYPE BCONTD, "THIS IS A STRUCTURE CONTAINING OTHER DATA ELEMENTS
P_NOTICE TYPE EENOT_NOTICE_AUTO,
P_OBJECTS TYPE BAPIBCONTACT_OBJECT_TAB,
P_OBJECTS_WITH_ROLES TYPE BAPIBCONTACT_OBJROLE_TAB,
end of oref2.
TRY.
CALL METHOD CL_ISU_CUSTOMER_CONTACT=>SELECT " STATIC METHODE & PUBLIC VISIBILITY
EXPORTING
X_CONTACTID = '000001114875' "Whatever value here
RECEIVING
Y_CONTACTLOG = oref
ENDTRY.
field-symbols: <FS1> type any table,
<wa_oref2> type any.
create data dref_tab type handle oref. " <<===ERROR LINE
assign dref->* to <FS1>.
Loop at <FS1> assigning <wa_oref2>.
*use <wa_orfe2> to transfer into oref2.
endloop.
write: / 'hello'.
=========================================
Here are the errors I get:
The field "DREF" is unknown, but there is a field with the similar name "OREF" . . . .
When I replace itr by OREF I get:
"OREF" is not a data reference variable.
I then try to change it to dref_tab. I get:
"DREF_TAB" is not a data reference variable.
Any idea? By the way, must there be a HANDLE event for this to work?
Thanks for your help. -
How to use abap memory in global class
Hi experts,
I want to know how to use abap memory in global class. when i try write export and import statement its showing
error is export statement does not support in object oriented concept.
Thanks
Ramesh ManoharanHi Ramesh,
Export and import statements were not allowed to use in classes. Create a global variable in public section of that class of type of export parameter.Then pass value to the global variable of class by calling that class.
by
Prasad GVK. -
Using container from another global class
There are two global classes being used by me in a program - Class A and Class B.
Class A contains the container to display ALV.
Class B contains the logic to display ALV.
class B is used as attribute class in Class A.
How is that I can use the container from Class A from class B?Like this?
class A ...
public section.
methods: get_container returining value(ref_cont) type ref to ...,
constructor.
private section.
data ref_container type ref to....
endclass.
class A impl...
method get_container.
ref_cont = me->ref_container.
endmethod.
method constructor.
create object ref_container ....
endmethod.
endclass.
class B ...
public section.
methods: constructor,
display alv.
private section.
data ref_alv type ref to....
data ref_A type ref to A.
endclass.
class B impl...
method constructor.
data lr_container type ref to ...
if ref_A is not bound.
create object ref_A.
endif.
"get container from class A
lr_container = ref_A->get_container( ).
create object ref_alv
exporting
container = lr_container
endmethod.
method display_alv.
call method ref_alv->set_table_for_first_display...
endmethod.
endclass.
If storing container's reference under local LR_CONTAINER in class B constructor causes not displaying ALV, you will have to store this under class B attribute. Alternative would be directly indicating the container reference as parent to ALV by calling functional method like
create object ref_alv
exporting
container = ref_A->get_container( )
this will however work in recent releases of SAP NW AS.
Regards
Marcin -
Hi all,
I am working on handling events in global classes.
but my event is not triggererd,i m not able to find where it's going wrong.
Below is my code.
Global Class:ZCL_TEST_EVENT
events :EXCEEDEDRANGE
methods:CHECKRANGE,DISPLAYVENDOR.
Checkrange is event handler for exceededrange.
below is the code for methods.
method checkrange.
write:/ 'Vendor not within the range'(001).
exit.
endmethod.
method displayvendor.
DATA : exlfa1 TYPE lfa1.
IF imlifnr NOT BETWEEN 1000 AND 2000.
RAISE EVENT exceededrange.
ENDIF.
SELECT SINGLE * FROM lfa1
INTO exlfa1
WHERE lifnr = imlifnr
IF sy-subrc = 0.
WRITE : / exlfa1-lifnr,exlfa1-name1.
ELSE.
WRITE : / 'No vendor found'(002).
ENDIF.
endmethod.
below is the report I developed.
REPORT ztest_113.
parameters :plifnr type lfa1-lifnr obligatory.
data : obj type ref to ZCL_TEST_EVENT.
START-OF-SELECTION.
CREATE OBJECT obj.
CALL METHOD obj->displayvendor
EXPORTING
imlifnr = plifnr
Please helpYes, you do need to write the SET HANDLER statement. As per your current design, you can set the event handler in your method CONSTRUCTOR. Like:
method constructor.
SET HANDLER me->CHECKRANGE FOR me.
endmethod.
Regards,
Naimesh Patel -
Declaration of Rabge table Paramater in Global class method
Hi Friends,
I have created a Global class with a method GET_DATA.
In that method,i have written the like :
select * from kna1 into table it_kna1where kunnr in S_kunnr.
But, I am getting the error with Range table S_KUNNR.
Kindly, Let me know how I should Declare S_KUNNR in parameter list of GET_DATA, what should be its associated data type?
Regards,
Xavier.p
Edited by: Xavier on Jul 16, 2009 3:50 PM1) Create a Public Type for ranges. You can do it in SE11 or in SE24. I generally prefer doing it in SE24.
Go to Types Tab
Declare your range type
TYPES: ty_r_kunnr type range of kna1-kunnr.
2) Use this type to declare your method's parameters:
IR_KUNNR TYPE TY_R_KUNNR
3) When calling the method you can do like:
CALL METHOD O_REF->GET_dATA
EXPORTING
IR_KUNNR = S_KUNNR[].
Regards,
Naimesh Patel -
Global classes / Doppelclick
Hello Every Body,
please can someone tell me how can implement Doppelclick using Global classes.!!
Best regards.
danielHello Daniel
I assume you want to handle DOUBLE_CLICK events of controls (e.g. ALV grid, tree) using global classes.
That's a piece of cake. Below I outline a possible procedure:
(1) Create your control instance (e.g. go_grid, CL_GUI_ALV_GRID)
(2) Create an instance of your global class. The CONSTRUCTOR method may look like this:
CREATE OBJECT go_myclass
EXPORTING
io_instance = go_grid. " Assumption: class should only handle ALV grid events
METHOD constructor.
me->mo_grid = io_instance. " class may have instance attribute for grid instance
me->set_handler( ). " perhaps private method for setting event handler
ENDMETHOD.
METHOD set_handler.
SET HANDLER: handle_double_click FOR me->mo_grid.
ENDMETHOD.
(3) Create an event handler method (e.g. HANDLE_DOUBLE_CLICK for event DOUBLE_CLICK of cl_gui_alv_grid) within your global class.
That's it. As soon as the user double-clicks on a row in the ALV grid (go_grid) the method HANDLE_DOUBLE_CLICK of your global class will be called to handle the event.
Regards
Uwe -
Error while usind Private Method of a global class
HI All..
I created a global class (ZLINE_GLOBAL) which has TOT_DATA private method. I have to call this private method in my report, I know that using Friend class we can do this.
But it is not working and showing the same error " METHOD "TOT_DATA" is unknown or Private or Public..
code i tried is
CLASS c2 DEFINITION DEFERRED.
CLASS ZLINE_GLOBAL DEFINITION FRIENDS c2.
PUBLIC SECTION.
METHODS : m1.
PRIVATE SECTION.
METHODS: m2.
ENDCLASS.
CLASS ZLINE_GLOBAL IMPLEMENTATION .
METHOD m1.
WRITE : 'Public Method C1'.
ENDMETHOD. "M1
METHOD m2.
WRITE : 'Private Method C1'.
ENDMETHOD.
ENDCLASS.
CLASS c2 DEFINITION FRIENDS ZLINE_GLOBAL. "my friends are here, allow them access to my (C2's) private components
PUBLIC SECTION.
METHODS :m3.
ENDCLASS.
CLASS c2 IMPLEMENTATION.
METHOD m3.
DATA : obj TYPE REF TO ZLINE_GLOBAL.
CREATE OBJECT obj.
CALL METHOD obj->TOT_DATA. "here Iam calling Private method of global class
ENDMETHOD. "M3
ENDCLASS.
START-OF-SELECTION.
DATA obj_c2 TYPE REF TO c2.
CREATE OBJECT obj_c2.
obj_c2->m3( ).
can anybody help me on this..
MurthyHi Murthy,
Replace TOT_DATA with M2, you do not have any method by name "TOT_DATA" in your code.
CLASS c2 DEFINITION DEFERRED.
CLASS ZLINE_GLOBAL DEFINITION FRIENDS c2.
PUBLIC SECTION.
METHODS : m1.
PRIVATE SECTION.
METHODS: m2.
ENDCLASS.
CLASS ZLINE_GLOBAL IMPLEMENTATION .
METHOD m1.
WRITE : 'Public Method C1'.
ENDMETHOD. "M1
METHOD m2.
WRITE : 'Private Method C1'.
ENDMETHOD.
ENDCLASS.
CLASS c2 DEFINITION FRIENDS ZLINE_GLOBAL. "my friends are here, allow them access to my (C2's) private components
PUBLIC SECTION.
METHODS :m3.
ENDCLASS.
CLASS c2 IMPLEMENTATION.
METHOD m3.
DATA : obj TYPE REF TO ZLINE_GLOBAL.
CREATE OBJECT obj.
CALL METHOD obj->M2. "here Iam calling Private method of global class
ENDMETHOD. "M3
ENDCLASS.
START-OF-SELECTION.
DATA obj_c2 TYPE REF TO c2.
CREATE OBJECT obj_c2.
obj_c2->m3( ).
Regards,
Chen -
Creation of Material using BDC Session method & global class
Hi
Creation of Material using BDC Session method & global class by using oops.
can anyone plz help me outHi,
it looks like it's not possible to call this BAPI wihtout material number. Here is a quote from BAPI documentation.
When creating material master data, you must transfer the material
number, the material type, and the industry sector to the method. You
must also enter a material description and its language.
Cheers -
Download Global Class attributes
Hi...
I want to download the global class attributes into an excel. when i checked the menu there is no such option.. Is that possible to do.. Can anyone guide me...
Thanks in advance.
Kalpanashri Rajendran.Hi,
Assuming you are asking specifically about the global class "Attributes" and not all information about the global class itself. To get the "Attributes" in a spreadsheet you can try this work-around:
1. Run transaction SE84 Repository Info System.
2. Expand the "Class Library" branch.
3. Double-click the "Attributes" node.
4. Enter your global class name and run the search.
5. Once the list of attributes is displayed, choose menu path System -> List -> Save -> Local File.
6. Choose "Spreadsheet" format in the popup.
7. Give a file path and name for your spreadsheet.
8. You should now have a spreadsheet with all the "Attributes" of your global class.
Best Regards,
Jamie
Maybe you are looking for
-
Hotmail is completely dysfunctional since the start of this week!! Go across the parking lot with a 3/4 inch pipe that is say 24 inches long and persuade them from screwing up the system!! If windows explorer was not a virus magnet maybe more people
-
Third party applications don`t work!!!!!!
Hi I really need help here I have a bb 9530 verizon(my uncle`s) cause my last phone broke a bb 9300 3G.i have set up the bb but I really don't know what I'm doing so every thing works fine except third party applications because when ever I go into a
-
Signal Express not activated with Labview Full Development System Volume License
I'm using a volume license manager to generate license for disconnected machines. I just upgraded to Labview 2009. The license files work for labview but are not working for signal express. I have the Labview full development system which included
-
Audio Book - file organization
Hi all. New to iPod and iTunes. I am importing an AudioBook that I purchased. Having a problem with the joined files not being in the correct order - two "albums" have formed with the joined tracks appearing in random order between the two albums. Ho
-
How to get logic onto two computers?
i got a new mac, and I have logic on my old one, we bought logic for more than one computer but how do i get the same one onto my other mac without paying for it?