Fetching of multiple files from Application Server into SAP Program

Question

Hi All,
I have a issue related <b>Fetching of multiple files from Application Server into SAP Program</b>.
Actual issue is as below.
In the <b>selection screen</b> of <b>my program</b> i will give <b>Application Server Path</b> as :
<b>/PW/DATA/SAP/D1S/PP/DOWN/eppi0720*</b>
Then the based on above input it should pick up all the files that are matching <b>eppi0720*</b> criteria.
Suppose if i am having <b>5</b> files with above scenario, i have to fetch all those <b>5</b> files at a time and place in my SAP Program.
All those 5 file's data should come into SAP at a time.
Can anybody tell me how can we solve above issue.
If any body has come across same issue please provide me with solution.
Thanks in advance.
Thanks & Regards,
Rayeez.

Answer 1

If you want to get around the authorization check, you can do something like this.
report zrich_0001 .
parameters: p_path type epsf-epsdirnam
                  default '/usr/sap/TST/SYS/global'.
parameters: p_file type epsf-epsfilnam default 'CO*'.
start-of-selection.
perform get_file_list.
*       FORM get_file_list                                            *
form get_file_list.
  types: name_of_dir(1024)        type c,
         name_of_file(260)        type c,
         name_of_path(1285)       type c.
  data: begin of file_list occurs 100,
          dirname     type name_of_dir,  " name of directory. (possibly
                                         " truncated.)
          name        type name_of_file, " name of entry. (possibly
                                         " truncated.)
          type(10)    type c,            " type of entry.
          len(8)      type p,            " length in bytes.
          owner(8)    type c,            " owner of the entry.
        mtime(6)    type p, " last modification date, seconds since 1970
          mode(9)     type c, " like "rwx-r-x--x": protection mode.
          useable(1)  type c,
          subrc(4)    type c,
          errno(3)    type c,
          errmsg(40)  type c,
          mod_date    type d,
          mod_time(8) type c,            " hh:mm:ss
          seen(1)     type c,
          changed(1)  type c,
        end of file_list.
  data: begin of file,
          dirname     type name_of_dir,  " name of directory. (possibly
                                         " truncated.)
          name        type name_of_file, " name of entry. (possibly
                                         " truncated.)
          type(10)    type c,            " type of entry.
          len(8)      type p,            " length in bytes.
          owner(8)    type c,            " owner of the entry.
        mtime(6)    type p, " last modification date, seconds since 1970
          mode(9)     type c, " like "rwx-r-x--x": protection mode.
          useable(1)  type c,
          subrc(4)    type c,
          errno(3)    type c,
          errmsg(40)  type c,
          mod_date    type d,
          mod_time(8) type c,            " hh:mm:ss
          seen(1)     type c,
          changed(1)  type c,
        end of file.
  call 'C_DIR_READ_FINISH'             " just to be sure
       id 'ERRNO'  field file_list-errno
       id 'ERRMSG' field file_list-errmsg.
  call 'C_DIR_READ_START' id 'DIR'    field p_path
                          id 'FILE'   field p_file
                          id 'ERRNO'  field file-errno
                          id 'ERRMSG' field file-errmsg.
  if sy-subrc <> 0.
    sy-subrc = 4.
    exit.
  endif.
* Read the file list and add to internal table.
  do.
    clear file.
    call 'C_DIR_READ_NEXT'
      id 'TYPE'   field file-type
      id 'NAME'   field file-name
      id 'LEN'    field file-len
      id 'OWNER'  field file-owner
      id 'MTIME'  field file-mtime
      id 'MODE'   field file-mode
      id 'ERRNO'  field file-errno
      id 'ERRMSG' field file-errmsg.
    if sy-subrc =  1.
      exit.
    endif.
    append file to file_list.
  enddo.
* Write out the file list
  loop at file_list.
    write:/ file_list-name.
  endloop.
endform.
Regards,
Rich Heilman