Folder for multiple details in ALV GRID DISPLAY

Question

Hi All,
I am developing one ALV GRID DISPLAY report. Here I am displaying the material and production order details in the report. If we have the multiple production order details for one material , then in that case , we have to place one folder at the first material level, in that folder I need to show all the multiple production order details.
I am using FUNCTION MODULE to develope the report, not using any Objects to develope this. 
Thanks in advance.
Ramesh.

Answer 1

Here is a simple example of such an ALV.
report zrich_0001.
type-pools: slis.
data: begin of head occurs 0,
       matnr type afpo-matnr,
       maktx type makt-maktx,
       EXPAND type c,
      end of head.
data: begin of detail occurs 0,
       aufnr type afpo-aufnr,
       matnr type afpo-matnr,
       werks type aufk-werks,
       pwerk type afpo-pwerk,
       psmng type afpo-psmng,
      end of detail.
start-of-selection.
  select * into corresponding fields of table detail
               from afpo
                  inner join aufk
                    on afpo~aufnr = aufk~aufnr
                  inner join afko
                    on afpo~aufnr = afko~aufnr
                              up to 500 rows
                                    where aufk~auart = 'PP01'.
  if not detail[] is initial.
    sort detail ascending by matnr.
    select distinct * into corresponding fields of table head
              from makt
                 for all entries in detail
                    where matnr = detail-matnr
                      and spras = sy-langu.
  endif.
  perform call_alv.
*       FORM call_alv                                                 *
form call_alv.
  data: gt_fieldcat type slis_t_fieldcat_alv,
        gs_keyinfo  type slis_keyinfo_alv,
        gs_layout   type slis_layout_alv.
  data: ls_fieldcat type slis_fieldcat_alv.
  clear gs_keyinfo.
  gs_keyinfo-header01 = 'MATNR'.
  gs_keyinfo-item01   = 'MATNR'.
  clear ls_fieldcat.
  ls_fieldcat-fieldname    = 'MATNR'.
  ls_fieldcat-reptext_ddic = 'Material'.
  ls_fieldcat-tabname      = 'HEAD'.
  ls_fieldcat-outputlen    = 18.
  append ls_fieldcat to gt_fieldcat.
  clear ls_fieldcat.
  ls_fieldcat-fieldname    = 'MAKTX'.
  ls_fieldcat-reptext_ddic = 'Description'.
  ls_fieldcat-tabname      = 'HEAD'.
  ls_fieldcat-outputlen    = 40.
  append ls_fieldcat to gt_fieldcat.
  clear ls_fieldcat.
  ls_fieldcat-fieldname    = 'AUFNR'.
  ls_fieldcat-reptext_ddic = 'Production Order'.
  ls_fieldcat-tabname      = 'DETAIL'.
  ls_fieldcat-outputlen    = 12.
  append ls_fieldcat to gt_fieldcat.
  clear ls_fieldcat.
  ls_fieldcat-fieldname    = 'WERKS'.
  ls_fieldcat-reptext_ddic = 'Production Plant'.
  ls_fieldcat-tabname      = 'DETAIL'.
  ls_fieldcat-outputlen    = 4.
  append ls_fieldcat to gt_fieldcat.
  clear ls_fieldcat.
  ls_fieldcat-fieldname    = 'PWERK'.
  ls_fieldcat-reptext_ddic = 'Planning Plant'.
  ls_fieldcat-tabname      = 'DETAIL'.
  ls_fieldcat-outputlen    = 4.
  append ls_fieldcat to gt_fieldcat.
  clear ls_fieldcat.
  ls_fieldcat-fieldname    = 'PSMNG'.
  ls_fieldcat-reptext_ddic = 'Quantity'.
  ls_fieldcat-tabname      = 'DETAIL'.
  ls_fieldcat-outputlen    = 20.
  append ls_fieldcat to gt_fieldcat.
  gs_layout-expand_fieldname = 'EXPAND'.
  call function 'REUSE_ALV_HIERSEQ_LIST_DISPLAY'
       exporting
            it_fieldcat      = gt_fieldcat[]
            is_layout        = gs_layout
            i_tabname_header = 'HEAD'
            i_tabname_item   = 'DETAIL'
            is_keyinfo       = gs_keyinfo
       tables
            t_outtab_header  = head
            t_outtab_item    = detail.
endform.
Regard,s
RIch Heilman