Getting a script to run in automator

Question

Thanks to Hiroto I have a script that does what I was looking for. The discussion on it is at http://discussions.apple.com/thread.jspa?threadID=1566429
I am now trying to put this script into an automator workflow. By itself the script works fine. The automater workflow works by itself. Put the script into automator using the run applescript action and it gets skipped.
This is what the script looks like inside the automator action. What I do not understand is why virtually the entire script is grayed out. The 1st line and the last two lines are the only ones that show as colored type when compiled in automator, like the rest is being commented out for some reason. When I compile it in the automator window it doesn't give an error.
on run {input, parameters}
(* on run
--main((choose folder with multiple selections allowed) as list)
main((choose folder) as list)
end run
on open aa
main(aa)
end open
on main(aa)
(* list aa : list of folder aliases *)
script o
property ff : {}
-- confirmation for safety
set AppleScript's text item delimiters to {ASCII character 0}
set aa to (aa as Unicode text)'s text items
set AppleScript's text item delimiters to {""}
set aa to (choose from list aa default items aa ¬
with prompt ("You're renaming pdf files in following folder.") ¬
with multiple selections allowed)
if aa = false then error number -128
-- process each folder
set k to 0
repeat with a in aa
set a to a as alias
-- get pdf file aliases' list (= ff)
set ff to {}
tell application "Finder"
tell item a
if its class is in {disk, folder} then
try
set ff to (files of entire contents whose name ends with ".pdf") as alias list
on error
set ff to (files of entire contents whose name ends with ".pdf") as alias as list
end try
end if
end tell
end tell
-- process each pdf file
repeat with f in my ff
set f to f's contents
tell application "Adobe Acrobat Pro"
--open f
open f with invisible -- open it invisibly (?)
tell document 1
set p to count pages
close
end tell
end tell
tell application "Finder"
set n to f's name
set f's name to (n's text 1 thru -5) & "_" & p & ".pdf"
end tell
set k to k + 1
end repeat
end repeat
-- decent notice -- remove -- on four lines below to get confirmation window when done
-- tell application (path to frontmost application as string)
-- display dialog ("Total of " & k & " pdf file(s) renamed successfully.") ¬
-- with icon 1 giving up after 5
-- end tell
end script
tell o to run
end main *)
return input
end run
Now the difference I need to figue out how to adjust for, once the script works in automator, is that the script operates based on the folder selected and performs the desired functions to the enclosed pdf files. The automator action I have acts on the selected files themselves. I will need to also get the script to recognize the selected files rather than the selected folder and contents of this folder.
Any help would be greatly appreciated,
John

Answer 1

Hello
You may try something like the code below.
It assumes the input from the previous action is a list of pdf files.
Hope this may help,
Hiroto
--SCRIPT (for Automator Action)
on run {input, parameters}
list input : list of alias of pdf files
record parameters : dummy
main(input)
return input
end run
on main(aa)
list aa : list of alias of pdf files
script o
property ff : aa
-- process each pdf file
repeat with f in my ff
set f to f's contents
tell application "Adobe Acrobat Pro"
--open f
open f with invisible -- open it invisibly (?)
tell document 1
set p to count pages
close
end tell
end tell
tell application "Finder"
set n to f's name
set f's name to (n's text 1 thru -5) & "_" & p & ".pdf"
end tell
end repeat
end script
tell o to run
end main
--END OF SCRIPT