Handling Events in ALV Grid Display

Question

Hi,
     I need ur urgent help on how to trigger and handle the events associated with the class CL_GUI_ALV_GRID_DISPLAY .Events like
•     ONF4
•     ONF1
•     DATA_CHANGED
•     USER_COMMAND
•     TOOLBAR
•     HOTSPOT_CLICK
Please help me in this matter and post some valid codes depicting these events.Ur help will be really appreciated throught points.
Thnkx in advance.

Answer 1

Hi,
Please refer program "BCALV_TEST_GRID_EVENTS"
Best regards,
Prashant
*& Report  BCALV_TEST_GRID_EVENTS                                      *
report  bcalv_test_grid_events.
types: g_ty_t_carrid  type standard table of alv_tab,
       g_ty_t_connid  type standard table of alv_chck,
       g_ty_t_curr    type standard table of alv_cur,
       g_ty_s_sflight type alv_t_t2,
       g_ty_s_carrid  type alv_tab,
       g_ty_s_connid  type alv_chck,
       g_ty_s_curr    type alv_cur.
constants: con_sflight type lvc_fname value 'ALV_T_T2',
           con_scarr   type lvc_fname value 'ALV_TAB',
           con_spfli   type lvc_fname value 'ALV_CHCK'.
* DATA                                                                 *
class lcl_events_d0100 definition deferred.
types: begin of g_ty_s_plane,
         carrid    type g_ty_s_sflight-carrid,
         connid    type g_ty_s_sflight-connid,
         planetype type g_ty_s_sflight-planetype,
         seatsmax  type g_ty_s_sflight-seatsmax,
       end   of g_ty_s_plane,
       g_ty_t_plane type sorted table of g_ty_s_plane
                         with unique key carrid connid,
       begin of g_ty_s_event,
         user_command                 type char1,
         before_user_command          type char1,
         after_user_command           type char1,
         double_click                 type char1,
         hotspot_click                type char1,
         button_click                 type char1,
         onf1                         type char1,
         onf4                         type char1,
         menu_button                  type char1,
         toolbar                      type char1,
         context_menu_request         type char1,
         ondrag                       type char1,
         ondrop                       type char1,
         ondropcomplete               type char1,
         ondropgetflavor              type char1,
         subtotal_text                type char1,
         data_changed                 type char1,
         data_changed_finished        type char1,
         after_refresh                type char1,
         delayed_callback             type char1,
         delayed_changed_sel_callback type char1,
         top_of_page                  type char1,
         end_of_list                  type char1,
         print_top_of_page            type char1,
         print_end_of_page            type char1,
         print_top_of_list            type char1,
         print_end_of_list            type char1,
       end   of g_ty_s_event,
       begin of g_ty_s_onf4,
         register        type char1,
         get_before      type char1,
         change_after    type char1,
         internal_format type char1,
       end   of g_ty_s_onf4,
       begin of g_ty_s_test,
         select_amount      type i,
         no_info_popup      type char1,
         info_popup_once    type char1,
         events_info_popup  type lvc_fname occurs 0,
         application_events type char1,
         event              type g_ty_s_event,
         onf4               type g_ty_s_onf4,
         button_fields      type lvc_fname occurs 0,
         hotspot_fields     type lvc_fname occurs 0,
         onf1_fields        type lvc_fname occurs 0,
         onf4_fields        type lvc_fname occurs 0,
         bypassing_buffer   type char1,
         buffer_active      type char1,
       end   of g_ty_s_test,
       begin of g_ty_s_outtab.
include type g_ty_s_sflight.
types:   box                  type char1,
         lights               type char1,
       end   of g_ty_s_outtab,
       g_ty_t_outtab type table of g_ty_s_outtab.
constants: con_exit type sy-ucomm value 'EXIT',
           con_canc type sy-ucomm value 'CANC',
           con_back type sy-ucomm value 'BACK',
           con_true     type char1 value 'X'.
data: g_okcode type sy-ucomm.
data: gs_test type g_ty_s_test.
data: gt_outtab type g_ty_t_outtab with header line,
      gr_container_d0100   type ref to cl_gui_custom_container,
      gr_grid_d0100        type ref to cl_gui_alv_grid,
      gr_events_d0100      type ref to lcl_events_d0100,
      gr_grid_dragdrop     type ref to cl_dragdrop.
data: g_static_menu            type ref to cl_ctmenu,
      g_static_menu_default    type ref to cl_ctmenu.
data: g_field type lvc_s_fcat-fieldname.
*       CLASS lcl_dragdrop_obj_d0100 DEFINITION
class lcl_dragdrop_obj_d0100 definition.
  public section.
    data: line  type g_ty_s_outtab,
          index type i.
endclass.                    "lcl_dragdrop_obj_d0100 DEFINITION
*       CLASS lcl_events_d0100 DEFINITION
class lcl_events_d0100 definition.
  public section.
    methods:
    user_command         for event user_command
                         of cl_gui_alv_grid
                         importing e_ucomm sender,
    before_user_command  for event before_user_command
                         of cl_gui_alv_grid
                         importing e_ucomm,
    after_user_command   for event after_user_command
                         of cl_gui_alv_grid
                         importing e_ucomm
                                   e_not_processed
                                   e_saved,
    double_click         for event double_click
                         of cl_gui_alv_grid
                         importing e_row
                                   e_column
                                   es_row_no,
    hotspot_click        for event hotspot_click
                         of cl_gui_alv_grid
                         importing e_row_id
                                   e_column_id
                                   es_row_no,
    menu_button          for event menu_button
                         of cl_gui_alv_grid
                         importing e_object
                                   e_ucomm,
    toolbar              for event toolbar
                         of cl_gui_alv_grid
                         importing e_object
                                   e_interactive,
    context_menu_request for event context_menu_request
                         of cl_gui_alv_grid
                         importing e_object,
    top_of_page          for event top_of_page
                         of cl_gui_alv_grid
                         importing e_dyndoc_id,
    end_of_list          for event end_of_list
                         of cl_gui_alv_grid
                         importing e_dyndoc_id,
    print_top_of_page    for event print_top_of_page
                         of cl_gui_alv_grid,
    print_end_of_page    for event print_end_of_page
                         of cl_gui_alv_grid,
    print_top_of_list    for event print_top_of_list
                         of cl_gui_alv_grid,
    print_end_of_list    for event print_end_of_list
                         of cl_gui_alv_grid,
    after_refresh        for event after_refresh
                         of cl_gui_alv_grid,
    delayed_callback     for event delayed_callback
                         of cl_gui_alv_grid,
    delayed_changed_sel_callback
                         for event delayed_changed_sel_callback
                         of cl_gui_alv_grid,
    subtotal_text        for event subtotal_text
                         of cl_gui_alv_grid
                         importing es_subtottxt_info
                                   ep_subtot_line
                                   e_event_data,
    ondrag               for event ondrag
                         of cl_gui_alv_grid
                         importing e_row
                                   e_column
                                   es_row_no
                                   e_dragdropobj,
    ondrop               for event ondrop
                         of cl_gui_alv_grid
                         importing e_row
                                   e_column
                                   es_row_no
                                   e_dragdropobj,
    ondropcomplete       for event ondropcomplete
                         of cl_gui_alv_grid
                         importing e_row
                                   e_column
                                   es_row_no
                                   e_dragdropobj,
    ondropgetflavor      for event ondropgetflavor
                         of cl_gui_alv_grid
                         importing e_row
                                   e_column
                                   es_row_no
                                   e_dragdropobj
                                   e_flavors,
    data_changed         for event data_changed
                         of cl_gui_alv_grid
                         importing er_data_changed
                                   e_onf4
                                   e_onf4_before
                                   e_onf4_after,
    data_changed_finished
                         for event data_changed_finished
                         of cl_gui_alv_grid,
    button_click         for event button_click
                         of cl_gui_alv_grid
                         importing es_col_id
                                   es_row_no,
    onf1                 for event onf1
                         of cl_gui_alv_grid
                         importing e_fieldname
                                   es_row_no
                                   er_event_data,
    onf4                 for event onf4
                         of cl_gui_alv_grid
                         importing e_fieldname
                                   e_fieldvalue
                                   es_row_no
                                   er_event_data
                                   et_bad_cells
                                   e_display.
endclass.                    "lcl_events_d0100 DEFINITION
*       CLASS lcl_events_d0100 IMPLEMENTATION
class lcl_events_d0100 implementation.
*       METHOD user_command                                           *
  method user_command.
    perform d0100_event_ucomm using e_ucomm.
  endmethod.                    "user_command
*       METHOD before_user_command                                    *
  method before_user_command.
    perform d0100_event_before_ucomm using e_ucomm.
  endmethod.                    "before_user_command
*       METHOD after_user_command                                     *
  method after_user_command.
    perform d0100_event_after_ucomm using e_ucomm
                                          e_not_processed
                                          e_saved.
  endmethod.                    "after_user_command
*       METHOD double_click                                           *
  method double_click.
    perform d0100_event_double_click using e_row
                                           e_column.
  endmethod.                    "double_click
*       METHOD hotspot_click                                          *
  method hotspot_click.
*    perform d0100_event_hotspot_click using e_row_id
*                                            e_column_id.
    gr_grid_d0100->refresh_table_display( ).
  endmethod.                    "hotspot_click
*       METHOD menu_button                                            *
  method menu_button.
    perform d0100_event_menu_button using e_object
                                          e_ucomm.
  endmethod.                    "menu_button
*       METHOD toolbar                                                *
  method toolbar.
    perform d0100_event_toolbar using e_object
                                      e_interactive.
  endmethod.                    "toolbar
*       METHOD context_menu_request                                   *
  method context_menu_request.
    perform d0100_event_context_menu_reqst using e_object.
  endmethod.                    "context_menu_request
*       METHOD top_of_page                                            *
  method top_of_page.
    perform d0100_event_top_of_page using e_dyndoc_id.
  endmethod.                    "top_of_page
*       METHOD end_of_list                                            *
  method end_of_list.
    perform d0100_event_end_of_list using e_dyndoc_id.
  endmethod.                    "end_of_list
*       METHOD print_top_of_page                                      *
  method print_top_of_page.
    perform d0100_event_print_top_of_page.
  endmethod.                    "print_top_of_page
*       METHOD print_end_of_page                                      *
  method print_end_of_page.
    perform d0100_event_print_end_of_page.
  endmethod.                    "print_end_of_page
*       METHOD print_top_of_list                                      *
  method print_top_of_list.
    perform d0100_event_print_top_of_list.
  endmethod.                    "print_top_of_list
*       METHOD print_end_of_list                                      *
  method print_end_of_list.
    perform d0100_event_print_end_of_list.
  endmethod.                    "print_end_of_list
*       METHOD after_refresh                                          *
  method after_refresh.
    perform d0100_event_after_refresh.
  endmethod.                    "after_refresh
*       METHOD delayed_callback                                       *
  method delayed_callback.
    perform d0100_event_delayed_callback.
  endmethod.                    "delayed_callback
*       METHOD delayed_changed_sel_callback                           *
  method delayed_changed_sel_callback.
    perform d0100_event_changed_sel_callba.
  endmethod.                    "delayed_changed_sel_callback
*       METHOD subtotal_text                                          *
  method subtotal_text.
    perform d0100_event_subtotal_text using es_subtottxt_info
                                            ep_subtot_line
                                            e_event_data.
  endmethod.                    "subtotal_text
*       METHOD ondrag                                                 *
  method ondrag.
    perform d0100_event_ondrag using e_row
                                     e_column
                                     e_dragdropobj.
  endmethod.                    "ondrag
*       METHOD ondrop                                                 *
  method ondrop.
    perform d0100_event_ondrop using e_row
                                     e_column
                                     e_dragdropobj.
  endmethod.                    "ondrop
*       METHOD ondropcomplete                                         *
  method ondropcomplete.
    perform d0100_event_ondropcomplete using e_row
                                             e_column
                                             e_dragdropobj.
  endmethod.                    "ondropcomplete
*       METHOD ondropgetflavor                                        *
  method ondropgetflavor.
    perform d0100_event_ondropgetflavor.
  endmethod.                    "ondropgetflavor
*       METHOD data_changed                                           *
  method data_changed.
    perform d0100_event_data_changed using er_data_changed
                                           e_onf4
                                           e_onf4_before
                                           e_onf4_after.
  endmethod.                    "data_changed
*       METHOD data_changed_finished                                  *
  method data_changed_finished.
    perform d0100_event_data_changed_finis.
  endmethod.                    "data_changed_finished
*       METHOD button_click                                           *
  method button_click.
    perform d0100_event_button_click using es_col_id
                                           es_row_no.
  endmethod.                    "button_click
*       METHOD onf1                                                   *
  method onf1.
    perform d0100_event_onf1 using e_fieldname
                                   es_row_no
                                   er_event_data.
  endmethod.                                                "onf1
*       METHOD onf4                                                   *
  method onf4.
    perform d0100_event_onf4 using e_fieldname
                                   e_fieldvalue
                                   es_row_no
                                   er_event_data
                                   et_bad_cells
                                   e_display.
  endmethod.                                                "onf4
endclass.                    "lcl_events_d0100 IMPLEMENTATION
* SELECTION-SCREEN                                                     *
selection-screen begin of block gen with frame.
  selection-screen begin of line.
  parameters:
    p_ext    radiobutton group db.
  selection-screen comment (29) for field p_ext.
  selection-screen comment (29) for field p_d_file.
  parameters:
    p_d_file   type char255.
  selection-screen end of line.
  selection-screen begin of line.
  parameters:
    p_db    radiobutton group db default 'X'.
  selection-screen comment (29) for field p_db.
  selection-screen comment (29) for field p_amount.
  parameters:
    p_amount type i default 30.
  selection-screen end of line.
selection-screen end of block gen.
selection-screen begin of block inf with frame.
parameters:
p_inf01 as checkbox default con_true,
p_inf02 as checkbox.
selection-screen end of block inf.
selection-screen begin of block app with frame.
parameters:
p_appevt as checkbox.
selection-screen end of block app.
selection-screen begin of block evt with frame.
parameters:
p_evt01 as checkbox, "USER_COMMAND
p_evt02 as checkbox, "BEFORE_USER_COMMAND
p_evt03 as checkbox. "AFTER_USER_COMMAND
selection-screen skip.
parameters:
p_evt04 as checkbox, "DOUBLE_CLICK
p_evt05 as checkbox. "HOTSPOT_CLICK
select-options:
p_hotspt for g_field no intervals default 'CARRID'.
parameters:
p_evt06 as checkbox. "BUTTON_CLICK
select-options:
p_button for g_field no intervals default 'CARRID'.
selection-screen skip.
parameters:
p_evt07 as checkbox.                                        "ONF1
selection-screen begin of block of4 with frame.
parameters:
p_evt08 as checkbox.                                        "ONF4
select-options:
p_onf4 for g_field no intervals default 'CARRID'.
selection-screen begin of line.
selection-screen comment 5(30) text-c01 for field p_f401.
parameters:
p_f401 as checkbox default con_true. "REGISTER
selection-screen end of line.
selection-screen begin of line.
selection-screen comment 5(30) text-c02 for field p_f402.
parameters:
p_f402 as checkbox. "GET_BEFORE
selection-screen end of line.
selection-screen begin of line.
selection-screen comment 5(30) text-c03 for field p_f403.
parameters:
p_f403 as checkbox. "CHANGE_AFTER
selection-screen end of line.
selection-screen begin of line.
selection-screen comment 5(30) text-c04 for field p_f404.
parameters:
p_f404 as checkbox. "INTERNAL_FORMAT
selection-screen end of line.
selection-screen end of block of4.
selection-screen skip.
parameters:
p_evt09 as checkbox, "MENU_BUTTON
p_evt10 as checkbox, "TOOLBAR
p_evt11 as checkbox. "CONTEXT_MENU_REQUEST
selection-screen skip.
parameters:
p_evt12 as checkbox, "ONDRAG
p_evt13 as checkbox, "ONDROP
p_evt14 as checkbox, "ONDROPCOMPLETE
p_evt15 as checkbox. "ONDROPGETFLAVOR
selection-screen skip.
parameters:
p_evt16 as checkbox. "SUBTOTAL_TEXT
selection-screen skip.
parameters:
p_evt17 as checkbox, "DATA_CHANGED
p_evt18 as checkbox, "DATA_CHANGED_FINISHED
p_evt19 as checkbox. "AFTER_REFRESH
selection-screen skip.
parameters:
p_evt20 as checkbox, "DELAYED_CALLBACK
p_evt21 as checkbox. "DELAYED_CHANGED_SEL_CALLBACK
selection-screen skip.
parameters:
p_evt22 as checkbox, "TOP_OF_PAGE
p_evt23 as checkbox, "END_OF_LIST
p_evt24 as checkbox, "PRINT_TOP_OF_PAGE
p_evt25 as checkbox, "PRINT_END_OF_PAGE
p_evt26 as checkbox, "PRINT_TOP_OF_LIST
p_evt27 as checkbox. "PRINT_END_OF_LIST
selection-screen end of block evt.
* AT SELECTION-SCREEN ON VALUE-REQUEST                                 *
at selection-screen on value-request for p_hotspt-low.
  perform d0100_f4_fcode changing p_hotspt-low.
at selection-screen on value-request for p_button-low.
  perform d0100_f4_fcode changing p_button-low.
at selection-screen on value-request for p_onf4-low.
  perform d0100_f4_fcode changing p_onf4-low.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_d_file.
  PERFORM f4_file.
* START-OF-SELECTION                                                   *
start-of-selection.
  gs_test-select_amount = p_amount.
  gs_test-no_info_popup   = p_inf01.
  gs_test-info_popup_once = p_inf02.
  gs_test-application_events = p_appevt.
  gs_test-event-user_command                 = p_evt01.
  gs_test-event-before_user_command          = p_evt02.
  gs_test-event-after_user_command           = p_evt03.
  gs_test-event-double_click                 = p_evt04.
  gs_test-event-hotspot_click                = p_evt05.
  gs_test-event-button_click                 = p_evt06.
  gs_test-event-onf1                         = p_evt07.
  gs_test-event-onf4                         = p_evt08.
  gs_test-event-menu_button                  = p_evt09.
  gs_test-event-toolbar                      = p_evt10.
  gs_test-event-context_menu_request         = p_evt11.
  gs_test-event-ondrag                       = p_evt12.
  gs_test-event-ondrop                       = p_evt13.
  gs_test-event-ondropcomplete               = p_evt14.
  gs_test-event-ondropgetflavor              = p_evt15.
  gs_test-event-subtotal_text                = p_evt16.
  gs_test-event-data_changed                 = p_evt17.
  gs_test-event-data_changed_finished        = p_evt18.
  gs_test-event-after_refresh                = p_evt19.
  gs_test-event-delayed_callback             = p_evt20.
  gs_test-event-delayed_changed_sel_callback = p_evt21.
  gs_test-event-top_of_page                  = p_evt22.
  gs_test-event-end_of_list                  = p_evt23.
  gs_test-event-print_top_of_page            = p_evt24.
  gs_test-event-print_end_of_page            = p_evt25.
  gs_test-event-print_top_of_list            = p_evt26.
  gs_test-event-print_end_of_list            = p_evt27.
  gs_test-onf4-register        = p_f401.
  gs_test-onf4-get_before      = p_f402.
  gs_test-onf4-change_after    = p_f403.
  gs_test-onf4-internal_format = p_f404.
  if p_evt05 ne space.
    loop at p_hotspt.
      if not p_hotspt-low is initial.
        append p_hotspt-low to gs_test-hotspot_fields.
      endif.
    endloop.
  endif.
  if p_evt06 ne space.
    loop at p_button.
      if not p_button-low is initial.
        append p_button-low to gs_test-button_fields.
      endif.
    endloop.
  endif.
  if p_evt08 ne space.
    loop at p_onf4.
      if not p_onf4-low is initial.
        append p_onf4-low to gs_test-onf4_fields.
      endif.
    endloop.
  endif.
  gs_test-bypassing_buffer = space.
  gs_test-buffer_active    = space.
* END-OF-SELECTION                                                     *
end-of-selection.
  call screen 100.
*&      Module  d0100_set_status  OUTPUT
*       text
module d0100_set_status output.
  perform d0100_set_status.
endmodule.                 " d0100_set_status  OUTPUT
*&      Module  d0100_prepare_container  OUTPUT
*       text
module d0100_prepare_container output.
  perform d0100_prepare_container.
endmodule.                 " d0100_prepare_container  OUTPUT
*&      Module  d0100_exit  INPUT
*       text
module d0100_exit input.
  perform d0100_exit.
endmodule.                 " d0100_exit  INPUT
*&      Module  d0100_fcode  INPUT
*       text
module d0100_fcode input.
  perform d0100_fcode.
endmodule.                 " d0100_fcode  INPUT
*&      Form  d0100_set_status
*       text
form d0100_set_status .
  types: begin of l_ty_s_excl,
           func type syucomm,
         end   of l_ty_s_excl,
         l_ty_t_excl type standard table of l_ty_s_excl.
  data: lt_excl type l_ty_t_excl.
  set pf-status 'D0100' excluding lt_excl.
  set titlebar 'D0100'.
endform.                    " d0100_set_status
*&      Form  d0100_prepare_container
*       text
form d0100_prepare_container .
  data: lt_fcat             type lvc_t_fcat,
        ls_layo             type lvc_s_layo,
        ls_vari             type disvariant,
        ls_prnt             type lvc_s_prnt,
        l_consistency_check type char1.
  if gr_container_d0100 is initial.
    if cl_gui_alv_grid=>offline( ) is initial.
      create object gr_container_d0100
                    exporting container_name = 'D0100_CONTAINER'.
    endif.
    create object gr_grid_d0100
                  exporting i_parent      = gr_container_d0100
                            i_appl_events = gs_test-application_events.
    DATA: l_filename TYPE string,
          l_struct   TYPE string.
    CASE con_true.
      WHEN p_db.
        perform d0100_get_outtab.
      WHEN p_ext.
        l_struct = 'g_ty_t_outtab'.
        l_filename = p_d_file.
        CALL METHOD cl_salv_test_data=>select_data
          EXPORTING
            structname = l_struct
            SOURCE     = 2
             filename   = l_filename
*            AMOUNT     = 30
          CHANGING
            data       = gt_outtab[].
    ENDCASE.
    perform d0100_set_grid_vari     changing ls_vari.
    perform d0100_set_grid_layo     changing ls_layo.
    perform d0100_set_grid_fcat     changing lt_fcat.
    perform d0100_set_grid_onf4     changing lt_fcat.
    perform d0100_set_grid_buttons  changing lt_fcat.
    perform d0100_set_grid_hotspot  changing lt_fcat.
    perform d0100_set_grid_dragdrop changing ls_layo.
    perform d0100_set_grid_edit     changing ls_layo.
    perform d0100_set_grid_events.
    ls_prnt-grpchgedit = con_true.
    call method gr_grid_d0100->set_table_for_first_display
      exporting
        i_buffer_active     = gs_test-buffer_active
        i_bypassing_buffer  = gs_test-bypassing_buffer
        i_consistency_check = l_consistency_check
        is_variant          = ls_vari
        i_save              = 'A'
        i_default           = con_true
        is_layout           = ls_layo
        is_print            = ls_prnt
      changing
        it_outtab           = gt_outtab[]
        it_fieldcatalog     = lt_fcat.
  endif.
endform.                    " d0100_prepare_container
*&      Form  d0100_exit
*       text
form d0100_exit .
  data: l_okcode like sy-ucomm.
  l_okcode = g_okcode.
  clear g_okcode.
  case l_okcode.
    when con_exit or con_back or con_canc.
      call method gr_grid_d0100->free.
      call method gr_container_d0100->free.
      call method cl_gui_cfw=>flush.
      clear gr_container_d0100.
      clear gr_grid_d0100.
      clear gr_events_d0100.
      set screen 0.
      leave screen.
  endcase.
endform.                    " d0100_exit
*&      Form  d0100_fcode
*       text
form d0100_fcode .
  data: l_okcode like sy-ucomm.
  l_okcode = g_okcode.
  clear g_okcode.
  call method cl_gui_cfw=>dispatch.
  case l_okcode.
    when con_exit or con_back or con_canc.
      g_okcode = l_okcode.
      perform d0100_exit.
    when others.
  endcase.
endform.                    " d0100_fcode
*&      Form  d0100_set_grid_vari
*       text
form d0100_set_grid_vari changing cs_vari type disvariant.
  cs_vari-report      = sy-repid.
  cs_vari-handle      = space.
  cs_vari-log_group   = space.
  cs_vari-username    = space.
  cs_vari-variant     = space.
  cs_vari-text        = space.
  cs_vari-dependvars  = space.
endform.                    " d0100_set_grid_vari
*&      Form  d0100_set_grid_layo
*       text
form d0100_set_grid_layo  changing cs_layo type lvc_s_layo.
*... ALV-Control: Allgemeine Anzeigeoptionen
  cs_layo-stylefname  = space.
  cs_layo-cwidth_opt  = con_true.
  cs_layo-zebra       = space.
  cs_layo-smalltitle  = space.
  cs_layo-graphics    = space.
  cs_layo-frontend    = space.
  cs_layo-template    = space.
*... ALV-Control: Gridcustomizing
  cs_layo-no_colexpd  = space.
  cs_layo-no_hgridln  = space.
  cs_layo-no_vgridln  = space.
  cs_layo-no_rowmark  = space.
  cs_layo-no_headers  = space.
  cs_layo-no_merging  = space.
  cs_layo-grid_title  = space.
  cs_layo-no_toolbar  = space.
  cs_layo-sel_mode    = 'D'.
  cs_layo-box_fname   = space.
  cs_layo-sgl_clk_hd  = space.
*... ALV-Control: Summenoptionen
  cs_layo-totals_bef  = space.
  cs_layo-no_totline  = space.
  cs_layo-numc_total  = space.
  cs_layo-no_utsplit  = space.
*... ALV-Control: Exceptions
  cs_layo-excp_fname  = 'LIGHTS'.
  cs_layo-excp_rolln  = space.
  cs_layo-excp_conds  = space.
  cs_layo-excp_led    = space.
*... ALV-Control: Steuerung Interaktion
  cs_layo-detailinit  = space.
  cs_layo-detailtitl  = space.
  cs_layo-keyhot      = space.
  cs_layo-no_keyfix   = space.
  cs_layo-no_author   = space.
  clear cs_layo-s_dragdrop.
*... ALV-Control: Farben
  cs_layo-info_fname  = space.
  cs_layo-ctab_fname  = space.
*... ALV-Control: Eingabefähigkeit
  cs_layo-edit        = space.
  cs_layo-edit_mode   = space.
  cs_layo-no_rowins   = space.
  cs_layo-no_rowmove  = space.
*... ALV-Control: Web-Optionen
  cs_layo-weblook     = space.
  cs_layo-webstyle    = space.
  cs_layo-webrows     = space.
  cs_layo-webxwidth   = space.
  cs_layo-webxheight  = space.
endform.                    " d0100_set_grid_layo
*&      Form  d0100_set_grid_fcat
*       text
form d0100_set_grid_fcat changing ct_fcat type lvc_t_fcat.
  call function 'LVC_FIELDCATALOG_MERGE'
    exporting
      i_buffer_active        = gs_test-buffer_active
      i_structure_name       = con_sflight
      i_client_never_display = con_true
      i_bypassing_buffer     = gs_test-bypassing_buffer
    changing
      ct_fieldcat            = ct_fcat[]
    exceptions
      inconsistent_interface = 1
      program_error          = 2
      others                 = 3.
  if sy-subrc <> 0.
    message id sy-msgid type sy-msgty number sy-msgno
            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  endif.
endform.                    " d0100_set_grid_fcat
*&      Form  d0100_set_grid_onf4
*       text
form d0100_set_grid_onf4 changing ct_fcat type lvc_t_fcat.
  field-symbols: <ls_fcat> type lvc_s_fcat.
  data: l_field type lvc_fname,
        lt_f4   type lvc_t_f4,
        ls_f4   type lvc_s_f4.
  if gs_test-event-onf4 eq con_true.
    loop at gs_test-onf4_fields into l_field.
      read table ct_fcat assigning <ls_fcat>
                 with key fieldname = l_field.
      if sy-subrc eq 0.
        <ls_fcat>-f4availabl = con_true.
      endif.
      ls_f4-fieldname  = l_field.
      ls_f4-register   = gs_test-onf4-register.
      ls_f4-getbefore  = gs_test-onf4-get_before.
      ls_f4-chngeafter = gs_test-onf4-change_after.
      ls_f4-internal   = gs_test-onf4-internal_format.
      insert ls_f4 into table lt_f4.
    endloop.
  endif.
  check not lt_f4 is initial.
  call method gr_grid_d0100->register_f4_for_fields
    exporting
      it_f4 = lt_f4.
endform.                    " d0100_set_grid_onf4
*&      Form  d0100_set_grid_buttons
*       text
form d0100_set_grid_buttons changing ct_fcat type lvc_t_fcat.
  field-symbols: <ls_fcat> type lvc_s_fcat.
  data: l_field type lvc_fname.
  loop at gs_test-button_fields into l_field.
*... Spaltenebene
*    In Feldkatalog wird Feld STYLE für Spalte auf
*    cl_gui_alv_grid=>mc_style_button gesetzt
    read table ct_fcat assigning <ls_fcat>
               with key fieldname = l_field.
    if sy-subrc eq 0.
      <ls_fcat>-style = cl_gui_alv_grid=>mc_style_button.
    endif.
  endloop.
endform.                    " d0100_set_grid_buttons
*&      Form  d0100_set_grid_hotspot
*       text
form d0100_set_grid_hotspot changing ct_fcat type lvc_t_fcat.
  field-symbols: <ls_fcat> type lvc_s_fcat.
  data: l_field type lvc_fname.
  loop at gs_test-hotspot_fields into l_field.
*... Spaltenebene
*    In Feldkatalog wird Feld STYLE für Spalte auf
*    cl_gui_alv_grid=>mc_style_hotspot gesetzt
    read table ct_fcat assigning <ls_fcat>
               with key fieldname = l_field.
    if sy-subrc eq 0.
      <ls_fcat>-style = cl_gui_alv_grid=>mc_style_hotspot.
    endif.
  endloop.
endform.                    " d0100_set_grid_hotspot
*&      Form  d0100_set_grid_edit
*       text
form d0100_set_grid_edit changing cs_layo type lvc_s_layo.
  if gs_test-event-data_changed eq con_true or
     gs_test-event-data_changed_finished eq con_true or
     gs_test-event-after_refresh eq con_true.
    cs_layo-edit = con_true.
    call method gr_grid_d0100->register_edit_event
      exporting
        i_event_id = cl_gui_alv_grid=>mc_evt_enter.
  endif.
endform.                    " d0100_set_grid_edit
*&      Form  d0100_set_grid_dragdrop
*       text
form d0100_set_grid_dragdrop changing cs_layo type lvc_s_layo.
  data: l_effect       type i,
        l_handle_grid  type i,
        ls_dragdrop    type lvc_s_dd01.
*... setzen für Zeilen
  create object gr_grid_dragdrop.
  l_effect = cl_dragdrop=>move + cl_dragdrop=>copy.
  call method gr_grid_dragdrop->add
    exporting
      flavor     = 'Line'                                   "#EC NOTEXT
      dragsrc    = 'X'
      droptarget = 'X'
      effect     = l_effect.
  call method gr_grid_dragdrop->get_handle
    importing
      handle = l_handle_grid.
  ls_dragdrop-cntr_ddid = space.
  ls_dragdrop-grid_ddid = space.
  ls_dragdrop-col_ddid  = space.
  ls_dragdrop-row_ddid  = l_handle_grid.
  ls_dragdrop-fieldname = space.
  cs_layo-s_dragdrop = ls_dragdrop.
endform.                    " d0100_set_grid_dragdrop
*&      Form  d0100_set_grid_events
*       text
form d0100_set_grid_events .
  create object gr_events_d0100.
  if gs_test-event-user_command eq con_true.
    set handler gr_events_d0100->user_command
                for gr_grid_d0100.
  endif.
  if gs_test-event-before_user_command eq con_true.
    set handler gr_events_d0100->before_user_command
                for gr_grid_d0100.
  endif.
  if gs_test-event-after_user_command eq con_true.
    set handler gr_events_d0100->after_user_command
                for gr_grid_d0100.
  endif.
  if gs_test-event-double_click eq con_true.
    set handler gr_events_d0100->double_click
                for gr_grid_d0100.
  endif.
  if gs_test-event-hotspot_click eq con_true.
    set handler gr_events_d0100->hotspot_click
                for gr_grid_d0100.
  endif.
  if gs_test-event-button_click eq con_true.
    set handler gr_events_d0100->button_click
                for gr_grid_d0100.
  endif.
  if gs_test-event-onf1 eq con_true.
    set handler gr_events_d0100->onf1
                for gr_grid_d0100.
  endif.
  if gs_test-event-onf4 eq con_true.
    set handler gr_events_d0100->onf4
                for gr_grid_d0100.
  endif.
  if gs_test-event-menu_button eq con_true.
    set handler gr_events_d0100->menu_button
                for gr_grid_d0100.
  endif.
  if gs_test-event-toolbar eq con_true.
    set handler gr_events_d0100->toolbar
                for gr_grid_d0100.
  endif.
  if gs_test-event-context_menu_request eq con_true.
    set handler gr_events_d0100->context_menu_request
                for gr_grid_d0100.
  endif.
  if gs_test-event-ondrag eq con_true.
    set handler gr_events_d0100->ondrag
                for gr_grid_d0100.
  endif.
  if gs_test-event-ondrop eq con_true.
    set handler gr_events_d0100->ondrop
                for gr_grid_d0100.
  endif.
  if gs_test-event-ondropcomplete eq con_true.
    set handler gr_events_d0100->ondropcomplete
                for gr_grid_d0100.
  endif.
  if gs_test-event-ondropgetflavor eq con_true.
    set handler gr_events_d0100->ondropgetflavor
                for gr_grid_d0100.
  endif.
  if gs_test-event-subtotal_text eq con_true.
    set handler gr_events_d0100->subtotal_text
                for gr_grid_d0100.
  endif.
  if gs_test-event-data_changed eq con_true.
    set handler gr_events_d0100->data_changed
                for gr_grid_d0100.
  endif.
  if gs_test-event-data_changed_finished eq con_true.
    set handler gr_events_d0100->data_changed_finished
                for gr_grid_d0100.
  endif.
  if gs_test-event-after_refresh eq con_true.
    set handler gr_events_d0100->after_refresh
                for gr_grid_d0100.
  endif.
  if gs_test-event-delayed_callback eq con_true.
    set handler gr_events_d0100->delayed_callback
                for gr_grid_d0100.
    call method gr_grid_d0100->register_delayed_event
      exporting
        i_event_id = cl_gui_alv_grid=>mc_evt_delayed_move_curr_cell.
  endif.
  if gs_test-event-delayed_changed_sel_callback eq con_true.
    set handler gr_events_d0100->delayed_changed_sel_callback
                for gr_grid_d0100.
    call method gr_grid_d0100->register_delayed_event
      exporting
        i_event_id = cl_gui_alv_grid=>mc_evt_delayed_change_select.
  endif.
  if gs_test-event-top_of_page eq con_true.
    set handler gr_events_d0100->top_of_page
                for gr_grid_d0100.
  endif.
  if gs_test-event-end_of_list eq con_true.
    set handler gr_events_d0100->end_of_list
                for gr_grid_d0100.
  endif.
  if gs_test-event-print_top_of_page eq con_true.
    set handler gr_events_d0100->print_top_of_page
                for gr_grid_d0100.
  endif.
  if gs_test-event-print_end_of_page eq con_true.
    set handler gr_events_d0100->print_end_of_page
                for gr_grid_d0100.
  endif.
  if gs_test-event-print_top_of_list eq con_true.
    set handler gr_events_d0100->print_top_of_list
                for gr_grid_d0100.
  endif.
  if gs_test-event-print_end_of_list eq con_true.
    set handler gr_events_d0100->print_end_of_list
                for gr_grid_d0100.
  endif.
endform.                    " d0100_set_grid_events
*&      Form  d0100_get_outtab
*       text
form d0100_get_outtab .
  field-symbols: <ls_outtab> type g_ty_s_outtab.
  data: l_excp_mod      type i,
        l_excp_div      type i,
        l_excp_amnt     type i value 4,
        l_excp          type i,
        lt_carrid       type g_ty_t_carrid,
        ls_carrid       type g_ty_s_carrid,
        l_carrid_amount type i,
        l_carrid_select type i,
        l_carrid_index1 type i,
        lt_connid       type g_ty_t_connid,
        ls_connid       type g_ty_s_connid,
        l_connid_amount type i,                             "#EC NEEDED
        l_connid_select type i,
        l_connid_index1 type i,
        l_connid_index2 type i,
        lt_plane        type g_ty_t_plane,
        ls_plane        type g_ty_s_plane.
  if gs_test-select_amount gt 0.
    select * from (con_sflight) into corresponding fields
               of table gt_outtab up to gs_test-select_amount rows.
  endif.
  gs_test-select_amount = sy-dbcnt.
  perform d0100_get_carrid changing lt_carrid.
  perform d0100_get_connid changing lt_connid.
  perform d0100_get_plane  using lt_connid changing lt_plane.
  describe table lt_carrid lines l_carri