"Handling" Killed Sessions

Question

I'm curious as to if anybody has some insight to killed sessions. I have a procedure that looks like this:
procedure x
  lv_result number;
  lv_msg varchar2(4000);
  for x in cursor
  loop
    lv_result := NULL;
    lv_msg := NULL;
    begin
      execute immediate x.sql into lv_result;
    exception
      when others then
         lv_msg := dbms_utility.format_error_stack;
         lv_result = NULL;
    end;
    log_result;  --autonomous transaction that inserts to table and commits;
  end loop;
  print_summary;
end x;What struck me as odd was that even though I'd kill the session while it was in the middle of processing rec 10 out of 30, it would still log the remaining 20 records with a "ORA-00028: your session has been killed" message. But it didn't print the results. So modified it a bit...
procedure x
  SESSION_KILLED exception ;
  pragma exception_init(SESSION_KILLED, -28);
  lv_result number;
  lv_msg varchar2(4000);
  lv_session_killed boolean := FALSE;
  for x in cursor
  loop
    lv_result := NULL;
    lv_msg := NULL;
    begin
      execute immediate x.sql into lv_result;
    exception
      when session_killed then
         lv_session_killed := TRUE;
         lv_msg := dbms_utility.format_error_stack;
         lv_result = NULL;
      when others then
         lv_msg := dbms_utility.format_error_stack;
         lv_result = NULL;
    end;
    log_result; --autonomous transaction that inserts to table and commits;
    exit when lv_session_killed;
  end loop;
  print_summary;
end x;...which effectively stopped the loop at the first record in the cursor at which the session was killed, and still didn't print the summary. But it's obvious that processing still "continues" in the background even though the session was killed. Does killing the session just terminate communications between the client and the DB, letting the procedure to continue on it's own? Is there any way to get DBMS_OUTPUT calls to work before the procedure actually dies?

Answer 1

Database is 10.2.0.4.0
Here's a quickie example:
drop table tst_output;
create table tst_output (num number, msg varchar2(4000));
create or replace procedure p1
as
  -- Make killed session named exception
  SESSION_KILLED exception ;
  pragma exception_init(SESSION_KILLED, -28);
  -- Random query to generate string (a little slowly on my dev box).
  lv_sql varchar2(4000) := 'select case when cnt is not null then ''SUCCESS!'' end as dummy_data ' ||
                           'from (select count(*) cnt from all_objects ' ||
                           'where last_ddl_time > (select min(last_analyzed) from all_tables))';
  lv_return tst_output.msg%type;        --result of execute immedaite
  lv_session_killed boolean := FALSE;   --stop processing if session killed.
  procedure insert_rec (
    p_num in tst_output.num%type,
    p_msg in tst_output.msg%type)
  as
    pragma autonomous_transaction;
  begin
    insert into tst_output (num, msg)
    values (p_num, p_msg);
    commit;
  end insert_rec;
  procedure print_something
  as
  begin
    for x in (select msg from tst_output)
    loop
      dbms_output.put_line(x.msg);
    end loop;
  end print_something;
begin
  execute immediate 'truncate table tst_output';
  for x in 1 .. 30  -- or however many loops it takes that you can jump to another window
  loop
    begin
      execute immediate lv_sql into lv_return;
    exception
      when SESSION_KILLED then
        lv_session_killed := TRUE;
        lv_return := dbms_utility.format_error_stack;
        dbms_output.put_line('Kill Time: ' || to_char(sysdate, 'dd-mon-yyyy'));
      when OTHERS then
        lv_return := dbms_utility.format_error_stack;
    end;
    insert_rec(x, lv_return);
    --exit when lv_session_killed;
  end loop;
  print_something; 
  dbms_output.put_line('Finish Time: ' || to_char(sysdate, 'dd-mon-yyyy'));
end p1;Run this with a high enough loop count that you can jump to another window and kill that session...
ALTER SYSTEM KILL SESSION 'SID, SERIAL'If you log back in (disconnected from the session kill) and look a the tst_output table, you'll still see 1 record for every loop. If you uncomment the EXIT towards the end of the actual executable portion and do it again, the program will break from the loop when you kill the session.
So that means that the inner exception handler is catching the SESSION_KILLED_EXCEPTION, but
1) DBMS_OUTPUT in the exception is not displayed
2) It doesn't return to the normal flow after it is handled because the print at the bottom isn't displaying either.
The session running the procedure is killed (and disconnected), but doesn't get the DBMS_OUTPUT before it's disconnected...and the procedure continues processing till it's done?