Hi i need help with applescript to stop downloads when vpn fails

Question

I am an apple script novice, I would like to be able to have a script run all the time to detect vpn failures and close transmission when this happens:
so far:
on idle
          do shell script "ifconfig -lu"
          if "ifconfig -lu" contains "tun0" then
          else if "ifconfig -lu" does not contain "tun0" then
                    tell application "System Events"
                              tell application "Transmission"
                                        quit
                              end tell
                    end tell
          end if
end idle
it closes transmission and nothing else.  tun0 is my vpn interface and seemed the most fireproof way of understanding the state of the vpn connect.  When VPN is down tun0 doesnt exist.  Please help.
many thanks

Answer 1

There are several things wrong with your script.
First, the glaring one:
          if "ifconfig -lu" contains "tun0" then
This will never, ever, ever be true. What you're asking AppleScript is whether the string "ifconfig -lu" contains the string "tun0". Never going to happen. Not even close.
What you really mean is whether the output of the shell command 'ifconfig -lu' contains 'tun0'. The easiest way to do that is to capture the output of the do shell script command in a variable and then test the variable, not the literal string:
set activeInterfaces to do shell script "ifconfig -lu"
if activeInterfaces does not contain "tun0" then
  -- stuff goes here
end if
Now AppleScript runs the shell script and puts the result in activeInterfaces which you then test to see if it contains (or, in this case, does not contain) the string you're looking for.
Note that I've also reworked your if statement.. there's no need to have an empty 'if' clause followed by an else if that checks the opposite... by definition if the first one fails the second one will be true.
Also note that there's no need to tell System Events to tell another application to quit - you can just do that directly.
Next up is that you don't exit your own script after you quit Transmission. So now you have the scenario where the VPN drops, your script detects it and tells transmission to quit. However, your script keeps running so it then rechecks whether the tunnel is up... since it presumably isn't, it then relaunches Transmission in order to tell it to quit again. Then it rechecks whether the tunnel is up, if it isn't, it relaunches Transmission to tell it to quit... then it rechecks... you get the idea.
Ideally you should tell your own script to quit after Transmission has exited so that you're not stuck in this loop.
Lastly you don't include a return value in your idle handler. This means that your idle handler will run every 30 seconds. That might be good enough, or you might want to check more or less frequently. Just return a value indicating the number of seconds to pause between iterations -  realise that the more frequently you check, of course, the more load you put on your system
Adding that all up you'll end up with something like:
on idle
          set activeInterfaces to do shell script "ifconfig -lu"
          if activeInterfaces does not contain "tun0" then
                    tell application "Transmission" to quit
                    tell me to quit
          end if
          return 30 -- 30 is default value, but it doesn't hurt to include it here
end idle