How can i test if i'm in the EOF of my file text in applescript?

Question

hello
i want to known how can i test my EOF of my file text or if i meet "Plan N°" when i read each linesdxhezdcxezkchcochzhejc
my file text :
Plan N°1
94.64%
MDF_280;;3050;1850;1
piece;0;0;500;500;0;AAA
piece;0;504;500;500;0;AAA
piece;0;1008;500;500;0;AAA
piece;0;1512;500;500;0;AAA
piece;0;2016;500;500;0;AAA
piece;0;2520;500;500;0;AAA
chute;0;3024;26;500
piece;504;0;500;500;0;AAA
piece;504;504;500;500;0;AAA
piece;504;1008;500;500;0;AAA
piece;504;1512;500;500;0;AAA
piece;504;2016;500;500;0;AAA
piece;504;2520;500;500;0;AAA
chute;504;3024;26;500
piece;1008;0;500;500;0;AAA
piece;1008;504;500;500;0;AAA
piece;1008;1008;500;500;0;AAA
piece;1008;1512;500;500;0;AAA
piece;1008;2016;500;500;0;AAA
piece;1008;2520;500;500;0;AAA
chute;1008;3024;26;500
piece;1512;0;700;300;1;BBB
piece;1512;704;700;300;1;BBB
piece;1512;1408;700;300;1;BBB
piece;1512;2112;700;300;1;BBB
chute;1512;2816;234;300
chute;1816;0;3050;34
Plan N°2
93.58%
MDF_280;;3050;1850;1
piece;0;0;300;700;0;BBB
piece;0;304;300;700;0;BBB
piece;0;608;300;700;0;BBB
i want test
i : line 1 ok next
i <- 94... ok -< next
if i == MDF_280 => loop (exit while EOF or when i == Plan N°)
do ....
end loop
soory but i'm novice in apple script
and i'm french
i need to improve my english
this is my applescript
repeat with l in lesLignes
if (l as text) starts with "MDF_280" then
while ???? (!= EOF or "MDF_280") do ....
if (l as text) starts with "piece" then .....
end if
end if
end repeat
THANKS

Answer 1

property sString01 : "Plan N" -- String to search for.
property sString02 : "MDF_280" -- String to search for.
set uFile to (choose file) -- Select file to process.
set tText to read uFile -- Read contents of selected file.
repeat -- Cycle through contents of 'tText'.
set {offset01, offset02} to {offset of sString01 in tText, offset of sString02 in tText} -- Obtain offset locations of 'sString01' and 'sString02'.
if (offset01 = 0) then exit repeat -- If 'sString01' does not exist, exit repeat loop.
-- Adjust content of 'tText' as to position of 'offset02' relative to 'offset01'.
if (offset02 > offset01) then set tText to get (characters (offset02 + (count sString02)) through (count tText) of tText) as string
set offset01 to (offset of sString01 in tText) - 1 -- Obtain next offset of 'String01'.
if (offset01 < 1) then set offset01 to (count tText) -- Correct 'offset01' to obtain remaining contents of 'tText'.
set tmpText to get (characters 1 through offset01 of tText) as string -- Obtain subset content of 'tText' - between 'sString02' and next 'sString01', of end of 'tText'.
display dialog tmpText -- Display obtain subset of content of 'tText'.
end repeat
Since you posted 'how can i read a file text by applescript', and have not replied to others posts; nor marked any reply as 'answered' or even 'helpful'; and, I anticipate you creating a new post asking how to incorporate one of the 'how can i read a file text by applescript' replies into the above (or similar) code - a revised version of 'how can i read a file text by applescript' incorporated within the above code is provided below.
property sString01 : "Plan N" -- String to search for.
property sString02 : "MDF_280" -- String to search for.
property sString03 : "piece" -- String to search for.
property sString04 : "chute" -- String to search for.
set uFile to (choose file) -- Select file to process.
set tText to read uFile -- Read contents of selected file.
repeat -- Cycle through contents of 'tText'.
set {offset01, offset02} to {offset of sString01 in tText, offset of sString02 in tText} -- Obtain offset locations of 'sString01' and 'sString02'.
if (offset01 = 0) then exit repeat -- If 'sString01' does not exist, then exit the repeat loop.
-- Adjust content of 'tText' as to position of 'offset02' relative to 'offset01'.
if (offset02 > offset01) then set tText to get (characters (offset02 + (count sString02)) through (count tText) of tText) as string
set offset01 to (offset of sString01 in tText) - 1 -- Obtain next offset of 'String01'.
if (offset01 < 1) then set offset01 to (count tText) -- Correct 'offset01' to obtain remaining contents of 'tText'.
set tmpText to get (characters 1 through offset01 of tText) as string -- Obtain subset content of 'tText' - between 'sString02' and next 'sString01', of end of 'tText'.
set tPars to paragraphs of tmpText -- Obtain list of 'piece' entries.
repeat with i in tPars -- Cycle through list.
if (i begins with sString03) then
set {var01, var02, var03, var04, var05, var06} to my handle_List(i) -- Obtain individual values.
-- Your code here.
display dialog ("Piece: " & var01 & " ... " & var02 & " ... " & var03 & " ... " & var04 & " ... " & var05 & " ... " & var06) -- Code sample.
else if (i begins with sString04) then
set {var01, var02, var03, var04} to my handle_List(i)
-- Your code here.
display dialog ("Chute: " & var01 & " ... " & var02 & " ... " & var03 & " ... " & var04) -- Code sample.
end if
end repeat
end repeat
on handle_List(localList) -- Extract values, from each line of data, and place into a list.
set {oAStid, AppleScript's text item delimiters} to {AppleScript's text item delimiters, ";"}
set tItems to text items 2 through -1 of localList
set AppleScript's text item delimiters to oAStid
return tItems -- Return a list of values.
end handle_List