How can I write cursor which tell me no record exists

Question

Hi Experts,
I want to know how can I write a cursor which told me no record exists before opening and running the loop.
So I want that if no record exist then I dont want to run loop and open the cursor.
Example: cursor c1 is select empno from scott.emp where empno=10
In procedure body, I want to check if there is no record against my cusor then I don't like to open it.
Thanks

Answer 1

Rizwan Ali Wahla wrote:
I want to know how can I write a cursor which told me no record exists before opening and running the loop.
So I want that if no record exist then I dont want to run loop and open the cursor.Not possible.
Example: cursor c1 is select empno from scott.emp where empno=10Single row? No need for an explicit cursor. No need for a loop. It can be done using an implicit cursor. E.g.
SQL> create or replace function GetEmployee( empID number ) return EMP%RowType is
  2          empRow EMP%RowType;
  3  begin
  4          select
  5                  e.* into empRow
  6          from    emp e
  7          where   e.empno = empID;
  8          return( empRow );
  9  exception when NO_DATA_FOUND then
10          return( null );
11  end;
12  /
Function created.
SQL>
SQL> declare
  2 
  3          procedure ProcessEmp( empID number ) is
  4                  empRow  EMP%RowType;
  5          begin
  6                  empRow := GetEmployee( empID );
  7 
  8                  if empRow.empno is null then
  9                          dbms_output.put_line( 'Employee '||empID||' does not exist.' );
10                  else
11                          dbms_output.put_line(
12                                  'Employee '||empID||' is '||empRow.ename ||
13                                  ' and employed as '||empRow.job
14                          );
15                  end if;
16          end;
17 
18  begin
19          ProcessEmp( 7900 );
20          ProcessEmp( 7901 );
21  end;
22  /
Employee 7900 is JAMES and employed as CLERK
Employee 7901 does not exist.
PL/SQL procedure successfully completed.
SQL> All SQLs are cursors. Every single SQL passed to Oracle for parsing and execution is a cursor. So it does not make sense to use one SQL cursor for testing the existence of a specific row, and then another to return the row.
That kind of logic is PL/SQL logic and a single SQL cursor need to be used.
PS. Make sure that the SQL projection only includes the columns needed in PL/SQL. If the SQL is a pure exist row? check, then do not return any column and use a literal value as the projected column.
Edited by: Billy Verreynne on Feb 16, 2012 5:55 AM