How do I extract the list from a pop up menu back into Numbers?

Question

Hey guys
I made a few very large lists in pop-up menus in Numbers, and I would like to extract those lists and put them
in a seperate Numbers file.
Is there a way that I can take the lists I made and sort of copy paste them /export them / extract them, so I don't
have to manually copy them?
Thanks in advance!
Derk

Answer 1

Hi Derk,
Numbers doesn't seem to allow access to the values within a Pop-Up Menu, either through the native interface or through AppleScript.
However, if you are using Numbers 3.2 and you have a long column formatted as Pop-Up Menu where you have "used" each the choices in the menu somewhere in the column, then you can collect a list of those values with the script below.
Copy the script into AppleScript Editor.
Select the cells in the body of your column formatted as Pop-Up Menu.
Click the green triangle 'run' button.
Click once in a destination cell in any Numbers document.
Command-v or Edit > Paste & Match Style to paste the list of values.
SG
--places values from cells formatted as Pop-Up onto clipboard for pasting
try
          tell application "Numbers"
                    set t to front document's active sheet's first table whose selection range's class is range
                    set {valuesList, valuesStr} to {{}, ""}
                    tell t's selection range to repeat with aCell in cells
                              if aCell's formatted value is not in valuesList then
                                        copy aCell's formatted value to end of valuesList
                                        set valuesStr to valuesStr & aCell's formatted value & return
                              end if
                    end repeat
                    set the clipboard to valuesStr
                    display notification "Click a cell and command-v to paste." with title "Numbers"
          end tell
on error
          display alert "Did you select cells before running."
end try
--end of script