How to call user_comp in POV?

Question

Hello All
I have requirement of calling user_comp search help explicitly, please see the details below.
I have two fields on screen "Department" & "User ID" if I enter userid i am populating "Department" automatically. Now if user enters "Department" and press F4 on userid then in "user_comp", "Department" should be filled with the value user has entered on the screen.
I know that I can do it using customized search help.
However, I want to utilize standard search help only. I see in SE11 I have option of test for "USER_COMP" thats the reason I am thinking if I can use standard search help and just pass screen value to it.
Thanks for your inputs.
Amol.

Answer 1

You can pass the "Department value" to the Elementary Search help "USER_ADDR" ( The search help in USER_COMP which has department ) using the below code and would have been possible in the Collective search help with below code if the department field existed in the Search help parameters in the definition of Collective search help "USER_COMP". Below logic calls the USER_ADDR if department value is populated else calls USER_COMP - fine tune as per your requirements.
PROCESS ON VALUE-REQUEST.
  FIELD GV_NAME MODULE F4_UNAME.
*&      Module  F4_UNAME  INPUT
*       text
module F4_UNAME input.
* Local declarations
  CONSTANTS: LC_TABNAME   TYPE SHLPNAME   VALUE 'USER_COMP',
             LC_FLDNAME   TYPE DDSHLPDFLD VALUE 'BNAME'.
DATA: LV_SHLPNAME  TYPE SHLPNAME,
      LV_DEPT      TYPE AD_DPRTMNT,
      LV_RTRNCD    TYPE SY-SUBRC,
      LS_RETVAL    TYPE DDSHRETVAL,
      LS_SHLP      TYPE SHLP_DESCR,
      LT_SELOPT    TYPE DDSHSELOPS,
      LS_SELOPT    TYPE DDSHSELOPT,
      LT_RETVAL    TYPE STANDARD TABLE OF DDSHRETVAL.
  FIELD-SYMBOLS <LS_SHLP> TYPE DDSHIFACE.
  LS_RETVAL-SHLPNAME  = LC_TABNAME.
  LS_RETVAL-FIELDNAME = LC_FLDNAME.
  APPEND LS_RETVAL TO LT_RETVAL.
* Code the logic here to get the LV_DEPT from Department field in the screen.....
  LV_DEPT = 'Department'.   " Test value....
  IF NOT LV_DEPT is initial.
    LV_SHLPNAME = 'USER_ADDR'.
  Else.
    LV_SHLPNAME = 'USER_COMP'.
  Endif.
  CALL FUNCTION 'F4IF_GET_SHLP_DESCR'
    EXPORTING
      SHLPNAME = LV_SHLPNAME
      SHLPTYPE = 'SH'
    IMPORTING
      SHLP     = LS_SHLP.
  READ TABLE LS_SHLP-INTERFACE ASSIGNING <LS_SHLP> WITH KEY SHLPFIELD = LC_FLDNAME.
  IF SY-SUBRC EQ 0.
    <LS_SHLP>-F4FIELD = 'X'.
    <LS_SHLP>-VALTABNAME = LC_TABNAME.
    <LS_SHLP>-VALFIELD   = LC_FLDNAME.
  ENDIF.
  LS_SELOPT-SHLPNAME  = 'USER_ADDR'.
  LS_SELOPT-SHLPFIELD = 'DEPARTMENT'.
  LS_SELOPT-SIGN      = 'I'.
  LS_SELOPT-OPTION    = 'EQ'.
  LS_SELOPT-LOW       = LV_DEPT.
  APPEND LS_SELOPT TO LT_SELOPT.
  LS_SHLP-SELOPT = LT_SELOPT[].
CALL FUNCTION 'F4IF_START_VALUE_REQUEST'
  EXPORTING
    SHLP          = LS_SHLP
  IMPORTING
    RC            = LV_RTRNCD
  TABLES
    RETURN_VALUES = LT_RETVAL.
endmodule.                 " F4_UNAME  INPUT