How to create a structure which can hold a dynamic table as a field in DDIC

Question

Hi ,
       I am designing a solution for a problem and have a unique requirement.  I need to create a structure which can hold a field where dynamic table data can be stored.  Let me illustrate with an example :
My structure  ( say  Z_output_struc ) will have the fields
Table_name  Table_Data
My function module will have a table type of the above structure, so in effect ,my output can have multiple table names and related to each of them, there will be table data of that table name. The issue is how do I configure this in DDIC ?
I tried creating table_data as "Type ref to Data"  but was stuck  inside the func module when I tried to transfer data to this.
Any pointers as to how to think about this differently ? 
Best Regards,
Girish

Answer 1

Hi Girish,
you start directly from the ref to data. You assign it to a field symbol and cast this to the type of the destination of your select. So you can directly add the reference to the cache:
I hope this example helps a bit (I took a form instead of a function module as it is easier to add here and used an hr table as kna1 is empty on my test system):
REPORT  z_rwe_99_dyn_tab_cache.
* type definition
TYPES:
  BEGIN OF _s_cache,
    table TYPE        tabname16,
    cache TYPE REF TO data,
  END   OF _s_cache,
  _t_cache TYPE STANDARD TABLE OF _s_cache.
* data declaration
DATA:
  lv_table     TYPE tabname16,
  lv_condition TYPE string,
  lt_cache     TYPE _t_cache.
* define table and condition
lv_table     = 'HRP1000'.
lv_condition = 'plvar = ''01'' and otype = ''S'' and objid = ''50000016'''.
* get the result of a single table into the cache
PERFORM get_dyn_table USING
                        lv_table
                        lv_condition
                      CHANGING
                        lt_cache.
* form to read a single table
FORM get_dyn_table USING
                     iv_table     TYPE tabname16
                     iv_condition TYPE string
                   CHANGING
                     ct_cache     TYPE _t_cache.
  FIELD-SYMBOLS:
    <lt_table> TYPE ANY TABLE.
  DATA:
    ls_cache TYPE        _s_cache,
    lr_data  TYPE REF TO data.
  CREATE DATA lr_data TYPE STANDARD TABLE OF (iv_table).
  ASSIGN lr_data->* TO <lt_table>.
  SELECT * FROM (iv_table) INTO TABLE <lt_table>
    WHERE
      (iv_condition).
  ls_cache-table = lv_table.
  ls_cache-cache = lr_data.
  APPEND ls_cache TO ct_cache.
ENDFORM.                    "get_dyn_table
If you have more questions just give another post.
Best Regards
Roman