How to create subfolders with names corresponding to the filenames

Question

Hello outhere,
sorry to ask this here, but I'm a complete noob with Actionscript.
Can anybody please tell me if this is possible at all and perhaps give me some hint how to manage this:
I would like to be able to do something like this:
I have a source folder with files.
The files do have different extensions, which are not important for the actions
The filenames consist of a 8digit, some have some additional strings which are not important for the action.
Example filename: 14123456.tif or 1423456YT.jpg
I would like to create a folder structure where each of the 8digits of the filenames represents a subfolder (which needs to be created when not there) and then move the file into this subfolder, overwriting exinsting files with the same name without prompt.
So for the file 14123456YT.jpg the script should create a folder structure like:
Foler "1" with a subfolder "4", with a subfolder "1" etc. and move then this file into this subfolder. Again: it is only about 8 digits, if there are addition strings after the 8th digit, this does not need a subfolder (like "Y" in the above example". The next file in the source might have a complete different number.
I do not expect that somebody creates this for me, not at all.
But before I dive into the Applescript I would like to know if this is possible at all. Of course I would be happy for any hints to scripts that are similar to what I want so that I can use this as a starting point.
Thanks for any discussions on this matter,
gb5256

Answer 1

It looks like (on a British system with "." as the decimals separator), coercion from a string to an integer will round up with a "." - "1234.567" becomes 1235 - and will ignore a "," - the same string becomes "1234567". On a continental system, this will likely be the other way around.
In these circumstances, I think the only option you have is to iterate through every character to check that it's a number. This will take slightly longer, but it will at least guarantee that nothing other than a number will work. I have made the change below. Note that the 'exit repeat' takes you out of the repeat loop as soon as an illegal character is found.
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #FFDDFF;
overflow: auto;">
tell application "Finder"
set theFolder to choose folder --asks for user to select a top level folder
set topLevel to theFolder --holds the path to the top level
set fileList to document files of theFolder --gets every document file in the top level folder
repeat with theFile in fileList --iterates through the files
set fileName to name of theFile --sets variable to name of the file
set thePath to characters 1 thru 8 of fileName --gets first 8 characters of the file name into a list
set numeric to true
repeat with theChar in thePath
if theChar is not in "0123456789" then
set numeric to false
exit repeat
end if
end repeat
if numeric then
repeat with subFolder in thePath --iterates through the list of characters
if (subFolder as text) is in "0123456789" then --checks for numeral
if not (exists folder named subFolder in theFolder) then --checks if folder with this name already exists
set folderName to (subFolder as text) --puts name into a variable
set theFolder to (make new folder in theFolder with properties {name:folderName}) --makes the new folder
else
set theFolder to folder subFolder of theFolder --if the folder exists, move down to that level
end if
end if
end repeat
if not (exists file named fileName in theFolder) then
move theFile to theFolder --move the file from the top level to the bottom of the folder hierarchy
end if
set theFolder to topLevel --start again from the top
end if
end repeat
end tell </pre>
Message was edited by: Bernard Harte