How to delete data in table control

Question

Hi,
I am doing module pool programming. After the user enters the data in table control after saving the data. if the user wants to  remove the line item the line item shd be removed from the screen and data base.
Please Give me vaulable Suggestions
Regards

Answer 1

Hi,
Screen 8002 (with table control) --> select records --> press delete button --> delete selected records
Now you wan to delete those records selected by the user at runtime when DELETE button is clicked.
Take another internal table and work area same as the initial internal table and work area used in screen 8002 which is to be used to delete the selected data.
Take the names of the input/output fields as work_area-field_name and select column in table control as work_area-flag.
Also take a flag field of size 1 datatype character as the last field in the internal table and work area while declaration.
You must have passed a code in PBO of the screen for reading internal table into the table control.
So it reads the internal table into the table control whenever you perform any action on use command.
All you need to do is to write a code to modify the internal table form the table control while performing any user action.
Remember to change the LINE SEL option in attributes of table control as MULTIPLE.
At screen logic,
PROCESS BEFORE OUTPUT.
  MODULE status_8002. "for pf-status
  LOOP WITH CONTROL po_tab. "po_tab is table control
    MODULE pass_data. "to pass data into table control from internal table
  ENDLOOP.
PROCESS AFTER INPUT.
  MODULE user_command_8002. "for user command(back and exit)
  LOOP WITH CONTROL po_tab.
    MODULE modify_data. "to modify data from table control into table control
  ENDLOOP.
  MODULE delete. "to delete the selected records
In PBO,
*&      Module  STATUS_8002 OUTPUT
MODULE status_8002 OUTPUT.
  SET pf-status 'ZAB_PFSTA'. " pf-status
  DATA : line_count TYPE i.
  DESCIRBE TABLE it_ekpo
  LINES line_count.
  po_tab-lines = line_count + 10.
  " to make table control scrollable
ENDMODULE.                 " STATUS_8002  OUTPUT
*&      Module  PASS_DATA  OUTPUT
MODULE pass_data OUTPUT.
  READ TABLE it_ekpo into wa_ekpo INDEX po_tab-current_line.
ENDMODULE.                 " PASS_DATA  OUTPUT
"it_ekpo is internal table and wa_ekpo is the work area
In PAI,
*&      Module  MODIFY_DATA  INPUT
MODULE MODIFY_DATA INPUT.
  MODIFY IT_EKPO INDEX PO_TAB-CURRENT_LINE FROM WA_EKPO.
  "modify records from table control into the internal table
ENDMODULE.                 " MODIFY_DATA  INPUT
*&      Module  DELETE  INPUT
MODULE DELETE INPUT.
  OK_CODE = SY-UCOMM.
  CASE OK_CODE.
    WHEN 'DELETE'. "when delete button is clicked
      SORT IT_EKPO BY FLAG DESCENDING. "sort by flag(selection column value)
      CLEAR WA_EKPO1.
      CLEAR WA_EKPO.
      REFRESH IT_EKPO1.
      LOOP AT IT_EKPO INTO WA_EKPO WHERE FLAG = 'X'.
        DATA : J TYPE I.
        CLEAR J.
        J = SY-TABIX. "assign index value if a record is selected
        MOVE-CORRESPONDING WA_EKPO TO WA_EKPO1. "append selected records to another
        "work area and append to another internal table to delete
        APPEND WA_EKPO1 TO IT_EKPO1.
        DELETE IT_EKPO. "delete the selected records from initial internal table
        " to reflect the changes on the table control
      ENDLOOP.
      IF J = 0.
        MESSAGE I006. "if no record selected
      ELSE. "if some records are selected
        DELETE ZEKPO FROM TABLE IT_EKPO1. "delete from database table
        COMMIT WORK.
        IF SY-SUBRC = 0.
          MESSAGE S007. "success message (records deleted)
        ENDIF.
      ENDIF.
  ENDCASE.
ENDMODULE.                 " DELETE  INPUT
Now at PAI, you have delete records and these changes are reflected back to the internal table.
Now when PBO is executed it will again read the initial internal table and will not show the deleted records.
Hope this solves your problem.
Thanks & Regards,
Tarun Gambhir