How to open renamed files?

Question

Hi
I rename selected files and after that want to open them.
For my purpose renaming works well like this:
tell application "Finder"
set FilesToRENAME to selection
display dialog "Change what?" default answer ""
set ChangeFROM to text returned of the result
display dialog "Change to?" default answer ""
set ChangeTO to text returned of the result
set AppleScript's text item delimiters to {ChangeFROM}
set theCount to count of FilesToRENAME
repeat with x from 1 to theCount
try
set theName to name of item x of FilesToRENAME
set FirstNamePart to first text item of theName
set LastNamePart to second text item of theName
set newName to FirstNamePart & ChangeTO & LastNamePart
set name of item x of FilesToRENAME to newName
on error errStr number theNumber
activate
display dialog "Error in changing the Name " & theNumber & return & errStr ¬
& return & "Step " & x
end try
end repeat
set AppleScript's text item delimiters to ""
end tell
Now newly renamed files don't belong anymore to FilesToRENAME. So how to point to those files now (how to make a new list from those renamed files)? I was thinking to get a path to each file inside the repeat loop and replace the name, but couldn't do it.
Thank you for any help.
Vera

Answer 1

Pierre's method is pretty clever, but if you don't happen to be using a Finder selection (choose file for example), you can also use the interesting fact that an alias keeps track of an item even if it is moved or renamed.
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #DAFFB6;
overflow: auto;"
title="this text can be pasted into the Script Editor">
-- tell application "Finder" to set filesToRename to selection as alias list
set filesToRename to (choose file with multiple selections allowed)
set changeFrom to text returned of (display dialog "Change what?" default answer "")
set changeTo to text returned of (display dialog "Change to?" default answer "")
set renamedFiles to {} -- this will be the renamed files
repeat with aFile in filesToRename
set aFile to the contents of aFile
tell application "Finder" to set theName to name of aFile
try
set tempTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to {changeFrom}
set firstNamePart to first text item of theName
set lastNamePart to second text item of theName
set AppleScript's text item delimiters to tempTID
set newName to firstNamePart & changeTo & lastNamePart
tell application "Finder"
set name of aFile to newName -- aFile points to the original file
update aFile -- give Finder a chance to catch up
set the end of renamedFiles to aFile -- aFile now points to the renamed file
end tell
on error errStr number theNumber
activate me
display alert "Error " & theNumber & " in changing the Name" message errStr
end try
end repeat
renamedFiles --> aliases to the renamed files
</pre>