How to see the data from the execute immediate o/p

Question

Hello
i tried the following code
SQL> declare
  2  vSql varchar2(3000);
  3  begin
  4  vSql:='SELECT';
  5   for i in (select column_name from user_tab_columns where table_name='EMP' order by column_name
  6   loop
  7     vSql:=vSql||i.column_name||',';
  8   end loop;
  9   execute immediate rtrim(vSql)||' '||'from emp';
10  end;
11  /
declare
ERROR at line 1:
ORA-00900: invalid SQL statement
ORA-06512: at line 9Please guide me to solve this error
Edited by: josh1612 on Jun 22, 2010 3:58 AM

Answer 1

josh1612 wrote:
I need to execute that printed statment select ... from emp
You are already executing it by using:
execute immediate rtrim(vSql,',')||' from emp';What you probably want is to display results, right? Then you can either use bulk collect into clause in execute immediate or use cursor variable. Bulk collect example:
set serveroutput on
declare
  vSql varchar2(3000);
  type emp_rec_tbl_type is table of emp%rowtype;
  emp_rec_tbl emp_rec_tbl_type;
begin
  vSql:='SELECT ';
   for i in (select column_name from user_tab_columns where table_name='EMP' order by column_id)
   loop
     vSql:=vSql||i.column_name||',';
   end loop;
   dbms_output.put_line(rtrim(vSql,',')||' from emp');
   execute immediate rtrim(vSql,',')||' from emp' bulk collect into emp_rec_tbl;
   for i in 1..emp_rec_tbl.count loop
     dbms_output.put_line(rpad(emp_rec_tbl(i).ename,10) || emp_rec_tbl(i).sal);
   end loop;
end;
SELECT EMPNO,ENAME,JOB,MGR,HIREDATE,SAL,COMM,DEPTNO from emp
SMITH     800
ALLEN     1600
WARD      1250
JONES     2975
MARTIN    1250
BLAKE     2850
CLARK     2450
SCOTT     3000
KING      5000
TURNER    1500
ADAMS     1100
JAMES     950
FORD      3000
MILLER    1300
PL/SQL procedure successfully completed.
SQL> Cursor variable example:
set serveroutput on
declare
  vSql varchar2(3000);
  emp_rec emp%rowtype;
  cv sys_refcursor;
begin
  vSql:='SELECT ';
   for i in (select column_name from user_tab_columns where table_name='EMP' order by column_id)
   loop
     vSql:=vSql||i.column_name||',';
   end loop;
   dbms_output.put_line(rtrim(vSql,',')||' from emp');
   open cv for rtrim(vSql,',')||' from emp';
   loop
     fetch cv into emp_rec;
     exit when cv%notfound;
     dbms_output.put_line(rpad(emp_rec.ename,10) || emp_rec.sal);
   end loop;
   close cv;
end;
SELECT EMPNO,ENAME,JOB,MGR,HIREDATE,SAL,COMM,DEPTNO from emp
SMITH     800
ALLEN     1600
WARD      1250
JONES     2975
MARTIN    1250
BLAKE     2850
CLARK     2450
SCOTT     3000
KING      5000
TURNER    1500
ADAMS     1100
JAMES     950
FORD      3000
MILLER    1300
PL/SQL procedure successfully completed.
SQL> SY.