How to upload and download in BLOB?

Question

I tried webutil but is not working properly according to my needs is there any other way to upload and download files in BLOB?
If any body knows solution please tell me.
Regards,

Answer 1

Dear Colleague,
In my Forms application, I use the WEBUTIL to load files into a BLOB column. However, prior to getting WEBUTIL to work, I loaded files into the BLOB column using the following PL/SQL code.
Note, that the example assumes that the row already exists in the table and you are updating it by loading the file into the BLOB. You will also be required to first create a Database Directory object (in my case, it was called "RKMS_DOC_DIR")
I do not have an example for downloading, as I use the WEBUTIL functionality for this.
Good luck!
Randy
PL/SQL (DBMS_LOB Package): Loading an Internal Persistent BLOB
with BFILE Data
The following example illustrates:
How to use LOADBLOBFROMFILE to load the entire file without getting its length first.
How to use the return value of the offsets to calculate the actual amount loaded.
DECLARE
src_loc BFILE := bfilename('RKMS_DOC_DIR','ROPE_Offerte_v2.pdf') ;
v_author VARCHAR2(10) := 'RKMS_MGR' ;
dst_loc BLOB;
src_offset NUMBER := 1;
dst_offset NUMBER := 1;
src_osin NUMBER;
dst_osin NUMBER;
bytes_rd NUMBER;
bytes_wt NUMBER;
BEGIN
-- SELECT ad_composite INTO dst_loc FROM Print_media
-- WHERE product_id=3106 and ad_id=13001 FOR UPDATE;
SELECT doc INTO dst_loc FROM docs
WHERE USER_AUTHOR_ID = v_author FOR UPDATE;
/* Opening the source BFILE is mandatory */
dbms_lob.fileopen(src_loc, dbms_lob.file_readonly);
/* Opening the LOB is optional */
dbms_lob.OPEN(dst_loc, dbms_lob.lob_readwrite);
/* Save the input source/destination offsets */
src_osin := src_offset;
dst_osin := dst_offset;
/* Use LOBMAXSIZE to indicate loading the entire BFILE */
dbms_lob.LOADBLOBFROMFILE(dst_loc, src_loc, dbms_lob.lobmaxsize, src_offset, dst_offset) ;
/* Closing the LOB is mandatory if you have opened it */
dbms_lob.close(dst_loc);
dbms_lob.filecloseall();
COMMIT;
/* Use the src_offset returned to calculate the actual amount read from the BFILE */
bytes_rd := src_offset - src_osin;
dbms_output.put_line(' Number of bytes read from the BFILE ' || bytes_rd ) ;
/* Use the dst_offset returned to calculate the actual amount written to the BLOB */
bytes_wt := dst_offset - dst_osin;
dbms_output.put_line(' Number of bytes written to the BLOB ' || bytes_wt ) ;
/* If there is no exception the number of bytes read should equal to the number of bytes written */
END ;
/