ICal to alert me to call a contact from Address Book?

Question

I currently use Entourage's address book as a contact manager and want to switch to Mac Address Book and iCal to track my clients. I can't figure out how to have a specific Address Book client alert me to call back on a specific date I specify.
For instance, in Entourage, I use it's address book function and set a "To Do Date" for it to remind me to call this client. I was told on the Address Book forum it's not possible unless iCal can do it. How is this done in iCal (other than having to set a new event in meeting-like iCal which would be a real pain)? I have to be reminded of 10 to 30 call-backs each day.
If this doesn't work, what's my options? If I stay with Entourage I have to deal with syncing to my iPhone via the archaic and entirely reliable Entourage to iCal via Sync Services, and then to my iPhone. I do end up with duplicates calendar entries on occasions.
B. Other software or ideas?

Answer 1

Hi Mike,
I agree with Austin. Applescript will help with this. I've taken a different tack with it though and I'd suggest using Address Book's plug-in structure.
Copy the script below into Script Editor and make changes to the lines starting "property". You'll need to save this script in your User's Library > Address Book Plug-Ins folder (you may need to make this folder) or it won't work.
Now when you click on the label of a phone number in Address Book there will be a contextual menu item to "Call <name> later". This will ask you for a date and to add more notes, then it will make a Todo in the calendar you set in the script.
-- Call Later -- John Maisey -- www.nhoj.co.uk -- 1 May 2009
-- -- Address Book plug-in
-- -- Save as CallLater.scpt and add to folder "~/Library/Address Book plug-ins"
property myCalendar : "Home" -- Calendar to add todo to.
property myAdvance : 7 -- Default number of days from current date
property setAlarm : true -- Do the Todos pop up an alarm? (true or false)
using terms from application "Address Book"
on action property
return "phone"
end action property
on should enable action for thePerson with theEntry
if theEntry is not equal to missing value then
return true
else
return false
end if
end should enable action
on action title for thePerson with theEntry
return "Call " & (name of thePerson) & " later"
end action title
on perform action for thePerson with theEntry
set theName to name of thePerson
set thePhoneNumber to value of theEntry
set theURL to "addressbook://" & id of thePerson
set myDate to text returned of (display dialog "Enter the date to call " & theName default answer (short date string of ((current date) + (myAdvance * days))) with title "Call Later - by John Maisey")
set myNotes to text returned of (display dialog "Additional notes" default answer return & return with title "Call Later - by John Maisey")
tell application "iCal"
try
set myTodo to make new todo at the end of todos of calendar myCalendar with properties {summary:"Call " & theName, url:theURL, due date:(my date myDate), description:"On " & thePhoneNumber & return & myNotes, priority:medium priority}
if setAlarm then
make new display alarm at the end of display alarm of myTodo with properties {trigger interval:0}
end if
on error theErr
display dialog theErr with title "Call Later - by John Maisey"
end try
end tell
end perform action
end using terms from
Let us know if you need more details.
Best wishes
John M