Insert data into oracle table from XML script not working

Question

Hi,
I wrote simple PL/SQL program to extract values from a XML file and disply all the employee names. But the first employee name repeating. Please can you tell me how to fix it.
set serveroutput on size 2000;
declare
indoc VARCHAR2(2000);
indomdoc dbms_xmldom.domdocument;
innode dbms_xmldom.domnode;
myParser dbms_xmlparser.Parser;
l_nl dbms_xmldom.DOMNodeList;
lv_value varchar2(30);
l_n dbms_xmldom.DOMNode;
begin
indoc := '<emp> <name> Scott </name>
<name> Tiger </name>
</emp>';
myParser := dbms_xmlparser.newParser;
dbms_xmlparser.parseBuffer(myParser, indoc);
indomdoc := dbms_xmlparser.getDocument(myParser);
innode := dbms_xmldom.makeNode(indomdoc);
l_nl := dbms_xslprocessor.selectNodes(dbms_xmldom.makeNode(indomdoc),'/emp/name');
dbms_output.put_line('Record count '||dbms_xmldom.getLength(l_nl));
FOR cur_emp IN 0 .. dbms_xmldom.getLength(l_nl) - 1 LOOP
l_n := dbms_xmldom.item(l_nl, cur_emp);
lv_value := dbms_xslprocessor.valueOf(l_n,'//name/text()');
dbms_output.put_line('Emp Name : '||lv_value);
END LOOP;
end;
/

Answer 1

Based on an earlier example of mine from {message:id=2826611}
This works in 10.2.x.x for sure. I can't recall (didn't look up) whether in 10.1 it allowed for going straight from a CLOB to a DOMDocument via newDomDocument.
declare
   indoc    VARCHAR2(2000);
   indomdoc dbms_xmldom.domdocument;
   l_nl     dbms_xmldom.DOMNodeList;
   lv_value VARCHAR2(30);
   l_n      dbms_xmldom.DOMNode;
   l_xmltype   XMLTYPE;
   l_index     PLS_INTEGER;
begin
   indoc := '<emp> <name> Scott </name>
   <name> Tiger </name>
   </emp>';
   indomdoc := dbms_xmldom.newDomDocument(indoc);
   l_nl := dbms_xslprocessor.selectNodes(dbms_xmldom.makeNode(indomdoc),'/emp/name');
   dbms_output.put_line('Record count '||dbms_xmldom.getLength(l_nl));
   -- Method 1
   FOR cur_emp IN 0 .. dbms_xmldom.getLength(l_nl) - 1 LOOP
      l_n := dbms_xmldom.item(l_nl, cur_emp);
      lv_value := dbms_xmldom.getnodevalue(dbms_xmldom.getfirstchild(l_n));
      dbms_output.put_line('Emp Name : '||lv_value);
   END LOOP;
   dbms_xmldom.freeDocument(indomdoc);
   -- Method 2
   dbms_output.new_line;
   l_xmltype := XMLTYPE(indoc);
   l_index := 1;
   WHILE l_xmltype.Existsnode('/emp/name[' || To_Char(l_index) || ']') > 0
   LOOP
      lv_value := l_xmltype.extract('/emp/name[' || To_Char(l_index) || ']/text()').getStringVal();
      dbms_output.put_line('Emp Name : '||lv_value);
      l_index := l_index + 1;
   END LOOP;
end;