Instantiating Object with NDS

Question

I'm having no success in instantiating object with NDS. Does anyone know whether is possible?
I can hard code a statement as follows:
pkg1.gs_nt(gs_nt.LAST) := NEW SomeObject_ot('x');
where pkg1 is a package with the gs_nt variable declared in the spec. (global scope). The var. gs_nt is a nested table of SomeObject_ot type.
When I try to use the same approach using NDS I get error messages at compile time:
PLS-000103: Encountered the symbol "" - When I try to use the SomeObject_ot in a USING clause to set the value of a placeholder. In other words, it doesn't do the substitution.
PLS-00382: expression is of wrong type - when I try to concatenate the object with a string.
Based on the above, I've concluded that NDS can't be used to instantiate object types.
Is thsi conclusion correct? Does anyone have a solution?

Answer 1

Does this do what you need?
SQL> create or replace type SomeObject is Object (
  2         val varchar2(10)
  3  ) ;
  4  /
Type created.
SQL>
SQL> create or replace type SomeObject_nt is table of SomeObject ;
  2  /
Type created.
SQL>
SQL> CREATE OR REPLACE PACKAGE pkg1 IS
  2      gs_nt someobject_nt;
  3      PROCEDURE initialize(p_var IN VARCHAR2,
  4                           p_obj IN VARCHAR2);
  5  END;
  6  /
Package created.
SQL> CREATE OR REPLACE PACKAGE BODY pkg1 IS
  2      PROCEDURE initialize(p_var IN VARCHAR2,
  3                           p_obj IN VARCHAR2) IS
  4          str VARCHAR2(4000);
  5      BEGIN
  6          str := 'begin ' ||
  7                 '  ' || p_var ||'.EXTEND ; '||
  8                 '  ' || p_var || '(' || p_var ||'.LAST) := NEW ' || p_obj || '(:val) ; ' ||
  9                 'end ;';
10          dbms_output.put_line('Count=' || pkg1.gs_nt.COUNT);
11          EXECUTE IMMEDIATE str
12              USING 'String';
13          dbms_output.put_line('Count=' || pkg1.gs_nt.COUNT || ' pkg1.gs_nt(1).val='||pkg1.gs_nt(1).val);
14      END;
15  BEGIN
16    gs_nt := SomeObject_nt() ;
17  END;
18  /
Package body created.
SQL> set serveroutput on size 100000
SQL> exec pkg1.initialize(p_var => 'pkg1.gs_nt',p_obj => 'SomeObject') ;
Count=0
Count=1 pkg1.gs_nt(1).val=String
PL/SQL procedure successfully completed.
SQL>