Is there any function Module available?

Question

Hi,
Could you please tell me whether the function module is  available for the scenario below.
If we pass RFC Name to the function module it should return success or failure message for the particular target server maintained in the RFC.
We need to check with the help of RFC we just need to know whether the particular target server is running fine or not?
Please help me in this regard.
Thanks & Regards,
Swathi

Answer 1

Hi Swathi,
Actually there is a program available that can check an RFC destination (regardsless of what type it is). In fact within transaction SM59, behind the "Connection Test" button this report is runned and the results shown on screen.
I have made a small ABAP objects method to encapsulate this.
This method has an interface and ABAP code:
-->INTERFACE:
import: RFCDEST  TYPE RFCDEST (OPTIONAL) - Destination to test
change: REACHED  TYPE BOOLEAN            - Is destination active?
change: DETAILS  TYPE RFCSI              - RFC system info (see FM RFC_SYSTEM_INFO)
-->ABAP CODE:
METHOD reach_rfc_destination .
* Test RFC destination connection (all types)
  DATA:
    loc_rfcsi TYPE rfcsi.
* Answer is unknown at the start of the method
  CLEAR:
    loc_rfcsi,
    reached.                  " In this way it is always set to GC_FALSE
* Only if an RFC Destination is supplied
  IF  rfcdest IS SUPPLIED
  AND rfcdest NE space.
*   Clear memory area before call
*   so no details about previous RFC test calls do exist
    FREE MEMORY ID '%_rfctest'.
*   Remote test call
    SUBMIT rsrfctes
      WITH dest = rfcdest AND RETURN.                    "#EC CI_SUBMIT
*   Collect possible RFC information
    IMPORT rfcsi TO loc_rfcsi FROM MEMORY ID '%_rfctest'.
*   Reached
    IF loc_rfcsi IS INITIAL.
*     Answer is not reached
      reached = gc_false.
    ELSE.
*     Answer is reached
      reached = gc_true.
      details = loc_rfcsi.
    ENDIF.
  ENDIF.
* Housekeeping
  CLEAR:
    loc_rfcsi,
    sy-subrc.
ENDMETHOD.
This will supply you with gc_false (=constant value with space) or with gc_true (=constant value with X).
When gc_true the destination is OK and reachable.
Regards,
Rob.