Moving folders. Please help me with my script!

Question

Pretty much I'm making a script that facilitates moving files into other files that are in other files and so on.  First of all, I ask how many folders are within that folder. Example: Folder 1:Folder 2: Folder 3: Final Destination of Folder that wants to be moved.  Then depending on the amount of folders that are within eachother, I will ask them the name of each folder so I know the file path to the destination of the folder that wants to be moved.  I will then move the chosen folder to its destination.  This is my script so far:
set theAmount to the text returned of (display dialog "Is there a folder within that folder, if so how many folders are there?" default answer "")
if theAmount is 1 then set theName1 to the text returned of (display dialog "What is the name of the folder you want to move?" default answer "")
if theAmount is 1 then set theDestination1 to the text returned of (display dialog "What is the name of the folder you want to move it to?" default answer "")
if theAmount is 1 then tell application "Finder"
  move folder theName1 to folder theDestination1
end tell
if theAmount is 2 then set theName1 to the text returned of (display dialog "What is the name of the folder you want to move?" default answer "")
if theAmount is 2 then set theDestination1 to the text returned of (display dialog "What is the name of the folder that contains the folder that you want to move to?" default answer "")
if theAmount is 2 then set theDestination2 to the text returned of (display dialog "What is the name of the folder that is the final destination?" default answer "")
if theAmount is 2 then tell application "Finder"
  move folder theName1 to (folder theDestination1) + ":" + theDestination2
end tell
Problem 1: It asks me the first question then nothing happens.
Problem 2: I would like to make it so that I don't have to keep repeating "if theAmount is X then ask him the name of the folder it's in X amount of times."
I appreciate any help, thanks!

Answer 1

Without seeing your original source setup, it's hard to know quite how to set this up, but...
Why are you asking the user these questions at all? Let me explain...
Given a designated folder:
set theFolder to (choose folder)
You can find out yourself how many folders there are within it:
tell application "Finder"
          set theAmount to count folders of folder theFolder
end tell
So, for one, you don't need to ask the user how many folders there are - you already know (although you can still ask if you want).
More importantly, though, you don't have to rely on the user knowing the folder names (and typing them correctly). Give the user the ability to choose from a list:
tell application "Finder"
          set folder_list to name of folders of folder theFolder
          set theAmount to count folder_list
          set theName to choose from list folder_list with prompt "Which folder do you want to move?"
          set theDestination to choose from list folder_list with prompt "Where do you want to move it?"
end tell
Finally your move statement isn't going to work.
  move folder theName1 to folder theDestination1
In your original code, the user is likely (I assume) to enter the folder names (e.g. "Foo" and "Bar") which will translate into:
  move folder "Foo" to folder "Bar"
The Finder is going to choke on this - it can't find folder "Foo" (or "Bar") since there isn't enough data there - these strings are not paths, they're just names of folders - and if you're expecting the user to type full paths each time... well, good luck
The Finder is going to want proper paths to the folders in order to make the moves. You can do this by appending the folder names to the original folder object, e.g.:
  move (folder theName of theFolder) to (folder theDestination of theFolder)
Although now you're moving a folder out of the source directory, and there's nothing to stop the user from re-selecting the same folder name next time around. You can get around that with a loop but, again, not knowing your ultimate goal here, it's not easy to be precise.