Need 'Creation Date' function in '09

Question

I'm looking for a formula that automatically generates the date in a cell, when data is entered in an adjacent cell. Currently, whenever data is entered into A1 for example, B2 displays the current date using the 'TODAY' function, but that will change to the current day automatically. I need it to show the day data was entered into A1, and stay that way. Any suggestions?
Thanks!

Answer 1

Here is the beast
--[SCRIPT store_CreationDate]
Enregistrer le script en tant qu'Application ou Progiciel : store_CreationDate.app
déplacer l'application créée dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Numbers:
Il vous faudra peut-être créer le dossier Numbers et peut-être même le dossier Applications.
Placez le curseur dans la cellule que vous souhaitez alimenter.
menu Scripts > Numbers > store_CreationDate
La cellule pointée reçoit la chaîne saisie
La cellule située à sa droite dans la ligne inférieure reçoit la date_heure de l'intervention.
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
+++++++
Save the script as an Application or an Application Bundle: store_CreationDate.app
Move the newly created application into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Numbers:
Maybe you would have to create the folder Numbers and even the folder Applications by yourself.
Put the cursor in the cell which must receive your entry.
menu Scripts > Numbers > store_CreationDate
The pointed cell receives the entered string.
The cell on its right in the row below receive the current date_time.
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
Yvan KOENIG (Vallauris, FRANCE)
16 février 2009
property theApp : "Numbers"
--=====
on run
set {rname, tName, sName, dName} to my getSelection()
if rname is missing value then
if my parleFrancais() then
error "Pas de cellule sélectionnée !"
else
error "No selected cell !!"
end if
end if -- rname
set twoNames to my decoupe(rname, ":")
set {colNum1, rowNum1} to my decipher(item 1 of twoNames)
if item 2 of twoNames = item 1 of twoNames then
set {colNum2, rowNum2} to {colNum1, rowNum1}
else
set {colNum2, rowNum2} to my decipher(item 2 of twoNames)
end if
tell application (path to frontmost application as string)
if my parleFrancais() then
set rate to text returned of (display dialog "Contenu de la cellule…" default answer "blabla bla")
else
set rate to text returned of (display dialog "Cell's contents" default answer "blabla bla")
end if
end tell
my doYourDuty(colNum1, rowNum1, tName, sName, dName, rate)
end run
--=====
on doYourDuty(c, r, t, s, d, txt) (*
c = columnIndex
r = rowIndex
t = table's name
s = sheet's name
d = document's name
txt = new cell's contents *)
local cdt
set cdt to my cleanThisDate(current date) (* the new date_time as a clean date_time *)
tell application "Numbers" to tell document d to tell sheet s to tell table t
set value of cell r of column c to txt
set value of cell (r + 1) of column (c + 1) to (cdt as text)
(c+1) to put in the column on the right
(r+1) to put in the row below *)
end tell -- application …
end doYourDuty
--=====
on cleanThisDate(dt)
(* ugly code but once I got date_time with milliseconds so if necessary, I drop them *)
local L
set L to my decoupe(dt as text, ":")
if (count of L) = 4 then
set dt to date (my recolle(items 1 thru 3 of L, ":"))
end if
return dt
end cleanThisDate
--=====
on getSelection()
local mySelectedRanges, sheetRanges, thisRange, _, myRange, myTable, mySheet, myDoc, mySelection
tell application "Numbers" to tell document 1
set mySelectedRanges to selection range of every table of every sheet
repeat with sheetRanges in mySelectedRanges
repeat with thisRange in sheetRanges
if contents of thisRange is not missing value then
try
thisRange as text
on error errMsg number errNum
set {_, myRange, _, myTable, _, mySheet, _, myDoc} to my decoupe(errMsg, quote)
return {myRange, myTable, mySheet, myDoc}
end try
end if -- contents…
end repeat -- thisRange
end repeat -- sheetRanges
end tell -- table of sheet of document of application
return {missing value, missing value, missing value, missing value}
end getSelection
--=====
on decipher(n)
local colNum, rowNum, letters
set letters to "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
if (character 2 of n) as text > "9" then
set colNum to (offset of (character 1 of n) in letters) * 64 + (offset of (character 2 of n) in letters)
set rowNum to (text 3 thru -1 of n) as integer
else
set colNum to offset of (character 1 of n) in letters
set rowNum to (text 2 thru -1 of n) as integer
end if
return {colNum, rowNum}
end decipher
--=====
on decoupe(t, d)
local L
set AppleScript's text item delimiters to d
set L to text items of t
set AppleScript's text item delimiters to ""
return L
end decoupe
--=====
on recolle(L, d)
local t
set AppleScript's text item delimiters to d
set t to L as text
set AppleScript's text item delimiters to ""
return t
end recolle
--=====
on parleFrancais()
local z
try
tell application theApp to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z = "Annuler")
end parleFrancais
--=====
--[/SCRIPT]
Yvan KOENIG (from FRANCE lundi 16 février 2009 17:23:29)