Objects in normal reports

Question

Hi friends,
If i want to create a simple report in alv through objects i have to create a screen and gui status to show the output utilizing the class cl_gui_alv_grid.
Is there any alternative i can avoid creating screen and gui status and show the output in selection screen.
Regards,
Praveen Lobo

Answer 1

Not sure if Bruces example is complete or not, but here is another which I found in my bag of tricks.
report zrich_0001.
* Used to limit user commands on selection-screen
include rsdbc1xx.
data: begin of i_alv occurs 0,
      matnr type mara-matnr,
      maktx type makt-maktx,
      end of i_alv.
data: alv_grid       type ref to cl_gui_alv_grid.
data: fieldcat  type lvc_t_fcat.
selection-screen begin of block b1 with frame title text-001 .
select-options: s_matnr for i_alv-matnr.
selection-screen end of block b1.
selection-screen begin of screen 1010.
selection-screen end of screen 1010.
* Events
at selection-screen output.
  if sy-dynnr = '1010'.
    current_scr-mode = 'S'.
    append 'SPOS' to current_scr-excl.
    append 'SCRH' to current_scr-excl.
    append 'ONLI' to current_scr-excl.
  endif.
start-of-selection.
  perform get_data.
  create object alv_grid
         exporting
               i_parent           =  cl_gui_container=>screen0.
*  Populate Field Catalog
  perform get_fieldcatalog.
  call method alv_grid->set_table_for_first_display
      changing
           it_outtab              = i_alv[]
           it_fieldcatalog        = fieldcat[].
  call selection-screen 1010.
* FORM GET_DATA
form get_data.
  select * into corresponding fields of table i_alv
        from mara
          inner join makt
            on mara~matnr = makt~matnr
               where mara~matnr in s_matnr
                 and makt~spras = sy-langu.
  sort i_alv ascending by matnr.
endform.
*      Form  Get_Fieldcatalog - Set Up Columns/Headers
form get_fieldcatalog.
  data: ls_fcat type lvc_s_fcat.
  refresh: fieldcat.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Number'.
  ls_fcat-coltext    = 'Material Number'.
  ls_fcat-fieldname  = 'MATNR'.
  ls_fcat-ref_table  = 'I_ALV'.
  ls_fcat-outputlen  = '18'.
  ls_fcat-col_pos    = 1.
  append ls_fcat to fieldcat.
  clear: ls_fcat.
  ls_fcat-reptext    = 'Material Description'.
  ls_fcat-coltext    = 'Material Description'.
  ls_fcat-fieldname  = 'MAKTX'.
  ls_fcat-ref_table  = 'I_ALV'.
  ls_fcat-outputlen  = '40'.
  ls_fcat-col_pos    = 2.
  append ls_fcat to fieldcat.
endform.
Of course, I must recommend that you use the new ALV Object Model as Uwe has suggested.  If you are on a NetWeaver release, then it is available to you.
Regards,
RIch Heilman