Output of two ALV lists in background

Question

HI ALV experts,
[Soory I just saw that I posted this yesterday with a wrong subject]
I'm currently working with an existing reports which is quite complex. The report creates an ALV grid and uses a couple of write statements to create some statistics.
Running the report, we get the ALV grid. Then using BACK/F3 we leave the grid and get the list showing statistics.
I would like to create an ALV for the statistics. This works fine online: After leaving the grid the statistics ALV is started. But in background, I got just one list.
I tried this sample:
FORM batchtest .
  DATA:
    lr_data TYPE REF TO data,
    lo_salv TYPE REF TO cl_salv_table.
  FIELD-SYMBOLS:
    <table>  TYPE table.
* dynamic table fpr T000
  CREATE DATA lr_data TYPE TABLE OF t000.
  ASSIGN lr_data->* TO <table>.
  SELECT * INTO TABLE <table> FROM t000.
* show table in grid
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      i_structure_name = 'T000'
    TABLES
      t_outtab         = <table>
    EXCEPTIONS
      program_error    = 1
      OTHERS           = 2.
  IF sy-subrc  0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
* create another table
  TRY.
      CREATE DATA lr_data TYPE TABLE OF t100.
      ASSIGN lr_data->* TO <table>.
      SELECT * INTO TABLE <table> FROM t100 UP TO 100 ROWS.
      cl_salv_table=>factory(
        EXPORTING
          list_display   = if_salv_c_bool_sap=>true
        IMPORTING
          r_salv_table   = lo_salv
        CHANGING
          t_table        = <table> ).
* display list
      lo_salv->display( ).
    CATCH cx_salv_msg .
      ASSERT 1 = 2.
  ENDTRY.
ENDFORM.                    " BATCHTEST
Online, it works fine. In batch, I get only the second table as list. If I exit after calling FUNCTION 'REUSE_ALV_GRID_DISPLAY', I get the first list only. How to get both lists printed in sequence? I will not use ALV block list display, because this would mean major restructuring of the program and no grid online. SUBMIT ist no good idea as well.
Thanks in advance
Regards
Clemens

Answer 1

Hi
The option is in layout structure adn has to be set in the next ALV function called, so if the program works in background mode it can call REUSE_ALV_LIST_DISPLAY instaed of CL_SALV_TABLE.
The call can be place in the END_OF_LIST event of ALV:
TYPE-POOLS: SLIS.
PERFORM BATCHTEST.
FORM BATCHTEST .
  DATA:
    LR_DATA TYPE REF TO DATA,
    LO_SALV TYPE REF TO CL_SALV_TABLE.
  FIELD-SYMBOLS:
    <TABLE>  TYPE TABLE.
  DATA: T_EVENTS TYPE SLIS_T_EVENT WITH HEADER LINE.
  DATA: L_PRINT  TYPE SLIS_PRINT_ALV.
  DATA: L_REPORT TYPE SY-REPID.
* dynamic table fpr T000
  CREATE DATA LR_DATA TYPE TABLE OF T000.
  ASSIGN LR_DATA->* TO <TABLE>.
  SELECT * INTO TABLE <TABLE> FROM T000.
  IF SY-BATCH = 'X'.
* In background only
    L_PRINT-PRINT              = 'X'. "Print ALV
    L_PRINT-NO_PRINT_LISTINFOS = 'X'.
    T_EVENTS-NAME = 'END_OF_LIST'.    "Call event
    T_EVENTS-FORM = 'END_OF_LIST'.
    APPEND T_EVENTS.
  ENDIF.
  L_REPORT = SY-REPID.
* show table in grid
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
    EXPORTING
      I_CALLBACK_PROGRAM = L_REPORT
      I_STRUCTURE_NAME   = 'T000'
      IT_EVENTS          = T_EVENTS[]
      IS_PRINT           = L_PRINT
    TABLES
      T_OUTTAB           = <TABLE>
    EXCEPTIONS
      PROGRAM_ERROR      = 1
      OTHERS             = 2.
  IF SY-SUBRC  NE 0.
    MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
  CHECK SY-BATCH IS INITIAL.
* The form for the nex ALV is called by event END_OF_LIST if the
* program works in background   
  PERFORM NEXT_LIST.
ENDFORM.                    " BATCHTEST
FORM NEXT_LIST .
  DATA:
    LR_DATA TYPE REF TO DATA,
    LO_SALV TYPE REF TO CL_SALV_TABLE.
  FIELD-SYMBOLS:
    <TABLE>  TYPE TABLE.
  DATA: LT_LAYOUT TYPE SLIS_LAYOUT_ALV.
* create another table
  TRY.
      CREATE DATA LR_DATA TYPE TABLE OF T100.
      ASSIGN LR_DATA->* TO <TABLE>.
      SELECT * INTO TABLE <TABLE> FROM T100 UP TO 100 ROWS.
      IF SY-BATCH IS INITIAL. "Online
        CL_SALV_TABLE=>FACTORY(
          EXPORTING
            LIST_DISPLAY   = IF_SALV_C_BOOL_SAP=>TRUE
          IMPORTING
            R_SALV_TABLE   = LO_SALV
          CHANGING
            T_TABLE        = <TABLE> ).
* display list
        LO_SALV->DISPLAY( ).
      ELSE.                   "In background
        LT_LAYOUT-LIST_APPEND = 'X'. "Append new ALV list
        CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
          EXPORTING
            I_STRUCTURE_NAME = 'T100'
            IS_LAYOUT        = LT_LAYOUT
          TABLES
            T_OUTTAB         = <TABLE>
          EXCEPTIONS
            PROGRAM_ERROR    = 1
            OTHERS           = 2.
        IF SY-SUBRC  NE 0.
          MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
                  WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
        ENDIF.
      ENDIF.
    CATCH CX_SALV_MSG .
      ASSERT 1 = 2.
  ENDTRY.
ENDFORM.                    " NEXT_LIST
FORM END_OF_LIST.
  PERFORM NEXT_LIST.
ENDFORM.                    "END_OF_LIST
Max