Own F4 for one field in ALV-OO

Question

Hi,
i try to create an own F4 for a specific field in my ALV-OO.
I do it like this:
CLASS LCL_EVENT_HANDLER DEFINITION .
  PUBLIC SECTION .
    METHODS:
   HANDLE_ONF4
         FOR EVENT ONF4 OF CL_GUI_ALV_GRID
         IMPORTING E_FIELDNAME
                   E_FIELDVALUE
                   ES_ROW_NO,
CLASS LCL_EVENT_HANDLER IMPLEMENTATION .
  METHOD HANDLE_ONF4.
    PERFORM HANDLE_ONF4 USING E_FIELDNAME
                              E_FIELDVALUE
                              ES_ROW_NO.
  ENDMETHOD.
  GR_EVENT_HANDLER->HANDLE_ONF4               FOR GR_ALVGRID.
  SET HANDLER
  CALL METHOD GR_ALVGRID->SET_TABLE_FOR_FIRST_DISPLAY
    EXPORTING
      IT_TOOLBAR_EXCLUDING = GT_EXCLUDE
FORM HANDLE_ONF4 USING E_FIELDNAME E_FIELDVALUE ES_ROW_NO.
  BREAK-POINT.
ENDFORM.
My problem is, that the break-point will not be reached. Has anyone an ides what mistake i do.
Have i to set anything in fieldcat?
Thanks.
Regards, Dieter

Answer 1

Hi Dieter,
modify according to your needs:
Look at ... * loop once and append F4 result to event reference table
METHOD handle_f4.
* Importing VALUE( E_FIELDNAME )    TYPE LVC_FNAME  OPTIONAL  Feldname
* Importing VALUE( E_FIELDVALUE )   TYPE LVC_VALUE  OPTIONAL  ALV-Control: Zelleninhalt
* Importing VALUE( ES_ROW_NO )      TYPE LVC_S_ROID OPTIONAL  Zeilen ID
* Importing VALUE( ER_EVENT_DATA )  TYPE REF TO CL_ALV_EVENT_DATA OPTIONAL  Event Daten
* Importing VALUE( ET_BAD_CELLS )   TYPE LVC_T_MODI OPTIONAL  Fehlerhafte Zellen
* Importing VALUE( E_DISPLAY )      TYPE CHAR01     OPTIONAL  Display only
  DATA:
    lt_return_tab TYPE TABLE OF ddshretval,
    lr_dat        TYPE REF TO data,
    lv_tabname    TYPE tabname,
    lv_fieldname  TYPE fieldname,
    lv_field TYPE scrfname.
  FIELD-SYMBOLS:
    <dat> TYPE ANY,
    <tab> TYPE table,
    <rec> TYPE ANY,
    <col> TYPE ANY,
    <tbn> TYPE ANY,
    <ret> TYPE ddshretval,
    <mod> TYPE LINE OF lvc_t_modi,
    <tmd> TYPE lvc_t_modi.
*  use grid table currently displayed
  ASSIGN:
    mr_tabref->* TO <tab>.
* position at field where F4 was pressed
  READ TABLE <tab> INDEX es_row_no-row_id ASSIGNING <rec>.
* get table and field name of value inquestion
  IF e_fieldname = mc_fieldname_value_new.
    ASSIGN COMPONENT:
      'TABNAME'   OF STRUCTURE  <rec> TO <tbn>,
      'FIELDNAME' OF STRUCTURE  <rec> TO <col>.
  ELSEIF e_fieldname = mc_fieldname_value_new2.
    ASSIGN COMPONENT:
      'TABNAME2'   OF STRUCTURE  <rec> TO <tbn>,
      'FIELDNAME2' OF STRUCTURE  <rec> TO <col>.
  ENDIF.
  lv_tabname = <tbn>.
  lv_fieldname = <col>.
* call default F4
  CALL FUNCTION 'F4IF_FIELD_VALUE_REQUEST'
    EXPORTING
      tabname    = lv_tabname
      fieldname  = lv_fieldname
    TABLES
      return_tab = lt_return_tab
    EXCEPTIONS
      OTHERS     = 5.
  IF sy-subrc = 0.
* use table refernece in event object
    ASSIGN er_event_data->m_data->* TO <tmd>.
* loop once and append F4 result to event reference table
    LOOP AT lt_return_tab ASSIGNING <ret>.
      APPEND INITIAL LINE TO <tmd> ASSIGNING <mod>.
      <mod>-row_id              = es_row_no-row_id.
      <mod>-fieldname           = e_fieldname.
      <mod>-value               = <ret>-fieldval.
    ENDLOOP.
    er_event_data->m_event_handled = abap_true.
  ENDIF.
* if er_event_data->m_event_handled is not set to abap_true, system will handle it.
* In this context the message 'Keine Eingabehilfe verfügbar' will be displayed
ENDMETHOD.
Regards,
Clemens