Problem in XSL mapping with leading zero's

Question

Hi ,
i am facing a problem in disigning a XSL mapping where one of the source field (type string ) ,and I need to remove the leading zero's to map it to target.
we have format-numer ,but It is not working in this case ,may be because of type string.
and the replace command is not supported .
So can any one suggest me some way to resolve this xsl problem.
Thanks,
Raju.

Answer 1

I write an example
xsl file:
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
     <xsl:template match="/">
          <doc>
               <xsl:apply-templates/>
          </doc>
     </xsl:template>
     <xsl:template match="source_field">
          <source_field>
               <xsl:call-template name="remove_leading_zeros">
                    <xsl:with-param name="value" select="."/>
               </xsl:call-template>
          </source_field>
     </xsl:template>
     <xsl:template name="remove_leading_zeros">
          <xsl:param name="value"/>
          <xsl:choose>
               <xsl:when test="starts-with($value, '0')">
                    <xsl:call-template name="remove_leading_zeros">
                         <xsl:with-param name="value" select="substring($value, 2)"/>
                    </xsl:call-template>
               </xsl:when>
               <xsl:otherwise>
                    <xsl:value-of select="$value"/>
               </xsl:otherwise>
          </xsl:choose>
     </xsl:template>
</xsl:stylesheet>
to test:
input xml:
<?xml version="1.0" encoding="UTF-8"?>
<doc>
<source_field>000000123456</source_field>
<source_field>0987654</source_field>
</doc>
output xml:
<?xml version="1.0" encoding="UTF-8"?>
<doc xmlns:fo="http://www.w3.org/1999/XSL/Format">
     <source_field>123456</source_field>
     <source_field>987654</source_field>
</doc>
hope can help you.
regards
Bin