Problems with AppleScript and MS Office 2011

Question

The script below used to work great for converting MS Word files to PDF files.  However, sometime during the last few months it has stopped working and will no longer compile without error.  Possibly after upgrading to Mavericks but I'm not exactly sure when it stopped working, could have been an update to Office.  Anyway, the error I'm getting when I compile is a Syntax Error, "Expected end of line but found class name".  The editor highlights "document" in the line "set the_doc to active document".  I'm not very familiar with Applescript but I have opened the scripting dictionary for Microsoft Word in the Applescript editor and I do see "active document" as a property of the "document" object.  So why doesn't the compiler recognize it?  Am I missing something obvious or was there some sort of change in Mavericks that broke this functionality?
I've been pulling my hair out trying to get this script working again  but I have not had any luck.  I've tried uninstalling and reinstalling Microsoft Office per instructions from Microsoft.  I have all the latest updates and patches. Any help would be greatly appreciated.
Here is the original code which used to work just fine.
-- Stephen Norum
-- [email protected]
property pdf_ext : ".pdf"
on remove_extension(file_path)
    -- remove the extension if it exists
    set stripped to do shell script ("F=" & quoted form of file_path & " ; echo ${F%.*}")
    return stripped
end remove_extension
on get_pdf_path(doc_path)
    set doc_path to remove_extension(doc_path)
    -- Try the simple name first
    set pdf_path to (doc_path & pdf_ext)
    -- Otherwise, number the pdfs
    set counter to 1
    tell application "Finder"
        repeat while (exists pdf_path)
            set pdf_path to (doc_path & " " & counter & pdf_ext)
            set counter to counter + 1
        end repeat
    end tell
    return pdf_path
end get_pdf_path
on run {input, parameters}
    repeat with file_name in input
        tell application "Microsoft Word"
            open file_name
            set the_doc to active document
            set doc_path to path of the_doc
        end tell
        set pdf_path to get_pdf_path(doc_path)
        tell application "Microsoft Word"
            save as active document file name pdf_path file format format PDF
            close active document
        end tell
    end repeat
    tell application "Finder"
        activate
    end tell
    return input
end run

Answer 1

try this syntax:
                    tell application "Microsoft Word"
  save as (active document) file name pdf_path file format PDF
                    end tell
Apparently they changed the enumeration label from format PDF to just plain old PDF without bothering to update the scripting dictionary or ensure backward compatibility. If you want to know how they managed to do that, they are still not using sdef or even scriptSuite xml files, but are loading the scripting information from old-school (i.e. os 8 or os 9 style) resource files.
I've occasionally considered writing Microsoft a proposal to redo the Office scripting dictionaries so they are less crazy-making, but I'm not sure I'd survive the attempt.