Procedure that return record problem

Question

we have two table named comp and branch
comp table has two columns
canme caddress
sun hyd
honeywell banglore
microsoft bomaby
barnch table has two columns
bname baddress
sun1 pune
honeywell1 hyd
microsoft bnaglore
now i am using below code.if i enter 1 then i have to get all company records.if i enter 2 then i have to get all branch records
CREATE OR REPLACE PACKAGE reftest
IS
TYPE my_rec IS RECORD
(name comp.CNAME%type,
          address comp.CADDRESS%type
          type ref_cur is ref cursor;
          PROCEDURE test(P_no in number,
          cur_o OUT my_rec);
          end;
CREATE OR REPLACE PACKAGE body reftest
as
PROCEDURE test(P_no in number,cur_o OUT my_rec)
          as
refvar     ref_cur;
my_rec_var my_rec;
myexc exception;
begin
if P_no =1 then
open refvar for
select CNAME, CADDRESS from comp;
elsif p_no =2 then
open refvar for
select bname,baddress from BARNCH;
else
RAISE myexc;
END IF;
loop
if P_no =1then
fetch refvar into my_rec_var ;
exit when refvar%notfound;
elsif P_no =2then
fetch refvar into my_rec_var ;
exit when refvar%notfound;
--insert into temp_tab(roomid,description) values(v_roomid,v_description);
end if;
end loop;
close refvar;
cur_o :=my_rec_var ;
commit;
exception
when myexc then
raise_application_error(20991,'input must be 1 or 2');
end ;
end reftest;
by excuting this using below
DECLARE
P_NO NUMBER;
CUR_O REFTEST.my_rec;
BEGIN
P_NO := 1;
ORA10GV2.REFTEST.TEST ( P_NO, CUR_O );
dbms_output.put_line(CUR_O .name||' '||CUR_O .address);
END;
i have to get all company records but i am getting only one recordas o/p
how to get all records of company

Answer 1

Another option would be to use a pipelined function and effectively return the results as if it were a table. This of course relies on the resultant data from the different queries being of the same structure and type...
e.g.
SQL> CREATE OR REPLACE TYPE num_descript AS OBJECT(num number, descript varchar2(30))
  2  /
Type created.
SQL>
SQL> CREATE OR REPLACE TYPE tbl_num_descript AS TABLE OF num_descript
  2  /
Type created.
SQL>
SQL>
SQL> CREATE OR REPLACE PACKAGE reftest AS
  2    FUNCTION pipedata(p_choice number) RETURN tbl_num_descript PIPELINED;
  3  END;
  4  /
Package created.
SQL>
SQL> CREATE OR REPLACE PACKAGE BODY reftest AS
  2    FUNCTION pipedata(p_choice number) RETURN tbl_num_descript PIPELINED IS
  3      v_obj num_descript := num_descript(NULL,NULL);
  4      v_rc  sys_refcursor;
  5    BEGIN
  6      IF p_choice = 1 THEN
  7        OPEN v_rc FOR SELECT empno as num, ename as descript FROM emp;
  8      ELSIF p_choice = 2 THEN
  9        OPEN v_rc FOR SELECT deptno as num, dname as descript FROM dept;
10      END IF;
11      LOOP
12        FETCH v_rc INTO v_obj.num, v_obj.descript;
13        EXIT WHEN v_rc%NOTFOUND;
14        PIPE ROW(v_obj);
15      END LOOP;
16      CLOSE v_rc;
17      RETURN;
18    END;
19  END;
20  /
Package body created.
SQL> select * from table(reftest.pipedata(1));
       NUM DESCRIPT
      7369 SMITH
      7499 ALLEN
      7521 WARD
      7566 JONES
      7654 MARTIN
      7698 BLAKE
      7782 CLARK
      7788 SCOTT
      7839 KING
      7844 TURNER
      7876 ADAMS
      7900 JAMES
      7902 FORD
      7934 MILLER
14 rows selected.
SQL> select * from table(reftest.pipedata(2));
       NUM DESCRIPT
        10 ACCOUNTING
        20 RESEARCH
        30 SALES
        40 OPERATIONS
SQL>