Referring to Cursor Row and Column in Dynamic SQL

Question

I have a procedure that dynamically reads a schema name and table name from an input table. The code then needs to loop through all rows and columns of each table and output the data. I'm 95% done with what I want to accomplish, but there is one small bug. The line dbms_output.put(*col.column_name* || '',''); ' ||
should refer to something like rec.col.column_name so that it gets the column of the current record. Right now it just displays the column name for each record instead of the actual value. Can anyone help me tweak the code to get the actual value?
CREATE OR REPLACE PACKAGE BODY some_proc IS
-- Function and procedure implementations
PROCEDURE create_files IS
CURSOR c_tbls IS
SELECT * FROM tbl_list;
l_sql VARCHAR2(4000);
BEGIN
--Loop through all tables
FOR tbl IN c_tbls LOOP
l_sql := 'DECLARE ' || ' CURSOR c_tbl_recs IS ' || ' SELECT * ' ||
' FROM ' || tbl.schema_name || '.' || tbl.table_name || '; ' ||
' t_tbl_rowtype c_tbl_recs%ROWTYPE; ' || 'BEGIN ' ||
' FOR rec IN c_tbl_recs LOOP ' ||
' FOR col IN (SELECT column_name ' ||
' FROM dba_tab_cols ' ||
' WHERE owner = ''' || tbl.schema_name || '''' ||
' AND table_name = ''' || tbl.table_name || '''' ||
' ORDER BY column_id) LOOP ' ||
*' dbms_output.put(col.column_name || '',''); ' ||* ' END LOOP; dbms_output.put_line(''''); END LOOP; ' ||
'END; ';
--dbms_output.put_line(l_sql);
EXECUTE IMMEDIATE l_sql;
END LOOP;
EXCEPTION
WHEN OTHERS THEN
dbms_output.put_line(SQLERRM);
END;
END;

Answer 1

Is it this what you are looking for?
(it took some minutes)
create or replace
package some_proc is
procedure create_files;
end;
CREATE OR REPLACE
PACKAGE BODY some_proc
IS
  -- Function and procedure implementations
PROCEDURE create_files
IS
  CURSOR c_tbls
  IS
    SELECT * FROM tbl_list;
  CURSOR c_cols (p_table_owner VARCHAR2, p_table_name VARCHAR2)
  IS
    SELECT column_name
    FROM all_tab_columns
    WHERE owner   =p_table_owner
    AND table_name=p_table_name
    ORDER BY all_tab_columns.column_id;
  l_sql     VARCHAR2(32000);
  separator VARCHAR2(1):=';';
BEGIN
  --Loop through all tables
  FOR tbl IN c_tbls
  LOOP
    dbms_output.put_line('TABLE: '||tbl.schema_name||'.'||tbl.table_name);
    l_sql := 'DECLARE ' ;
    l_sql := l_sql|| '  CURSOR c_tbl_recs IS ' ;
    l_sql := l_sql||'    SELECT * FROM ' || tbl.schema_name || '.' || tbl.table_name || '; ' ;
    l_sql := l_sql||'    linenr number:=1; ';
    l_sql := l_sql||'BEGIN ' ;
    l_sql := l_sql|| ' FOR rec IN c_tbl_recs LOOP ';
    FOR c IN c_cols(tbl.schema_name,tbl.table_name)
    LOOP
      l_sql:=l_sql ||' if linenr=1 then  dbms_output.put('''||c.column_name||''||separator||'''); end if; ' ;
    END LOOP;
    l_sql :=l_sql||'  dbms_output.put_line(''''); linenr:=linenr+1; ';
    FOR c IN c_cols(tbl.schema_name,tbl.table_name)
    LOOP
      l_sql:=l_sql ||' dbms_output.put(rec.'||c.column_name||'||'''||separator||'''); ' ;
    END LOOP;
    l_sql:=l_sql||'  end loop; ';
    l_sql:=l_sql||'  dbms_output.put_line(''''); ';
    l_sql:=l_sql||'  dbms_output.put_line(''''); ';
    l_sql:=l_sql||'end;';
    EXECUTE IMMEDIATE l_sql;
  END LOOP;
EXCEPTION
WHEN OTHERS THEN
  dbms_output.put_line(SQLERRM);
END;
END;
/