Regd:- Execute Immediate

Question

HI,
WHEN I EXECUTE THE BELOW QUERY I get PLSQL /Numeric or value error. Suggestions are welcome.
DECLARE
CURSOR c1
IS
SELECT object_name, object_type, owner
FROM all_objects
WHERE object_type IN ('PACKAGE')
AND object_name = 'PKG_UPLOAD'
AND owner = 'TEST';
lv_v_header VARCHAR2 (2000) := 'SELECT DBMS_METADATA.GET_DDL( ';
lv_v_footer VARCHAR2 (200) := ' )FROM DUAL';
lv_v_object_type all_objects.object_type%TYPE;
lv_v_object_name all_objects.object_name%TYPE;
lv_v_owner all_objects.owner%TYPE;
lv_v_stmt VARCHAR2 (4000);
lv_v_quotes VARCHAR2 (100) := '''';
lv_v_comma VARCHAR2 (100) := ',';
lv_v_value VARCHAR2 (32767);
filehandler UTL_FILE.file_type;
lv_v_file_name VARCHAR2 (3000);
BEGIN
FOR i IN c1
LOOP
BEGIN
lv_v_file_name :=
i.owner
|| '_'
|| i.object_name
|| CASE
WHEN i.object_type = 'PACKAGE'
THEN '.PKB'
WHEN i.object_type = 'TRIGGER'
THEN '.TRG'
END;
lv_v_object_type := i.object_type;
lv_v_object_name := i.object_name;
lv_v_owner := i.owner;
lv_v_stmt :=
lv_v_header
|| lv_v_quotes
|| lv_v_object_type
|| lv_v_quotes
|| lv_v_comma
|| lv_v_quotes
|| lv_v_object_name
|| lv_v_quotes
|| lv_v_comma
|| lv_v_quotes
|| lv_v_owner
|| lv_v_quotes
|| lv_v_footer;
EXECUTE IMMEDIATE lv_v_stmt
INTO lv_v_value;
filehandler := UTL_FILE.fopen ('TEST_DIR', lv_v_file_name, 'w');
UTL_FILE.putf (filehandler, lv_v_value||'\n');
UTL_FILE.fclose (filehandler);
END;
END LOOP;
END;
/

Answer 1

In case you need help to use UTL_FILE, then here it is.
SQL> DECLARE
  2    myddl clob;
  3    fname VARCHAR2(200);
  4    extn VARCHAR2(200);
  5 
  6  /* Main function to get the DDls with DBMS_METADATA */ 
  7    FUNCTION get_metadata(pi_obj_name  dba_objects.object_name%TYPE,
  8                          pi_obj_type  IN dba_objects.object_type%TYPE,
  9                          pi_obj_owner IN dba_objects.owner%TYPE) RETURN clob IS
10      h   number;
11      th  number;
12      doc clob;
13    BEGIN
14      h := DBMS_METADATA.open(pi_obj_type);
15      DBMS_METADATA.set_filter(h, 'SCHEMA', pi_obj_owner);
16      DBMS_METADATA.set_filter(h, 'NAME', pi_obj_name);
17      th := DBMS_METADATA.add_transform(h, 'MODIFY');
18      th := DBMS_METADATA.add_transform(h, 'DDL');
19      --DBMS_METADATA.set_transform_param(th,'SEGMENT_ATTRIBUTES',false);
20      doc := DBMS_METADATA.fetch_clob(h);
21      DBMS_METADATA.CLOSE(h);
22      RETURN doc;
23    END get_metadata;
24 
25  ---Writing the CLOB using UTL_FILE
26  PROCEDURE write_clob(p_clob in clob, pi_fname VARCHAR2) as
27      l_offset number default 1;
28      fhandle UTL_FILE.file_type;
29      buffer VARCHAR2(4000);
30    BEGIN
31      fhandle:=UTL_FILE.fopen('SAUBHIK',pi_fname,'A');
32      loop
33        exit when l_offset > dbms_lob.getlength(p_clob);
34        buffer:=dbms_lob.substr(p_clob, 255, l_offset);
35        UTL_FILE.put_line(fhandle,buffer);
36        l_offset := l_offset + 255;
37        buffer:=NULL;
38      end loop;
39      UTL_FILE.fclose(fhandle);
40    END write_clob; 
41 
42  ---Main execution begins. 
43  BEGIN
44    FOR i in (SELECT object_name, object_type, owner
45                FROM dba_objects
46               WHERE owner IN ('SCOTT', 'HR')
47                 AND object_type IN ('PACKAGE', 'TRIGGER')) LOOP
48      --Calling the function.              
49      myddl := get_metadata(i.object_name,i.object_type,i.owner);
50      --Preparing the filename.
51      fname := i.owner||i.object_name || '.' ||
52               CASE WHEN i.object_type='PACKAGE' THEN 'pkb'
53               ELSE 'trg'
54               END;
55     --Writing the file using UTL_FILE.
56      write_clob(myddl,fname);
57    END LOOP;
58  END;
59  /
PL/SQL procedure successfully completed.
SQL> also, about your error, "EXECUTE IMMEDIATE lv_v_stmt INTO lv_v_value;" DBMS_METADATA.get_dll returns a CLOB.