Return more than one row to display as text?

Question

I don't know if this is possible or not. I'd rather not create a report for one item.
is there a way to allow a display as text filed show more than one item from a query? I've tryed several things none work. I have one field that I'd like to show multiple data as just text. but everything I try displays one row only in the field. is there a way around this?

Answer 1

Nazdev,
If you're trying to display multiple records as separate parts (not just concatenated together), the easiest solution would be a report. If you just want to append values together and present them in a single item, you should be able to create a query to build your string pretty easily, though you might need to write an Oracle function to do the concatenation for you.
I wrote a function to do that a while back, obvious you should check it thoroughly before you use it.
CREATE OR REPLACE FUNCTION cursor_to_list(cur_in IN aeo_misc_tools.string_ref_cur,
                                          delimiter_in IN VARCHAR2 := ', ',
                                          max_len_in IN PLS_INTEGER := 32000,
                                          more_string_in IN VARCHAR2 := 'More...') RETURN VARCHAR2 IS
        Description:    Given single-column ref cursor, return values separated
                        by delimiter parameter value.
                        Trim last trailing delimiter.
        Parameters:     cur_in - opened cursor w/ single string column
                        delimiter_in - separate values w/ this, defaults to comma-space
                        max_len_in - maximum returned length
                        more_string_in - Append if length would be longer than max_len_in
        Returns:        String of separated values
        Author:         Stew Stryker
        Usage:          children_list := cursor_to_list(cur_in => child_cur, delimiter_in => ' | ');
        Note: Can also pass a cursor to this directly, using the CURSOR clause, as follows:
        children_list := cursor_to_list(CURSOR(SELECT pref_mail_name FROM children
                                            WHERE parent_id = '0000055555' ORDER BY dob),
                            delimiter_in => ' | ');
    TYPE single_string_rec_t IS RECORD(
        string_val VARCHAR2(256));
    TYPE string_ref_cur IS REF CURSOR;
    row_value single_string_rec_t;
    ret_list VARCHAR2(32000);
    more_string VARCHAR2(256) := NVL(more_string_in, ' ');
    delim_len CONSTANT PLS_INTEGER := LENGTH(delimiter_in);
    more_len CONSTANT PLS_INTEGER := LENGTH(more_string_in);
    max_len PLS_INTEGER := max_len_in - more_len - delim_len;
BEGIN
    IF max_len > 0
    THEN
        IF cur_in%ISOPEN
        THEN
            FETCH cur_in
                INTO row_value;
            WHILE cur_in%FOUND
            LOOP
                IF NVL(LENGTH(ret_list), 0) + NVL(LENGTH(row_value.string_val), 0) + delim_len <=
                   max_len
                THEN
                    ret_list := ret_list || row_value.string_val || delimiter_in;
                ELSIF INSTR(NVL(ret_list, ' '), more_string) = 0
                      AND NVL(LENGTH(row_value.string_val), 0) > 0
                THEN
                    ret_list := ret_list || more_string;
                END IF;
                FETCH cur_in
                    INTO row_value;
            END LOOP;
            -- Strip last delimiter
            ret_list := RTRIM(ret_list, delimiter_in);
            CLOSE cur_in;
        END IF;
    END IF;
    RETURN ret_list;
EXCEPTION
    WHEN no_data_found THEN
        RETURN ret_list;
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE('EXCEPTION IN aeo_misc_tools.cursor_to_list - ' || TO_CHAR(SQLCODE) || ': ' ||
                             SQLERRM);
        RAISE;
        RETURN ret_list;
END cursor_to_list;Good luck,
Stew