REUSE_ALV_GRID_DISPLAY - layout variant

Question

Hi all
I am working with REUSE_ALV_GRID_DISPLAY function module. For layout variant I using the below code
parameters: variant LIKE disvariant-variant.
* POV for Layout
at selection-screen on value-request for variant.
g_save = 'A'.
clear g_variant.
g_variant-report = sy-repid.
gx_variant = g_variant.
  CALL FUNCTION 'REUSE_ALV_VARIANT_DEFAULT_GET'
       EXPORTING
            I_SAVE     = g_save
       CHANGING
            CS_VARIANT = gx_variant
       EXCEPTIONS
            NOT_FOUND  = 2.
  IF SY-SUBRC = 0.
    variant = gx_variant-variant.
  ENDIF.
  CALL FUNCTION 'REUSE_ALV_VARIANT_F4'
       EXPORTING
            IS_VARIANT          = g_variant
            I_SAVE              = g_save
       IMPORTING
            E_EXIT              = g_exit
            ES_VARIANT          = gx_variant
       EXCEPTIONS
            NOT_FOUND = 2.
  IF SY-SUBRC = 2.
    MESSAGE ID SY-MSGID TYPE 'S'      NUMBER SY-MSGNO
            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ELSE.
    IF g_exit = SPACE.
      variant = gx_variant-variant.
    ENDIF.
  ENDIF.
Everything is working well right now. I have two layouts saved. But my question is when I execute my report I want to see one of the saved layout by default in my 'variant' at selection screen.
How can I do this? PLease help. Waiting......

Answer 1

Here is some modified code.  Notice here that I have added another event.  AT SELECTION-SCREEN OUTPUT.  If you have a default variant defined, it will now show up in the screen.
report  zrich_0003.
data: g_save type c value 'X'.
data: g_variant type disvariant.
data: gx_variant type disvariant.
data: g_exit type c.
data: ispfli type table of spfli.
parameters: variant like disvariant-variant.
at selection-screen output.
check variant is initial.
  gx_variant-report = sy-repid.
  call function 'REUSE_ALV_VARIANT_DEFAULT_GET'
*    exporting
*      i_save     = g_save
    changing
      cs_variant = gx_variant
    exceptions
      not_found  = 2.
  if sy-subrc = 0.
    variant = gx_variant-variant.
  endif.
* POV for Layout
at selection-screen on value-request for variant.
  g_save = 'A'.
   clear g_variant.
   g_variant-report = sy-repid.
*  gx_variant = g_variant.
  call function 'REUSE_ALV_VARIANT_F4'
    exporting
      is_variant = g_variant
      i_save     = g_save
    importing
      e_exit     = g_exit
      es_variant = gx_variant
    exceptions
      not_found  = 2.
  if sy-subrc = 2.
    message id sy-msgid type 'S'      number sy-msgno
            with sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  else.
    if g_exit = space.
      variant = gx_variant-variant.
    endif.
  endif.
start-of-selection.
  select * into table ispfli from spfli.
  g_variant-report  = sy-repid.
  g_variant-variant = variant.
  call function 'REUSE_ALV_GRID_DISPLAY'
    exporting
      i_structure_name                  = 'SPFLI'
      i_save                            = g_save
      is_variant                        = g_variant
     tables
      t_outtab                          = ispfli
*   EXCEPTIONS
*     PROGRAM_ERROR                     = 1
*     OTHERS                            = 2
REgards,
Rich Heilman