Selecting a Graphic Layer with Apple Script

Question

I'm trying to build on a very helpful post by sstanleyau showing how to choose different layers in a placed PSD or PDF. Unfortunately, I'm stuck in my test script. It seems so simple …
Here's what the script should do after an image is placed in a text frame:
1. "Read" the names of each of the graphic layers in the placed graphic.
2. If one of the names contains a string, then
3. Turn current visibility of that layer on
4. Turn the visibility of every other layer off.
However, my script seems to come up with a different result each time I run it and often fails to "find" a layer that I know is there. Is it possible that my script can't access the name of a graphic layer if its visibility is set to off?
Here's why I've got
--before running, user selects a test frame containing a placed PDF with multiple layers named blue, red and green.
tell application "Adobe InDesign CS4"
set theFrame to item 1 of selection
set glOptions to graphic layer options of graphic 1 of theFrame
set theName to text of "blue"
repeat with z from 1 to count of graphic layers in glOptions
if name of graphic layer z of glOptions contains theName then
repeat with d from 1 to count of graphic layers in glOptions
if current visibility of graphic layer d of glOptions ≠ false then
set current visibility of graphic layer d of glOptions to false
end if
end repeat
if current visibility of graphic layer d of glOptions = false then
set current visibility of graphic layer z of glOptions to true
end if
end if
end repeat
end tell

Answer 1

Im NOT sure if you have just made this a little over complicated… This works just fine for me. Tested with about a dozen psd layers…
tell application "Adobe InDesign CS2"
tell active document
tell rectangle 1
tell graphic 1
tell graphic layer options
set GLC to count of graphic layers
repeat with i from 1 to GLC
if name of graphic layer i ≠ "Blue" then
set current visibility of graphic layer i to false
else
set current visibility of graphic layer i to true
end if
end repeat
end tell
end tell
end tell
end tell
end tell
This variant also works as I would have expected too… Retaining visibility from a list…
tell application "Adobe InDesign CS2"
tell active document
tell rectangle 1
tell graphic 1
tell graphic layer options
set On_List to {"Red", "Aqua", "Orange"}
set GLC to count of graphic layers
repeat with i from 1 to GLC
if name of graphic layer i is not in On_List then
set current visibility of graphic layer i to false
else
set current visibility of graphic layer i to true
end if
end repeat
end tell
end tell
end tell
end tell
end tell