Selecting and Printing Labels from Database

Question

I have tried to print address labels from a database in which I chose four lines, one of which (a company name) is often blank because there is no information. This line appears as a blank line on the label. Is there a way to eliminate this blank line?
I am also having trouble selecting records to print. Can you suggest where to look to get help?
Thank you.

Answer 1

Hello
Here is a script I passed last year about this kind of problem.
I hope that embedded comments would be sufficient because at this time, I am unable to work on such a script.
--[SCRIPT DB calcToSlideGUI v6]
Ce script récupère dans un champ une valeur calculée
et la dépose dans un champ texte classique.
Cela permet de bénéficier du retour à la ligne automatique
indisponible pour les champs calculés.
Si un champ contient des pseudo returns consécutifs,
ils sont remplacés par un unique pseudo return.
Si un champ contient des pseudo espaces consécutifs,
ils sont remplacés par un unique espace.
La fonction Chercher-Remplacer est utilisée
pour remplacer ces pseudo return par de VRAIS return.
Exemple de formule pour concat-calc
'prénom'&"◊"&'prénom2'&"◊"'nom'&"¶"&'rue1'&"¶"&'rue2'&"¶"&'code'&" "&'city
• This script grab the value calculated in a field
and drop it in a simple text field.
This permit to take benefit of the auto wrap feature
which is unavailable with calculated fields.
If a field contains adjacent pseudo returns,
they are replaced by single ones.
If a field contains adjacent pseudo spaces,
they are replaced by a single space.
The Find-Replace feature is used to replace
these pseudo returns by TRUE ones.
Sample formula for concat-calc:
'firstName'&"◊"&'firstName2'&"◊"&'lastName'&"¶"&'street1'&"¶"&'street2'&"¶"&'co de'&" "&'city'
Yvan KOENIG, Vallauris (FRANCE)
27 août 2004
complété le 31 août
modifié le 5 décembre
modifié le 8 décembre
modifié le 4 février 2005
property champsRequis : {"concat-calc", "concat-text"}
(* les noms des deux rubriques manipulées
vous pouvez modifier ces noms mais PAS leur ordre
• the names of the two used fields
you may change them but don’t change the order of them *)
property french : true (* true = messages français
• false = english messages *)
property fauxReturn : ASCII character 166 -- "¶"
(* use it in the database formula as Return indicator *)
property fauxEspace : ASCII character 215 -- "◊"
(* use it in the database formula as Space indicator *)
property fauxReturn2 : fauxReturn & fauxReturn
property fauxEspace2 : fauxEspace & fauxEspace
property msg0 : "" -- globale
property msg1 : "" -- globale
property msg2 : "" -- globale
property msg4 : "" -- globale
property msg6 : "" -- globale
property msg7 : "" -- globale
property msg71 : "" -- globale
property msg72 : "" -- globale
property msg81 : "" -- globale
property msg82 : "" -- globale
property msg98 : "" -- globale
property msg99 : "" -- globale
on run
try
if msg0 is "" then my prepareMessages()
my controlesDivers()
my modeUtilisation()
my afficheToutes()
my preparation()
set metsReturn to my alimente()
my pourRemplacer(metsReturn)
on error MsgErr number NroErr
if NroErr is not -128 then
beep 2
(* «constant afdregfp» est la forme canonique de frontmost application *)
-- tell application (path to «constant afdregfp» as string)
tell application (path to frontmost application as string)
display dialog "" & NroErr & " : " & MsgErr ¬
buttons {msg99} with icon 0
end tell -- to application
end if
return
end try
end run
-- ================== routines
on controlesDivers()
tell application "AppleWorks 6"
activate
-- Test version
if "6." is not in (version as text) then ¬
error msg0 number 8000
if (count each document) = 0 then ¬
error msg1 number 8001
if (document kind of document 1 ¬
is not database document) then ¬
error msg2 number 8002
select document 1 (* Utile si dialog recherche est au 1er plan
• Useful if the Search dialog is at front *)
end tell -- AppleWorks
end controlesDivers
-- ==================
on modeUtilisation()
tell application "AppleWorks 6"
tell document 1
select menu item 1 of menu 5 (* mode Utilisation¬
• Browse mode *)
end tell -- to document 1
end tell -- to AppleWorks
end modeUtilisation
-- ==================
on afficheToutes()
tell application "AppleWorks 6"
tell document 1
select menu item 1 of menu 6 (* Afficher toutes les fiches
• Show all records *)
end tell -- to document 1
end tell -- to AppleWorks
end afficheToutes
-- =====================
on preparation()
tell application "AppleWorks 6"
tell document 1
if (count of records) = 0 then error msg6 number 8006
set nomsChamps to name of every field
set {missing, msg8} to {0, ""}
set cnt_champsRequis to count of champsRequis
repeat with ky from 1 to cnt_champsRequis
set Rbrq to (item ky of champsRequis)
if Rbrq is not in nomsChamps then
set missing to missing + 1
set msg8 to msg8 & Rbrq & ", "
(* construit une chaîne avec les noms des rubriques absentes
• build a string with the names of missing field(s) *)
end if
end repeat
if missing is not 0 then
(* prépare un beau message d'erreur
• build a pretty error message *)
if missing = 1 then
set msgmiss to msg7 & msg71 & return & ¬
msg8 & msg81
else
set msgmiss to msg7 & msg72 & return & ¬
msg8 & msg82 -- pluriels
end if -- missing = 1
error msgmiss number 8078
end if -- missing is not 0
end tell -- to document 1
end tell -- to AppleWorks
end preparation
-- =====================
on alimente()
tell application "AppleWorks 6"
tell document 1
set {champSource, champDestination} to champsRequis
set metsReturn to false
set nbrec to count of records
repeat with ky from 1 to nbrec
set {champky, mets_Return} to ¬
my slide((value of field champSource of record ky) as text, metsReturn)
set value of field champDestination of record ky to champky
end repeat
end tell -- document 1
end tell -- Aworks
return mets_Return
end alimente
-- =====================
on remplace(Texte, avant, apres)
set AppleScript's text item delimiters to avant
set aListe to (text items of Texte)
set AppleScript's text item delimiters to apres
return (aListe as text)
end remplace
-- =====================
on slide(Texte, mets_Return)
repeat while Texte contains fauxReturn2
set Texte to my remplace(Texte, fauxReturn2, fauxReturn)
end repeat
repeat while Texte contains fauxEspace2
set Texte to my remplace(Texte, fauxEspace2, fauxEspace)
end repeat
if Texte contains fauxEspace then ¬
set Texte to my remplace(Texte, fauxEspace, " ")
set AppleScript's text item delimiters to ""
if Texte contains fauxReturn then set mets_Return to true
return {Texte, mets_Return}
end slide
-- =====================
on pourRemplacer(metsReturn)
if my quelOS() is not less than "1030" then
(* Mac OS X 10.3 ou plus *)
if metsReturn is true then ¬
my chercheRemplaceGUI(fauxReturn, return)
else
error msg4 number 8004
end if -- my quelOS() (GUIdispo)
end pourRemplacer
-- ==================
on chercheRemplaceGUI(avant_, apres_)
beep 2 (* Attire l'attention *)
tell application "AppleWorks 6"
--activate
select document 1
tell document 1
select menu item 1 of menu item 16 of menu 3 (* Rechercher/Remplacer…
• Find/Replace… *)
end tell
set the clipboard to avant_
paste
end tell -- to AppleWorks
tell application "System Events"
if UI elements enabled then
tell process "AppleWorks 6"
keystroke tab
end tell -- to process
else
tell application "System Preferences"
activate
set current pane to ¬
pane "com.apple.preference.universalaccess"
display dialog msg98
end tell -- to System Preferences
end if
end tell -- to System Events
tell application "AppleWorks 6"
set the clipboard to apres_
paste
end tell
tell application "System Events"
tell process "AppleWorks 6"
keystroke tab -- back to field "Search"
end tell -- to process
end tell -- to System Events
end chercheRemplaceGUI
-- =====================
on quelOS()
try
(* «event fndrgstl» = forme canonique de system attribute *)
-- set hexData to «event fndrgstl» "sysv"
set hexData to system attribute "sysv"
set hexString to {}
repeat 4 times
set hexString to ((hexData mod 16) as string) & hexString
set hexData to hexData div 16
end repeat
set OS_version to hexString as string
on error
set OS_version to "0000"
(* retournera "0000" si "system attribute" n'est pas reconnu *)
end try
return OS_version
end quelOS
-- =====================
on prepareMessages()
if french is true then
set msg0 to "Ce script n'est pas compatible" & return & ¬
"avec cette version d‘AppleWorks." & return & ¬
"Veuillez utiliser une version 6.0" & return & ¬
"ou plus récente..."
set msg1 to "Aucun document ouvert"
set msg2 to "Ce document n'est pas une base de données."
set msg4 to "Pensez à remplacer" & return & ¬
"«" & fauxReturn & "» par «\\p»."
set msg6 to "Impossible d’exécuter ce script" & return & ¬
"sur une base vide."
set msg7 to "Désolé, "
set msg71 to "la rubrique:"
set msg72 to "les rubriques:"
set msg81 to "est absente."
set msg82 to "sont absentes."
set msg98 to "Le scriptage des éléments d’interface est désactivé. " & ¬
"Cochez «Activez l’accès pour les périphériques d’aide»"
set msg99 to " Vu "
else
set msg0 to "This script is not compatible" & return & ¬
"with this version of AppleWorks." & return & ¬
"Please use version 6.0" & return & "or higher..."
set msg1 to "No open doc"
set msg2 to "This document is not a database."
set msg4 to "CAUTION, don’t forget to replace" & ¬
"“" & fauxReturn & "” by “\\p."
set msg6 to "Can’t apply this script" & return & ¬
"on an empty DB."
set msg7 to "Oops, the field"
set msg71 to ":"
set msg72 to "s:"
set msg81 to "is missing."
set msg82 to "are missing."
set msg98 to "UI element scripting is not enabled. " & ¬
"Check “Enable access for assistive devices”"
set msg99 to " Oops "
end if
end prepareMessages
--[/SCRIPT]
Yvan KOENIG (from FRANCE jeudi 15 juin 2006 09:07:25)