Selecting only columns from a table

Question

Could someone help me with a SQL query to select all the columns in a table as an array?

Answer 1

Hello
if you are on 9i upward, you can define a pl/sql table of the rowtype and use bulk collect to populate that table, otherwise, you can create separate array types for each column:
create table dt_test_tab (id number, col1 varchar2(10));
insert into dt_test_tab values(1, 'X');
insert into dt_test_tab values(2, 'X');
insert into dt_test_tab values(3, 'X');
insert into dt_test_tab values(4, 'X');
insert into dt_test_tab values(5, 'X');
commit;
declare
    type tt_TestTab is table of dt_test_tab%rowtype index by binary_integer;
    type tt_TestTabid IS TABLE OF dt_test_tab.id%type index by binary_integer;
    type tt_TestTabcol1 IS TABLE OF dt_test_tab.col1%type index by binary_integer;
    lt_TestTab     tt_TestTab;
    lt_Id          tt_TestTabId;
    lt_col1        tt_TestTabcol1;
begin
    --use the rowtype array
    select
         id,
         col1
    BULK COLLECT INTO
         lt_testtab
    FROM
        dt_test_tab;
   --use the individual column arrays
    select
         id,
         col1
    BULK COLLECT INTO
         lt_id,
         lt_col1
    FROM
        dt_test_tab;
    dbms_output.put_line('loop through the rowtype array');
    FOR x in lt_TestTab.FIRST..lt_TestTab.LAST LOOP
       dbms_output.put_line(to_char(lt_TestTab(x).id)||to_char(lt_TestTab(x).col1));
    end loop;
    dbms_output.put_line('loop through the two column arrays');
    FOR x in lt_Id.FIRST..lt_Id.LAST LOOP
       dbms_output.put_line(to_char(lt_Id(x))||to_char(lt_Col1(x)));
    end loop;
END;