Set name of file - 'the operation could not be completed'

Question

I have a script (see below) that is supposed to rename a list of files that have been recently saved as self contained by Quicktime Player in a script just run prior to this script .
What happens is that if the script is run immediately after the Quicktime Player script it generates a dialog with the message 'The operation could not be completed'. It was puzzling since the script would occasionally work as I tested it on its own in script editor.
After much trial and error messages I discovered that if
1. I run the Quicktime Player script saving the movies; Then
2. manually open the folder containing the movies in the finder, then
3. run the script to rename the movies,
the script would run correctly. If I don't open the folder the script fails with the 'the operation could not be completed' dialog.
Any ideas as to why this happens? Any workarounds suggested?
Thanks
Martin Koob
set movies_list to {"G-DRIVE:Projects:august 20 test 7:m-august 20 test 7A1.mov", "G-DRIVE:Projects:august 20 test 7:m-august 20 test 7A2.mov", "G-DRIVE:Projects:august 20 test 7:m-august 20 test 7A3.mov"}
set total_segments to "3" as integer
tell application "Finder"
try
activate
display dialog total_segments
repeat with current_segment from 1 to (total_segments)
set AppleScript's text item delimiters to ","
set thismoviepath to item current_segment of movies_list
set AppleScript's text item delimiters to ":"
set thisfilename to the last text item of thismoviepath
set name_length to the length of thisfilename
set AppleScript's text item delimiters to ""
set newfilename to the characters 3 thru name_length of thisfilename
set the name of file thismoviepath to newfilename as string
end repeat
on error errormessage
display dialog errormessage
end try
end tell

Answer 1

Hello
Finder has been affected by its long standing bug or design flaw in updating its internal cache, which seems relevant to your case.
Here's two sample codes I'd try.
Hope this may help,
H
PS. Why are you renaming files after saving them in different names? Saving them in the final names in QT Player would be the simplest way. Just my thought.
-- SAMPLE1
set pp to {"G-DRIVE:Videobook Projects:august 20 test 7:m-august 20 test 7A1.mov", "G-DRIVE:Videobook Projects:august 20 test 7:m-august 20 test 7A2.mov", "G-DRIVE:Videobook Projects:august 20 test 7:m-august 20 test 7A3.mov"}
try
set AppleScript's text item delimiters to {":"}
repeat with p in pp
set p to p's contents
set n to p's text item -1 -- original file name
set n1 to n's text 3 thru -1 -- new file name
set dp to "" & (p's text items 1 thru -2) & ":" -- container path
tell application "Finder"
(* code to evade Finder's bug by 'update' *)
update item dp -- update container status
--update item p -- update file status (may not be necessary)
set name of item p to n1 -- rename file
end tell
end repeat
set AppleScript's text item delimiters to {""}
on error errs number errn
set AppleScript's text item delimiters to {""}
display dialog errs & " " & errn
end try
-- END OF SAMPLE1
-- SAMPLE2
set pp to {"G-DRIVE:Videobook Projects:august 20 test 7:m-august 20 test 7A1.mov", "G-DRIVE:Videobook Projects:august 20 test 7:m-august 20 test 7A2.mov", "G-DRIVE:Videobook Projects:august 20 test 7:m-august 20 test 7A3.mov"}
try
tell application "Finder"
repeat with p in pp
set a to p as alias
(* code to evade Finder's bug by 'update' *)
update a's container -- update container status (may or may not work)
--update a -- update file status (may or may not work)
tell item a
set name to (get name)'s text 3 thru -1
end tell
end repeat
end tell
on error errs number errn
display dialog errs & " " & errn
end try
-- END OF SAMPLE2