Store \ Retrieve files from file system

Question

Hi to all!
I would like to implement a solution for storing files uploaded via apex user interface to servers file system. As well I would like this files to be retrievable by apex users. I designed the following solution:
For upload:
1. Through file browse item user chooses file to be uploaded
2. File goes to custom table (as BLOB)
-- so far i would use apex Upload\Download files tutorial
3. File(BLOB) would then have to be written to file system to some directory and file id would have to be written to some db table which holds pointers to files on file system
4. delete file(blob) from custom table (from step 2)
For download:
1. user chooses link from some report region(based on table giving file pointers to files residing on file system)
2. file identified with chosen file pointer is then inserted into blob column of some custom table in db
3. from custom table with download procedure fie is finally presented to user
4. delete file(blob) from custom table (from step 2)
Using apex tutorial for Upload\Download files it is straitforward to get the files from db table or into db table using blobs. But i have not seen any example of using BFILE or migrating files from db to file system and vice versa.
So some Q arise:
a) How can I implement step 3 under For upload section above
b) How can I implement step 2 under For download section above
c) Is there any way to directly upload file to file system via apex user interface or to directly download file from file system via some report region link column?
Please help!!!
Regards Marinero
Message was edited by:
marinero

Answer 1

marinero,
Here is a procedure that will copy an uploaded file to the file system:
  Procedure BLOB_TO_FILE(p_file_name In Varchar2) Is
    l_out_file    UTL_FILE.file_type;
    l_buffer      Raw(32767);
    l_amount      Binary_Integer := 32767;
    l_pos         Integer := 1;
    l_blob_len    Integer;
    p_data        Blob;
    file_name  Varchar2(256);
  Begin
    For rec In (Select ID
                          From HTMLDB_APPLICATION_FILES
                         Where Name = p_file_name)
    Loop
        Select BLOB_CONTENT, filename Into p_data, file_name From HTMLDB_APPLICATION_FILES Where ID = rec.ID;
        l_blob_len := DBMS_LOB.getlength(p_data);
        l_out_file := UTL_FILE.fopen('UPDOWNFILES_DIR', file_name, 'wb', 32767);
        While l_pos < l_blob_len
        Loop
          DBMS_LOB.Read(p_data, l_amount, l_pos, l_buffer);
          If l_buffer Is Not Null Then
            UTL_FILE.put_raw(l_out_file, l_buffer, True);
          End If;
          l_pos := l_pos + l_amount;
        End Loop;
        UTL_FILE.fclose(l_out_file);
    End Loop;         
  Exception
    When Others Then
      If UTL_FILE.is_open(l_out_file) Then
        UTL_FILE.fclose(l_out_file);
      End If;
  end; And here is a procedure that will download a file directly from the file system:
  Procedure download_my_file(p_file In Number) As
    v_length    Number;
    v_file_name Varchar2(2000);
    Lob_loc     Bfile;
  Begin
    Select file_name
      Into v_file_name
      From UpDownFiles F
     Where File_id = p_file;
    Lob_loc  := bfilename('UPDOWNFILES_DIR', v_file_name);
    v_length := dbms_lob.getlength(Lob_loc);
    owa_util.mime_header('application/octet', False);
    htp.p('Content-length: ' || v_length);
    htp.p('Content-Disposition: attachment; filename="' || SUBSTR(v_file_name, INSTR(v_file_name, '/') + 1) || '"');
    owa_util.http_header_close;
    wpg_docload.download_file(Lob_loc);
  End download_my_file;I could put a sample application on apex.oracle.com, but it wouldn't be able to access the file system on that server.