Strange behaviour in PL/SQL package - known bug or feature?

Question

On 10g (10.1.0.2.0/win32) we have some packages who behaves different than on 9i and 8.1.7. The problem is about a call to a procedure who clears a package record. The behaviour is strange because the result is wrong depending on the datatype of the elements in the record. The following example illustrates the problem:
create or replace package p as
type vc_type is record(f varchar2(10));
type nl_type is record(f number(10));
type nu_type is record(f number);
vc_rec vc_type;
nl_rec nl_type;
nu_rec nu_type;
procedure vc;
procedure nl;
procedure nu;
end p;
sho err
create or replace package body p as
procedure clr is
begin
vc_rec := null;
nl_rec := null;
nu_rec := null;
end clr;
procedure vc is
w vc_rec.f%type;
begin
vc_rec.f := '5';
w := vc_rec.f;
dbms_output.put_line('vc, before clr. w: '||w||', vc_rec.f: '||vc_rec.f);
p.clr;
dbms_output.put_line('vc, after clr. w: '||w||', vc_rec.f: '||vc_rec.f);
dbms_output.put_line('Expected: w = 5 and vc_rec.f = null');
end vc;
procedure nl is
w nl_rec.f%type;
begin
nl_rec.f := 5;
w := nl_rec.f;
dbms_output.put_line('nl, before clr. w: '||w||', nl_rec.f: '||nl_rec.f);
p.clr;
dbms_output.put_line('nl, after clr. w: '||w||', nl_rec.f: '||nl_rec.f);
dbms_output.put_line('Expected: w = 5 and nl_rec.f = null');
end nl;
procedure nu is
w nu_rec.f%type;
begin
nu_rec.f := 5;
w := nu_rec.f;
dbms_output.put_line('nu, before clr. w: '||w||', nu_rec.f: '||nu_rec.f);
p.clr;
dbms_output.put_line('nu, after clr. w: '||w||', nu_rec.f: '||nu_rec.f);
dbms_output.put_line('Expected: w = 5 and nu_rec.f = null');
end nu;
end p;
sho err
set serveroutput on size 1000000
exec p.vc
exec p.nl
exec p.nu
The output on my database is:
vc, before clr. w: 5, vc_rec.f: 5
vc, after clr. w: 5, vc_rec.f:
Expected: w = 5 and vc_rec.f = null
nl, before clr. w: 5, nl_rec.f: 5
nl, after clr. w: , nl_rec.f:
Expected: w = 5 and nl_rec.f = null
nu, before clr. w: 5, nu_rec.f: 5
nu, after clr. w: 5, nu_rec.f: 5
Expected: w = 5 and nu_rec.f = null
Whats going on here? Can anyone help?

Answer 1

Looks like a bug to me. I reproduced the results in 10.1.0.3.0 (linux) as well. Obviously you should check on Metalink and log a TAR if you don't find it.