To export query from Access to Excel in Read/Write mode in VBA

Question

Below is the code which exports the query named 'LatestSNR' from Access to Excel;
Public Sub Expdata()
Dim rst As DAO.Recordset
Dim Apxl As Object
Dim xlWBk, xlWSh As Object
Dim PathEx As String
Dim fld As DAO.Field
PathEx = Forms("Export").Text14 'path comes from the directory given in form
Set Apxl = CreateObject("Excel.Application")
Set rst = CurrentDb.OpenRecordset("LatestSNR")
Set xlWBk = Apxl.Workbooks.Open(PathEx)
'xlWBk.ChangeFileAccess xlReadWrite
Set xlWBk = Workbook("PathEx")
Apxl.Visible = True
Set xlWSh = xlWBk.Worksheets("Metadatasheet")
xlWSh.Activate
xlWSh.Range("A2").Select
For Each fld In rst.Fields
Apxl.ActiveCell = fld.Name
Apxl.ActiveCell.Offset(0, 1).Select
Next
rst.MoveFirst
xlWSh.Range("A2").CopyFromRecordset rst
xlWSh.Range("1:1").Select
' selects all of the cells
Apxl.ActiveSheet.Cells.Select
' selects the first cell to unselect all cells
xlWSh.Range("A2").Select
rst.Close
Set rst = Nothing
' Quit excel
Apxl.Quit
End Sub
After the execution of code, the query is transferred to excel sheet and is viewed in 'Read only' mode. If I try to save it, a copy of the excel file is produced. Can the Excel be opened in Read/Write mode ? so as to save the workbook and also to transfer
the query to same workbook repeatedly.
If in case the change of mode is not possible, then is there any alternative  method?

Answer 1

Try this version:
Public Sub Expdata()
Dim rst As DAO.Recordset
Dim Apxl As Object
Dim xlWBk As Object, xlWSh As Object
Dim PathEx As String
Dim i As Long
PathEx = Forms("Export").Text14 'path comes from the directory given in form
Set Apxl = CreateObject("Excel.Application")
Set xlWBk = Apxl.Workbooks.Open(PathEx)
Set xlWSh = xlWBk.Worksheets("Metadatasheet")
Set rst = CurrentDb.OpenRecordset("LatestSNR")
For i = 1 To rst.Fields.Count
xlWSh.Cells(1, i).Value = rst.Fields(i - 1).Name
Next i
rst.MoveFirst
xlWSh.Range("A2").CopyFromRecordset rst
xlWBk.Close SaveChanges:=True
Apxl.Quit
rst.Close
Set rst = Nothing
End Sub
or else
Public Sub Expdata()
Dim PathEx As String
PathEx = Forms("Export").Text14 'path comes from the directory given in form
DoCmd.TransferSpreadsheet TransferType:=acExport, _
SpreadsheetType:=acSpreadsheetTypeExcel12Xml, _
TableName:="LatestSNR", _
Filename:=PathEx, _
HasFieldNames:=True, _
Range:="Metadatasheet!"
End Sub
Regards, Hans Vogelaar (http://www.eileenslounge.com)