Transaction Variant -Skip first screen of sm30

Question

Hi ,
I have created a transaction variant for a ztransaction using shd0.This is for transaction sm30.
I need to skip the first screen and directly switch to table maintenance screen of the table.
While creating a transaction variant for sm30 I came across the maintain button , but I could not set its value to X.
Any idea how I can do this ?? or how i can directly switch to the maintainance screen?
Regards,
Shital

Answer 1

Hi,
You can make use of teh FM involved in SM30.
See the example code below
PARAMETERS: y_p_lgnm TYPE lgnum.
DATA : y_v_string   TYPE string.
CONSTANTS: y_k_u        TYPE char1   VALUE 'U',
          y_k_x        TYPE char1   VALUE 'X',
          y_k_lgnum    TYPE char7   VALUE 'LGNUM',
          y_k_lgtyp    TYPE char5   VALUE 'LGTYP',
          y_k_eq       TYPE char2   VALUE 'EQ',
          y_k_viewname TYPE tabname VALUE 'YLOMANAGTROL'.
DATA: y_i_seltab TYPE STANDARD TABLE OF vimsellist.
DATA: y_wa_seltab TYPE vimsellist.
START-OF-SELECTION.
*authority check for warehouse number
AUTHORITY-CHECK OBJECT 'L_LGNUM'
             ID y_k_lgnum FIELD y_p_lgnm
             ID y_k_lgtyp FIELD '*'.
IF sy-subrc NE 0.
* user not authorised
   CONCATENATE y_p_lgnm text-003 INTO y_v_string SEPARATED BY space.
   MESSAGE s015(ylo1) WITH text-001
                           sy-uname
                           text-002
                           y_v_string.
ELSE.
*Clear Internal Table
   CLEAR y_i_seltab.
   CLEAR y_wa_seltab.
*passing the selection parameters to the function module
*view_maintenance_call.
   y_wa_seltab-viewfield = y_k_lgnum.
   y_wa_seltab-value     = y_p_lgnm.
   y_wa_seltab-operator  = y_k_eq.
APPEND y_wa_seltab TO y_i_seltab.
   CALL FUNCTION 'VIEW_MAINTENANCE_CALL'
     EXPORTING
       action               = y_k_u
       view_name            = y_k_viewname
       show_selection_popup = y_k_x
     TABLES
       dba_sellist          = y_i_seltab.
ENDIF.
Here i am having my Y table 'YLOMANAGTROL'
It has primary key field warehouse number
I am creating a report with a parameter where user will give the warehouse number which he wants to change data for.
Then I check the authoity for this warehouse and then directly call the table in change mode using the FM.
I hope it is useful for you.
Regards,
Ankur Parab