Unable to INSERT PL/SQL record with EXECUTE IMMEDIATE

Question

Hi All,
I am selecting data from a source table and after some modification inserting into a target table. Source and target table name are available at run time. You can say only source table structure is fixed.
I have crated a pl/sql table of type source record and inserting record by record in target table using execute immediate. But I am not able to write
EXECUTE IMMEDIATE string USING pl_sql_table(index); and getting error as
PLS-00457: expressions have to be of SQL types
Please see the part of code below. Is it possible to use FORALL with dynamic sql like
FORALL pl_sql_table.FIRST .. pl_sql_table.COUNT
EXECUTE IMMEDIATE .... pl_sql_table(j); -- Like this.
Please suggest why I am not able to write record here. I also want to replace 'INSERT in a loop' with a single INSERT statement out of the loop, to upload whole pl_sql table into target table in one go.
Thanks,
Ravi
DECLARE
    TYPE rec_tab_CMP IS RECORD
     model_id          NUMBER(38),   
     absolute_rank          NUMBER(5)         
    v_rec_tab_CMP  rec_tab_CMP;
    TYPE t_rec_tab_CMP IS TABLE OF v_rec_tab_CMP%TYPE INDEX BY BINARY_INTEGER;
    v_records_CMP               t_rec_tab_CMP;
    rc                          SYS_REFCURSOR;
    v_old_table_name            VARCHAR2(30); -- passed from parameter 
    v_new_table_name            VARCHAR2(30); -- passed from parameter 
    dyn_str                     VARCHAR2(500);
    v_columns_str               VARCHAR2(200) := ' model_id, absolute_rank ';
BEGIN
       EXECUTE IMMEDIATE 'CREATE TABLE '|| v_new_table_name || ' AS SELECT * FROM ' || v_old_table_name ||' WHERE 1 = 2 ' ;
     OPEN rc FOR 'SELECT '|| v_columns_str ||' FROM '|| v_old_table_name;
     FETCH rc BULK COLLECT INTO v_records_CMP;
     FOR j IN 1..v_records_CMP.COUNT
     LOOP
        v_records_CMP(j).model_id := 1; -- Do someting here, This thing can be performed in SQL stmt directly.
        dyn_str := 'INSERT INTO '|| v_new_table_name ||' ( '|| v_columns_str || ' ) VALUES (:1, :2) ';
        EXECUTE IMMEDIATE dyn_str USING v_records_CMP(j).model_id          ,
                            v_records_CMP(j).absolute_rank     ;
     -- Here in place of two columns I want to use one record like
     -- EXECUTE IMMEDIATE dyn_str USING v_records_CMP(j);
     -- But it is giving me error like
        --          EXECUTE IMMEDIATE dyn_str USING v_records_st(j);
        --   PLS-00457: expressions have to be of SQL types
     END LOOP;
     CLOSE rc;
END;
/

Answer 1

You cannot bind PL/SQL record types to dynamic SQL.
Possibly you could work around this by declaring the INDEX-BY table of records at package specification level, e.g.
Oracle Database 10g Express Edition Release 10.2.0.1.0 - Production
SQL> CREATE PACKAGE package_name
  2  AS
  3     TYPE tt_emp IS TABLE OF emp%ROWTYPE;
  4     t_emp tt_emp;
  5  END package_name;
  6  /
Package created.
SQL> CREATE TABLE new_emp
  2  AS
  3     SELECT *
  4     FROM   emp
  5     WHERE  1 = 0;
Table created.
SQL> DECLARE
  2     v_table_name user_tables.table_name%TYPE := 'NEW_EMP';
  3  BEGIN
  4     SELECT *
  5     BULK COLLECT INTO package_name.t_emp
  6     FROM   emp;
  7
  8     EXECUTE IMMEDIATE
  9        'BEGIN ' ||
10        '   FORALL i IN 1 ..package_name.t_emp.COUNT ' ||
11        '      INSERT INTO ' || v_table_name ||
12        '      VALUES package_name.t_emp (i); ' ||
13        'END;';
14  END;
15  /
PL/SQL procedure successfully completed.
SQL> SELECT empno, ename
  2  FROM   new_emp;
     EMPNO ENAME
      7369 SMITH
      7499 ALLEN
      7521 WARD
      7566 JONES
      7654 MARTIN
      7698 BLAKE
      7782 CLARK
      7788 SCOTT
      7839 KING
      7844 TURNER
      7876 ADAMS
      7900 JAMES
      7902 FORD
      7934 MILLER
14 rows selected.
SQL>